Is anyone getting errors when they code

TYPE=REPORT, TITLETEXT='tab name', $ 

in a COMPOUND EXCEL sheet?

The error: "The embedded style sheet has an error in line 61. Keyword has illegal value: TITLETEXT='Inv. Rpt"

This message has been edited. Last edited by: FP Mod Chuck,

Hello,

Mine is working fine for both XLSX and ELX2K.
What format are you using?
Can you provide some sample code?

It looks like you have an extra quote at the tabname:

ITLETEXT='Inv. Rpt"

should be

ITLETEXT='Inv. Rpt'

Frans, That's wierd, the 'extra quote" only shows in the error message, not in the code.

quote:

TYPE=REPORT, TITLETEXT='tab name', $

quote:

The error: "The embedded style sheet has an error in line 61. Keyword has illegal value: TITLETEXT='Inv. Rpt"

Or is it a missing single quote mark? It looks like the message ends in a double quote character which could be the counterpart to the opening double quote character.

No, it is a mighty slippery fish.

[QUOTE]Originally posted by Tomsweb:
No, it is a mighty slippery fish.
I played with this quite a bit and it works. Whew!!!
Since the documentation is an embarrassment, it does not
appear that the App Studio UI provides the ability to
enter text for the TITLETEXT tag. Hence we have "to pin the
tail on the donkey with one eye closed" and hope for the best.

TABLE FILE CAR
BY  CAR.ORIGIN.COUNTRY
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE SET ASNAMES ON
ON TABLE NOTOTAL

ON TABLE SET XLSXPAGESETS ON
ON TABLE SET HTMLCSS ON

ON TABLE PCHOLD FORMAT EXL2K OPEN
ON TABLE SET STYLE *
     INCLUDE = IBFS:/EDA/EDASERVE/_EDAHOME/ETC/warm.sty,
$
TYPE=REPORT,
     TITLETEXT='Country Report',
     FONT='IBIDEFAULT',
     SIZE=14,
     COLOR='BLACK',
$
TYPE=DATA,
     SIZE=12,
     COLOR='RED',
     STYLE=ITALIC,
$
TYPE=TITLE,
     SIZE=13,
     COLOR='BLUE',
	 BACKCOLOR='WHITE',
     STYLE=BOLD+UNDERLINE,
$
ENDSTYLE
END

TABLE FILE CAR
SUM SALES
BY  CAR.ORIGIN.COUNTRY
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE SET ASNAMES ON
ON TABLE NOTOTAL

ON TABLE SET XLSXPAGESETS ON
ON TABLE SET HTMLCSS ON

ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET STYLE *
     INCLUDE = IBFS:/EDA/EDASERVE/_EDAHOME/ETC/warm.sty,
$
TYPE=REPORT,
     TITLETEXT='Sales Report',
     FONT='IBIDEFAULT',
     SIZE=14,
     COLOR='BLACK',
$
TYPE=DATA,
     SIZE=12,
     COLOR='WHITE',
	 BACKCOLOR='BLACK',
     STYLE=ITALIC,
$
TYPE=TITLE,
     SIZE=13,
     COLOR='WHITE',
	 BACKCOLOR='GREEN',
     STYLE=BOLD+UNDERLINE,
$
ENDSTYLE
END

TABLE FILE CAR
SUM DEALER
BY  CAR.ORIGIN.COUNTRY
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE SET ASNAMES ON
ON TABLE NOTOTAL

ON TABLE SET XLSXPAGESETS ON
ON TABLE SET HTMLCSS ON

ON TABLE PCHOLD FORMAT EXL2K CLOSE
ON TABLE SET STYLE *
     INCLUDE = IBFS:/EDA/EDASERVE/_EDAHOME/ETC/warm.sty,
$
TYPE=REPORT,
     TITLETEXT='Dealer Report',
     FONT='IBIDEFAULT',
     SIZE=14,
     COLOR='BLACK',
$
TYPE=DATA,
     SIZE=12,
     COLOR='WHITE',
	 BACKCOLOR='GREEN',
     STYLE=ITALIC,
$
TYPE=TITLE,
     SIZE=13,
     COLOR='BLUE',
     STYLE=BOLD+UNDERLINE,
$
ENDSTYLE
END 

Excellent Tom! The only thing I'd change, besides those beautiful colors, is 'EXL2K' to 'XLSX'. But, I understand that this is just a POC. I'm keeping a copy, and reference, in my tool box so that I don't need to 'reinvent the wheel'.