Focal Point Banner
Community Center Education Summit Technical Support User Groups
Let's Get Social!

Facebook Twitter LinkedIn YouTube
Focal Point    Focal Point Forums  Hop To Forum Categories  WebFOCUS/FOCUS Forum on Focal Point     [CLOSED] Border not reflecting for subtotal when OBJECT=FIELD
Go
New
Search
Notify
Tools
Reply
  
[CLOSED] Border not reflecting for subtotal when OBJECT=FIELD
 Login/Join
 
Member
posted
I am unable to generate border for OBJECT=FIELD which is item=3 in my code.
 TABLE FILE CAR
PRINT CAR LENGTH
RC  DC  
BY COUNTRY 
ON COUNTRY SUBFOOT
"Total:<ST.RC<ST.DC<0+> " 
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
UNITS=IN, PAGESIZE='Letter', ORIENTATION=LANDSCAPE, SQUEEZE=ON, $
TYPE = SUBFOOT,HEADALIGN=BODY, $
TYPE = SUBFOOT, STYLE = BOLD, BORDER=LIGHT, $
TYPE = SUBFOOT,LINE=1 ,ITEM=1, OBJECT=TEXT, COLSPAN=1, BORDER =LIGHT, BORDER-LEFT=LIGHT, BORDER-RIGHT=LIGHT, $
TYPE = SUBFOOT,LINE=1 ,ITEM=2, OBJECT=FIELD, COLSPAN=1, BORDER =LIGHT, BORDER-LEFT=LIGHT, BORDER-RIGHT=LIGHT, $
TYPE = SUBFOOT,LINE=1 ,ITEM=3, OBJECT=FIELD, COLSPAN=1, BORDER =LIGHT, BORDER-LEFT=LIGHT, BORDER-RIGHT=LIGHT, $
TYPE = SUBFOOT,LINE=1 ,ITEM=4, OBJECT=TEXT, COLSPAN=1, BORDER =LIGHT, BORDER-LEFT=LIGHT, BORDER-RIGHT=LIGHT,$
ENDSTYLE
END 

This message has been edited. Last edited by: FP Mod Chuck,
 
Posts: 9 | Registered: May 07, 2019Reply With QuoteReport This Post
Virtuoso
posted Hide Post
Is it what you're looking for ?

TABLE FILE CAR
PRINT CAR
      LENGTH
      RC
      DC
BY COUNTRY 
ON COUNTRY SUBFOOT
"Total:<ST.RC<ST.DC<0+>"
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
UNITS=IN, PAGESIZE='Letter', ORIENTATION=LANDSCAPE, SQUEEZE=ON, $
TYPE = SUBFOOT,HEADALIGN=BODY, $
TYPE = SUBFOOT, STYLE = BOLD,  $
TYPE = SUBFOOT,LINE=1 ,ITEM=1, OBJECT=TEXT,  COLSPAN=1, BORDER =LIGHT, $
TYPE = SUBFOOT,LINE=1 ,ITEM=1, OBJECT=FIELD, COLSPAN=3, BORDER =LIGHT, $
TYPE = SUBFOOT,LINE=1 ,ITEM=2, OBJECT=FIELD, COLSPAN=1, BORDER =LIGHT, $
ENDSTYLE
END 
-RUN


WF versions : Prod 8.2.0.1M gen 240, Dev 8.2.04 gen 48, OS : Windows, DB : MSSQL, Outputs : HTML, Excel, PDF
In Focus since 2007
 
