Focal Point Banner


As of December 1, 2020, Focal Point is retired and repurposed as a reference repository. We value the wealth of knowledge that's been shared here over the years. You'll continue to have access to this treasure trove of knowledge, for search purposes only.

Join the TIBCO Community
TIBCO Community is a collaborative space for users to share knowledge and support one another in making the best use of TIBCO products and services. There are several TIBCO WebFOCUS resources in the community.

  • From the Home page, select Predict: WebFOCUS to view articles, questions, and trending articles.
  • Select Products from the top navigation bar, scroll, and then select the TIBCO WebFOCUS product page to view product overview, articles, and discussions.
  • Request access to the private WebFOCUS User Group (login required) to network with fellow members.

Former myibi community members should have received an email on 8/3/22 to activate their user accounts to join the community. Check your Spam folder for the email. Please get in touch with us at community@tibco.com for further assistance. Reference the community FAQ to learn more about the community.


Focal Point    Focal Point Forums  Hop To Forum Categories  WebFOCUS/FOCUS Forum on Focal Point     [SOLVED] Help with compound reports saving to PDF

Read-Only Read-Only Topic
Go
Search
Notify
Tools
[SOLVED] Help with compound reports saving to PDF
 Login/Join
 
Member
posted
Well I'm finally turning to the boards for help... I've spent the last 3 days scouring our documentation and I think I've read every forum post related to compound reports looking for clues on how to implement this, and nothing has worked.

I think I'm close, but I'm getting an error that I don't know how to debug.

Here's the situation and what I know about it:

We have a clinical department who needs a monthly report. It's a fairly large, complex report and one of a couple we're tasked with delivering. In the end, each report will consist of approximately 15-20 included fexes. These fexes need to generate one big PDF, saved to a network folder.

We have the folder and app paths created, have permissions on the folder, and creating PDF's with each of the individual fexes works flawlessly. The compound is where it's failing.

Here is what I'm currently doing in the compound:

 -* FILE CS_COMPOUND_PDF.FEX

-*************************************************************
-* AUTHOR:     PETER VARVAIS (PETVAR)

-* CREATED ON: 8-11-2010

-* PURPOSE:    THIS COMPOUND PAGE JOINS MULTIPLE SMALLER PDF FEXES
-*             AND PRESENTS THEM IN ONE REPORT TO THE CUSTOMER.