Posts: 2191 | Location: Montreal Area, Qc, CA | Registered: September 25, 2013Reply With QuoteReport This Post
Expert
posted Hide Post
I, sometimes, eliminate the "ITEM=1, OBJECT=TEXT" and just count the items (regardless of the TYPE, TEXT or FIELD, just to eliminate some confusion. Just a thought...
 
Posts: 3020 | Location: Middle Tennessee [8204M Gen48 in Test&Prod] | Registered: February 23, 2005Reply With QuoteReport This Post
Member
posted Hide Post
DEFINE FILE CAR
RC_DC/D14.2CMB   = DEALER_COST - RETAIL_COST ;
RETAIL_COST_1/D14.2CMB = RETAIL_COST;
DEALER_COST_1/D14.2CMB = DEALER_COST;
END



TABLE FILE CAR
SUM RETAIL_COST_1
    DEALER_COST_1
	RC_DC/D14.2CMB
	LENGTH

BY COUNTRY
BY CAR
 ON COUNTRY SUBFOOT
"Total:<+0> <ST.RETAIL_COST_1<ST.DEALER_COST_1<RC_DC <0+>"
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE SET ASNAMES ON
ON TABLE SET ONLINE-FMT PDF
ON TABLE SET PAGE NOLEAD
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
SQUEEZE=ON, $
TYPE=TITLE, STYLE=BOLD,$
TYPE=REPORT, FONT='ARIAL', SIZE=5, STYLE=NORMAL, BORDER =LIGHT, $
TYPE=DATA,COLUMN=RETAIL_COST_1,							JUSTIFY=RIGHT,$
TYPE=DATA,COLUMN=DEALER_COST_1,							JUSTIFY=RIGHT,$
TYPE=DATA,COLUMN=RC_DC,						         	JUSTIFY=RIGHT,$
TYPE=TITLE, STYLE=BOLD,$
TYPE=SUBFOOT, HEADALIGN=BODY, BORDER=LIGHT, $
TYPE=SUBFOOT, LINE=1 ,OBJECT = TEXT , ITEM=1,  COLSPAN=1,  BORDER =ON, BORDER-LEFT=ON, BORDER-RIGHT=ON, $
TYPE=SUBFOOT, LINE=1 ,OBJECT = TEXT , ITEM=2,  COLSPAN=1,  BORDER =ON, BORDER-LEFT=ON, BORDER-RIGHT=ON, $
-*TYPE=SUBFOOT, LINE=1 ,OBJECT = FIELD, ITEM=1,  COLSPAN=1,  BORDER =ON, BORDER-LEFT=ON, BORDER-RIGHT=ON,$
-*TYPE=SUBFOOT, LINE=1 ,OBJECT = FIELD, ITEM=2,  COLSPAN=1,  BORDER =ON, BORDER-LEFT=ON, BORDER-RIGHT=ON,$
-*TYPE=SUBFOOT, LINE=1 ,OBJECT = FIELD, ITEM=3,  COLSPAN=1,  BORDER =ON, BORDER-LEFT=ON, BORDER-RIGHT=ON,$


TYPE=SUBFOOT, LINE=1 ,OBJECT = TEXT, ITEM=3,  COLSPAN=1,  BORDER =ON, BORDER-LEFT=ON, BORDER-RIGHT=ON,$
TYPE=SUBFOOT, LINE=1 ,OBJECT = TEXT, ITEM=4,  COLSPAN=1,  BORDER =ON, BORDER-LEFT=ON, BORDER-RIGHT=ON,$
TYPE=SUBFOOT, LINE=1 ,OBJECT = TEXT, ITEM=5,  COLSPAN=1,  BORDER =ON, BORDER-LEFT=ON, BORDER-RIGHT=ON,$
TYPE=SUBFOOT, LINE=1 ,OBJECT = TEXT , ITEM=6,  COLSPAN=1,  BORDER =ON, BORDER-LEFT=ON, BORDER-RIGHT=ON,$
ENDSTYLE
END  

---------------------------------------------------------------------------------
 
DEFINE FILE CAR
RC_DC/D14.2CMB   = DEALER_COST - RETAIL_COST ;
RETAIL_COST_1/D14.2CMB = RETAIL_COST;
DEALER_COST_1/D14.2CMB = DEALER_COST;
END



TABLE FILE CAR
SUM RETAIL_COST_1
    DEALER_COST_1
	RC_DC/D14.2CMB
	LENGTH

BY COUNTRY
BY CAR
 ON COUNTRY SUBFOOT
"Total:<+0> <ST.RETAIL_COST_1<ST.DEALER_COST_1<RC_DC <0+>"
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE SET ASNAMES ON
ON TABLE SET ONLINE-FMT PDF
ON TABLE SET PAGE NOLEAD
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
SQUEEZE=ON, $
TYPE=TITLE, STYLE=BOLD,$
TYPE=REPORT, FONT='ARIAL', SIZE=5, STYLE=NORMAL, BORDER =LIGHT, $
TYPE=DATA,COLUMN=RETAIL_COST_1,							JUSTIFY=RIGHT,$
TYPE=DATA,COLUMN=DEALER_COST_1,							JUSTIFY=RIGHT,$
TYPE=DATA,COLUMN=RC_DC,						         	JUSTIFY=RIGHT,$
TYPE=TITLE, STYLE=BOLD,$
TYPE=SUBFOOT, HEADALIGN=BODY, BORDER=LIGHT, $
TYPE=SUBFOOT, LINE=1 ,OBJECT = TEXT , ITEM=1,  COLSPAN=1,  BORDER =ON, BORDER-LEFT=ON, BORDER-RIGHT=ON, $
TYPE=SUBFOOT, LINE=1 ,OBJECT = TEXT , ITEM=2,  COLSPAN=1,  BORDER =ON, BORDER-LEFT=ON, BORDER-RIGHT=ON, $
TYPE=SUBFOOT, LINE=1 ,OBJECT = FIELD, ITEM=1,  COLSPAN=1,  BORDER =ON, BORDER-LEFT=ON, BORDER-RIGHT=ON,$
TYPE=SUBFOOT, LINE=1 ,OBJECT = FIELD, ITEM=2,  COLSPAN=1,  BORDER =ON, BORDER-LEFT=ON, BORDER-RIGHT=ON,$
TYPE=SUBFOOT, LINE=1 ,OBJECT = FIELD, ITEM=3,  COLSPAN=1,  BORDER =ON, BORDER-LEFT=ON, BORDER-RIGHT=ON,$


-*TYPE=SUBFOOT, LINE=1 ,OBJECT = TEXT, ITEM=3,  COLSPAN=1,  BORDER =ON, BORDER-LEFT=ON, BORDER-RIGHT=ON,$
-*TYPE=SUBFOOT, LINE=1 ,OBJECT = TEXT, ITEM=4,  COLSPAN=1,  BORDER =ON, BORDER-LEFT=ON, BORDER-RIGHT=ON,$
-*TYPE=SUBFOOT, LINE=1 ,OBJECT = TEXT, ITEM=5,  COLSPAN=1,  BORDER =ON, BORDER-LEFT=ON, BORDER-RIGHT=ON,$
TYPE=SUBFOOT, LINE=1 ,OBJECT = TEXT , ITEM=6,  COLSPAN=1,  BORDER =ON, BORDER-LEFT=ON, BORDER-RIGHT=ON,$
ENDSTYLE
END
 


Above is my code snippet to get subtotal using subfoot, but i could not able to generate right border for the totals in subfoot when i used OBJECT = TEXT. when i tried OBJECT = FIELD border is not respecting correctly for negative values.
 
Posts: 9 | Registered: May 07, 2019Reply With QuoteReport This Post
Virtuoso
posted Hide Post
DEFINE FILE CAR
RC_DC/D14.2CMB   = DEALER_COST - RETAIL_COST ;
RETAIL_COST_1/D14.2CMB = RETAIL_COST;
DEALER_COST_1/D14.2CMB = DEALER_COST;
END
TABLE FILE CAR
SUM RETAIL_COST_1
    DEALER_COST_1
	RC_DC
	LENGTH
BY COUNTRY
BY CAR
 ON COUNTRY SUBFOOT

"Total:<+0> <ST.RETAIL_COST_1<ST.DEALER_COST_1<ST.RC_DC <+0> "

ON TABLE SET PAGE-NUM NOLEAD
ON TABLE SET ASNAMES ON
ON TABLE SET ONLINE-FMT PDF
ON TABLE SET PAGE NOLEAD
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
SQUEEZE=ON, $
TYPE=TITLE, STYLE=BOLD,$
TYPE=REPORT, FONT='ARIAL', SIZE=5, STYLE=NORMAL, BORDER=LIGHT, $
TYPE=DATA,COLUMN=RETAIL_COST_1, JUSTIFY=RIGHT,$
TYPE=DATA,COLUMN=DEALER_COST_1,	JUSTIFY=RIGHT,$
TYPE=DATA,COLUMN=RC_DC,         JUSTIFY=RIGHT,$
TYPE=SUBFOOT,HEADALIGN=BODY, $
TYPE=SUBFOOT,STYLE=BOLD, $
TYPE=SUBFOOT,LINE=1 ,ITEM=1, OBJECT=TEXT,  COLSPAN=1, BORDER=LIGHT, $
TYPE=SUBFOOT,LINE=1 ,ITEM=1, OBJECT=FIELD, COLSPAN=1, BORDER=LIGHT, $
TYPE=SUBFOOT,LINE=1 ,ITEM=2, OBJECT=FIELD, COLSPAN=1, BORDER=LIGHT, $
TYPE=SUBFOOT,LINE=1 ,ITEM=3, OBJECT=FIELD, COLSPAN=1, $
TYPE=SUBFOOT,LINE=1 ,ITEM=3, OBJECT=TEXT,  COLSPAN=1, BORDER=LIGHT, $
END
-RUN 


WF versions : Prod 8.2.0.1M gen 240, Dev 8.2.04 gen 48, OS : Windows, DB : MSSQL, Outputs : HTML, Excel, PDF
In Focus since 2007
 
Posts: 2191 | Location: Montreal Area, Qc, CA | Registered: September 25, 2013Reply With QuoteReport This Post
Expert
posted Hide Post
I added some elaborations to MartinY's already prefect code.
-* File:  http://forums.informationbuild...407047196#5407047196 
-* Created by WebFOCUS Doug in AppStudio
DEFINE FILE CAR
COUNTRY_Total/A17=COUNTRY || ( ' Total') ;
END
TABLE FILE CAR
SUM CNT.DST.MODEL/I2 AS 'Models'
    RETAIL_COST/D12C AS 'Retail'
    DEALER_COST/D12C AS 'Dealer'
COMPUTE Profit/D12C = RETAIL_COST - DEALER_COST ;
BY COUNTRY
BY CAR
ON COUNTRY SUBFOOT
"<COUNTRY_Total <+0> <ST.RETAIL_COST<ST.DEALER_COST<ST.Profit <+0> "
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE SET ASNAMES ON
ON TABLE SET PAGE NOLEAD
ON TABLE SUBTOTAL AS 'Report Total:'
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
SQUEEZE=ON, $
TYPE=TITLE, STYLE=BOLD,$
TYPE=REPORT, FONT='ARIAL', SIZE=5, STYLE=NORMAL, BORDER=LIGHT, $
TYPE=DATA,COLUMN=RETAIL_COST, JUSTIFY=RIGHT,$
TYPE=DATA,COLUMN=DEALER_COST, JUSTIFY=RIGHT,$
TYPE=DATA,COLUMN=N3, JUSTIFY=CENTER, $
TYPE=SUBFOOT,HEADALIGN=BODY, $
TYPE=SUBFOOT,STYLE=BOLD, BACKCOLOR=RGB(244 244 244), $
TYPE=SUBFOOT,LINE=1 ,ITEM=1, OBJECT=FIELD, COLSPAN=1, BORDER=LIGHT, $
TYPE=SUBFOOT,LINE=1 ,ITEM=2, OBJECT=FIELD, COLSPAN=1, BORDER=LIGHT, $
TYPE=SUBFOOT,LINE=1 ,ITEM=3, OBJECT=FIELD, COLSPAN=1, $
TYPE=SUBFOOT,LINE=1 ,ITEM=3, OBJECT=TEXT,  COLSPAN=1, BORDER=LIGHT, $
TYPE=GRANDTOTAL,STYLE=BOLD, BACKCOLOR=RGB(204 204 204), $
TYPE=GRANDTOTAL,COLUMN=N3, JUSTIFY=CENTER,$
END
-RUN 
I hope you like it. Smiler


   In FOCUS Since 1983 ~ from FOCUS to WebFOCUS.
   Most recent: 8204 Gen 48 in Test and Production.
   Currently Available. Please contact me.
 
Posts: 3020 | Location: Middle Tennessee [8204M Gen48 in Test&Prod] | Registered: February 23, 2005Reply With QuoteReport This Post
Expert
posted Hide Post
For the first instance -

Thinking too hard guys.

Just correct and change the syntax on your subhead. I'll leave you to spot (no pun intended) the change and correction. Smiler -

ON COUNTRY SUBFOOT
"Total:<ST.RC<ST.DC><+0> "


For the second instance, use Martin's suggestion (Doug, you forgot the negative formatting) or I suggest raising a case with tech support.


T



In FOCUS
since 1986
WebFOCUS Server 8.2.01M, thru 8.2.06 on Windows Svr 2008 R2  
WebFOCUS App Studio 8.2.06 standalone on Windows 10 
 
Posts: 5607 | Location: United Kingdom | Registered: April 08, 2004Reply With QuoteReport This Post
Expert
posted Hide Post
Ah, the negatives... Thanks Tony.
 
Posts: 3020 | Location: Middle Tennessee [8204M Gen48 in Test&Prod] | Registered: February 23, 2005Reply With QuoteReport This Post
  Powered by Social Strata  
 

Focal Point    Focal Point Forums  Hop To Forum Categories  WebFOCUS/FOCUS Forum on Focal Point     [CLOSED] Border not reflecting for subtotal when OBJECT=FIELD

Copyright © 1996-2018 Information Builders, leaders in enterprise business intelligence.