-* NOTES:      REPORTS MEASURES #210 (HOSPITAL DISCHARGES,
-*             212 (INPATIENT STAYS, 214 (AVG DAILY CENCUS),
-*             AND 236 (HOSPITAL ADMISSIONS).

-* REVISION HISTORY:


-*************************************************************
-* part 1 - print report to main folder directory
-*************************************************************


-* INSTANTIATE THE COMPOUND REPORT
COMPOUND LAYOUT HOLD FORMAT PDF


-* FORMAT MAIN SECTION PARAMETERS
SECTION=1,
  LAYOUT=ON,
  MERGE=OFF,
  UNITS=IN,
  ORIENTATION=LANDSCAPE,
  PAGESIZE=Letter,
$

-* FORMAT BASIC PAGE LAYOUT CHARACTERISTICS
PAGELAYOUT=1,
  NAME='Page layout 1',
  TOC-LEVEL=1,
  BOTTOMMARGIN=0.15,
  TOPMARGIN=0.15,
$

-* DECLARE HEADER CHARACTERISTICS
COMPONENT='CS_SYS_HEADER',
  TYPE=REPORT,
  TOC-LEVEL=2,
  POSITION=(0.150 0.10),
  DIMENSION=(* *),
$

-* DECLARE REPORT001 (PSY) CHARACTERISTICS
COMPONENT='SYSREPORT',
  TYPE=REPORT,
  TOC-LEVEL=3,
  POSITION=(0.150 0.30),
  DIMENSION=(* *),
$

-* DECLARE REPORT002 (REH) CHARACTERISTICS
COMPONENT='CS_REG_HEADER',
  TYPE=REPORT,
  TOC-LEVEL=4,
  POSITION=(0.150 1.00),
  DIMENSION=(* *),
$

-* DECLARE REPORT003 (NBN) CHARACTERISTICS
COMPONENT='REGREPORT',
  TYPE=REPORT,
  TOC-LEVEL=5,
  POSITION=(0.150 2.00),
  DIMENSION=(* *),
$

-* DECLARE REPORT002 (REH) CHARACTERISTICS
COMPONENT='CS_FAC_HEADER',
  TYPE=REPORT,
  TOC-LEVEL=6,
  POSITION=(0.150 2.60),
  DIMENSION=(* *),
$

-* DECLARE REPORT003 (NBN) CHARACTERISTICS
COMPONENT='FACREPORT',
  TYPE=REPORT,
  TOC-LEVEL=7,
  POSITION=(0.150 3.60),
  DIMENSION=(* *),
$

END
-SET &ECHO=ON;
-* BEGIN POPULATING THE REPORT PAGE WITH INCLUDED SUB-REPORTS.

SET COMPOUND=OPEN NOBREAK
SET COMPONENT='CS_SYS_HEADER'
-INCLUDE dev_petvar/cs_212_systemwide_header.fex
-RUN

SET COMPOUND= NOBREAK
SET COMPONENT='SYSREPORT'
-INCLUDE dev_petvar/cs_212_systemtable_pdf.fex
-RUN

SET COMPOUND= NOBREAK
SET COMPONENT='CS_REG_HEADER'
-INCLUDE dev_petvar/cs_212_region_header.fex
-RUN

SET COMPOUND= NOBREAK
SET COMPONENT='REGREPORT'
-INCLUDE dev_petvar/cs_212_regiontable_pdf.fex
-RUN

SET COMPOUND= NOBREAK
SET COMPONENT='CS_FAC_HEADER'
-INCLUDE dev_petvar/cs_212_facility_header.fex
-RUN

SET COMPOUND= NOBREAK
SET COMPONENT='FACREPORT'
-INCLUDE dev_petvar/cs_212_facilitytable_pdf.fex
-RUN

SET COMPOUND= CLOSE
-* CLOSE THE COMPOUND STATEMENT
END



The error I'm getting is:

  0 ERROR AT OR NEAR LINE    137  IN PROCEDURE cs_212_facilitytab
 (FOC350) ERROR WRITING OUTPUT FILE:
 (FOC3296) Error found in Coordinated Compound Report: At Component FACREPORT
 Compound Report is TERMINATING.....
 


Now I know that this fex runs fine, it was the template that I built the others from after testing it extensively.

The gist of this erroring report looks like this:

 
-**  Manipulate comparator data for final report
DEFINE FILE 212PATDAYS1 ADD
-* DEFINE MONTHLY COMPARATOR DATA
NumMonthlyTarget/D5=IF MOTarget NE 'N/A' THEN EDIT(MOTarget);
AlphaMonthlyTarget/A16 = IF MOTarget EQ 'N/A' THEN 'N/A' ELSE FTOA(NumMonthlyTarget, '(D5)', 'A16');
MonthlyVariance/D5=PATDAYS - NumMonthlyTarget;
MonthlyPercentVariance/D5%=PATDAYS / NumMonthlyTarget;

-* DEFINE YEAR TO DATE COMPARATOR DATA
NumYTDTarget/D5 = IF YTDTarget NE 'N/A' THEN EDIT(YTDTarget);
AlphaYTDTarget/A16 = IF YTDTarget EQ 'N/A' THEN 'N/A' ELSE FTOA(NumYTDTarget, '(D5', 'A16');
YTDVariance/D5=YTDPATDAYS - NumYTDTarget ;
YTDPercentVariance/D5%=YTDPATDAYS / NumYTDTarget;
END

-**  Final Report for Psych filtered results

-*APP FI PDFPOC2 DISK \\Phibuilddev1\Archive\&FullDate|_CornerstoneBreakoutReport.pdf

APP FI PDFPOC1 DISK \\Phibuilddev1\POC\CornerstoneBreakoutReport.pdf
-RUN

TABLE FILE 212PATDAYS1
SUM
  COMPUTE PATDAYS/D5 = PATDAYS; AS ''
  NumMonthlyTarget AS ''
  MonthlyVariance AS ''
  MonthlyPercentVariance AS ''
  COMPUTE YTDPATDAYS/D5 = YTDPATDAYS; AS ''
  NumYTDTarget AS ''
  YTDVariance AS ''
  YTDPercentVariance AS ''
  FiscalMonth AS ''
BY HIGHEST 1 MonthDatetime NOPRINT
BY REGIONSHORTDESCR AS ''
BY LOCSHORTDESCR AS ''
BY Grouper ROWS 'Adult & Peds (no Psych or Rehab)' OVER 'Adult & Peds Psych' OVER 'Adult & Peds Rehab'
   OVER 'Adult & Peds Total' OVER 'Nursery' OVER 'Grand Total'
WHERE MonthDatetime LE DT(&completeddate);
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL
ON TABLE SAVE FORMAT PDF AS PDFPOC1 


Another note: every fex executed in the INCLUDE is saved to the same file name (PDFPOC1) and again, the save works individually, so it's not a permissions/folder issue.

Where do I go from here? I simply can't figure it out, it looks to be written correctly.

We're running 7.6.10, if that helps.

The last question I have on this is a bit different in nature... didn't want to start a new thread though.

part 2 of this problem is that we need to save two versions... one to one file location on a network share, and the other to a different one for archival purposes.

In each fex, we have the folder designation:
APP FI PDFPOC1 DISK \\Phibuilddev1\POC\CornerstoneBreakoutReport.pdf

And the SAVE command:
ON TABLE SAVE FORMAT PDF AS PDFPOC1

But we need a second group saving to a different file path, hopefully happening during the same COMPOUND execution.

My ability to create a functioning loop has failed... every time I get the 2nd report to generate, only... it skips past the first.

Any suggestions for writing a loop for the 2-file save option, based on the TABLE FILE 212PATDAYS1 procedure referenced above?

Thanks all, appreciate any help you could provide.

This message has been edited. Last edited by: Kerry,


WebFOCUS v. 7.6.10
___________________
Win2k3 Server
Intel Xeon 2.3Ghz/4Gb Ram Apache / IIS / SQL Srvr 2005
 
Posts: 29 | Location: Bellingham, WA | Registered: October 01, 2008Report This Post
Virtuoso
posted Hide Post
If you take out FACREPORT does it work or give you the same error saying it's now CS_FAC_HEADER


In Focus since 1993. WebFOCUS 7.7.03 Win 2003
 
Posts: 1903 | Location: San Antonio | Registered: February 28, 2005Report This Post
Expert
posted Hide Post
Don't you have COMPOUND END ternimating a coordinated compound report ?

And is SET COMPOUND= NOBREAK valid in this as well ?


Waz...

Prod:WebFOCUS 7.6.10/8.1.04Upgrade:WebFOCUS 8.2.07OS:LinuxOutputs:HTML, PDF, Excel, PPT
In Focus since 1984
Pity the lost knowledge of an old programmer!

 
Posts: 6347 | Location: 33°49'23.0"S, 151°11'41.0"E | Registered: October 31, 2006Report This Post
Member
posted Hide Post
quote:
Originally posted by Prarie:
If you take out FACREPORT does it work or give you the same error saying it's now CS_FAC_HEADER



yes that's what happens.

quote:
Originally posted by Waz:
Don't you have COMPOUND END ternimating a coordinated compound report ?

And is SET COMPOUND= NOBREAK valid in this as well ?


Actually, that looks to be the issue. Call it murphy's law, but we solved it ourselves just now.

Here's what we did:

All of the SET COMPOUND= declarations were commented out... even though I've read numerous times to include them.

BUT... suffice it to say (Thanks to my teammate Meghan), commenting all of them out (without the OPEN/CLOSE declaration) actually allowed it to run to completion and generated the report.

All's well that end's well, thank you for writing back so quickly. Maybe someone else will be able to benefit from it down the road Smiler

Peter


WebFOCUS v. 7.6.10
___________________
Win2k3 Server
Intel Xeon 2.3Ghz/4Gb Ram Apache / IIS / SQL Srvr 2005
 
Posts: 29 | Location: Bellingham, WA | Registered: October 01, 2008Report This Post
Expert
posted Hide Post
FYI

There are two types of compound reports in WebFOCUS

The original one with NOBREAK etc.
SET COMPOUND=OPEN
{Report}
.
.
SET COMPOUND = CLOSE
{Report}


And the otherone, a coordinated compound report. a very different beast.
COMPOUND LAYOUT ....

END
SET COMPONENT='{component name}'
{Report}
.
.
.
SET COMPONENT='{component name}'
{Report}
COMPOUND END


Waz...

Prod:WebFOCUS 7.6.10/8.1.04Upgrade:WebFOCUS 8.2.07OS:LinuxOutputs:HTML, PDF, Excel, PPT
In Focus since 1984
Pity the lost knowledge of an old programmer!

 
Posts: 6347 | Location: 33°49'23.0"S, 151°11'41.0"E | Registered: October 31, 2006Report This Post
Member
posted Hide Post
Actually, that was quite helpful to see side by side like that. I think I combined both into one, attempting earlier to fix my problem Smiler


WebFOCUS v. 7.6.10
___________________
Win2k3 Server
Intel Xeon 2.3Ghz/4Gb Ram Apache / IIS / SQL Srvr 2005
 
Posts: 29 | Location: Bellingham, WA | Registered: October 01, 2008Report This Post
Expert
posted Hide Post
It can be confusing and make you go crazy.



Below is a link to the documentation.

http://documentation.informati...htm?url=topic117.htm


Waz...

Prod:WebFOCUS 7.6.10/8.1.04Upgrade:WebFOCUS 8.2.07OS:LinuxOutputs:HTML, PDF, Excel, PPT
In Focus since 1984
Pity the lost knowledge of an old programmer!

 
Posts: 6347 | Location: 33°49'23.0"S, 151°11'41.0"E | Registered: October 31, 2006Report This Post
  Powered by Social Strata  

Read-Only Read-Only Topic

Focal Point    Focal Point Forums  Hop To Forum Categories  WebFOCUS/FOCUS Forum on Focal Point     [SOLVED] Help with compound reports saving to PDF

Copyright © 1996-2020 Information Builders