Focal Point Banner


As of December 1, 2020, Focal Point is retired and repurposed as a reference repository. We value the wealth of knowledge that's been shared here over the years. You'll continue to have access to this treasure trove of knowledge, for search purposes only.

Join the TIBCO Community
TIBCO Community is a collaborative space for users to share knowledge and support one another in making the best use of TIBCO products and services. There are several TIBCO WebFOCUS resources in the community.

  • From the Home page, select Predict: WebFOCUS to view articles, questions, and trending articles.
  • Select Products from the top navigation bar, scroll, and then select the TIBCO WebFOCUS product page to view product overview, articles, and discussions.
  • Request access to the private WebFOCUS User Group (login required) to network with fellow members.

Former myibi community members should have received an email on 8/3/22 to activate their user accounts to join the community. Check your Spam folder for the email. Please get in touch with us at community@tibco.com for further assistance. Reference the community FAQ to learn more about the community.


Focal Point    Focal Point Forums  Hop To Forum Categories  WebFOCUS/FOCUS Forum on Focal Point     Displaying footer with empty report?
Page 1 2 

Read-Only Read-Only Topic
Go
Search
Notify
Tools
Displaying footer with empty report?
 Login/Join
 
Platinum Member
posted
Is there a way I can get the footer to display on an empty report? The column headings / header all appear but goes blank there after.

Eric


dev: WF 7.6.5 w/IIS + Tomcat

prod: WF 7.6.5 w/IIS + Tomcat
 
Posts: 153 | Location: Chicago, IL | Registered: February 24, 2006Report This Post
Master
posted Hide Post
This one works,

-SET &DISPFORMAT='HTML';

TABLE FILE CAR
PRINT CAR NOPRINT
WHERE RECORDLIMIT EQ 1
HEADING
"NO DATA"
FOOTING
"PAGE ON TABLE SET EMPTYREPORT ON
ON TABLE PCHOLD FORMAT &DISPFORMAT
ON TABLE SET STYLE *
TYPE=REPORT,GRID=OFF,SIZE=8,FONT=ARIAL,$
TYPE=HEADING,STYLE=BOLD,$
TYPE=FOOTING,BACKCOLOR=SILVER,COLOR=MAROON,$
ENDSTYLE
END
-EXIT


WFConsultant

WF 8105M on Win7/Tomcat
 
Posts: 780 | Location: Florida | Registered: January 09, 2005Report This Post
Virtuoso
posted Hide Post
But this does not.

SET EMPTYREPORT=ON
TABLE FILE CAR
PRINT CAR
IF CAR EQ 'TRUCK'
HEADING
"NO DATA"
FOOTING
"PAGE"
END


In Focus since 1993. WebFOCUS 7.7.03 Win 2003
 
Posts: 1903 | Location: San Antonio | Registered: February 28, 2005Report This Post
Platinum Member
posted Hide Post
Prarie's example is what happens in my report....any ideas?


dev: WF 7.6.5 w/IIS + Tomcat

prod: WF 7.6.5 w/IIS + Tomcat
 
Posts: 153 | Location: Chicago, IL | Registered: February 24, 2006Report This Post
Guru
posted Hide Post
I think what Prarie and Kamesh are telling you is you can check &RECORDS and if there are none, branch to another place in the focexec that produces a dummy report against the CAR file. The CAR files comes with WebFOCUS. Empty Reports do not display footings. It would be nice if they did!

you're request here
-RUN
-IF &RECORDS EQ 0 GOTO NOREPORT;

-NOREPORT
TABLE FILE CAR......
dummy report



Good Luck!



WebFOCUS 7.6.6/TomCat/Win2k3
 
Posts: 428 | Location: Springfield, MA | Registered: May 07, 2003Report This Post
Platinum Member
posted Hide Post
Yeah, I know about the 0 records idea but the reason I didn't want to use that is because they want the report headers and column headings to still appear on the report.

Eric


dev: WF 7.6.5 w/IIS + Tomcat

prod: WF 7.6.5 w/IIS + Tomcat
 
Posts: 153 | Location: Chicago, IL | Registered: February 24, 2006Report This Post
Virtuoso
posted Hide Post
Seems to happen everywhere, under all conditions. Cannot get it to change behaviour.


Alan.
WF 7.705/8.007
 
Posts: 1451 | Location: Portugal | Registered: February 07, 2007Report This Post
Virtuoso
posted Hide Post
Quote from manual

An empty report, that is, the report without data but including column titles, a report heading (if one was specified in the report request), and a page heading (if one was specified).


Alan.
WF 7.705/8.007
 
Posts: 1451 | Location: Portugal | Registered: February 07, 2007Report This Post
Platinum Member
posted Hide Post
I believe that what Carol meant was to use something like the Car file and then hardcode the same report and column headings when the &lines(not necessarily &records) is zero in your report.

DEFINE FILE CAR
DUM/A1 WITH CAR =' ';
END
TABLE FILE CAR
HEADING
"WHATEVER THE REAL REPORT HEADING WOULD BE"
PRINT DUM AS 'TITLE FOR COLUMN1 ON REAL REPORT'
DUM AS 'TITLE FOR COLUMN2 ON REAL REPORT'
.... etc one for each column on real report
IF RECORDLIMIT EQ 1
FOOTING
"WHATEVER YOUR REAL REPORT FOOTING WOULD BE"
END

Good luck


FOCUS 7.6 MVS PDF,HTML,EXCEL
 
Posts: 115 | Location: Chicago, IL | Registered: May 28, 2004Report This Post
Platinum Member
posted Hide Post
Alright, that's what I was afraid of...thanks guys.

Eric


dev: WF 7.6.5 w/IIS + Tomcat

prod: WF 7.6.5 w/IIS + Tomcat
 
Posts: 153 | Location: Chicago, IL | Registered: February 24, 2006Report This Post
Virtuoso
posted Hide Post
WebFOCUS places footings at the end of the data or at the bottom of the last page of data. Since there is no data, it can't put it anywhere - basically division by zero. ET's idea would be the only way to get a footing in.
I guess you could re-run the same report if &RECORDS=0, changing the page heading to a report heading and the footing to a heading, (using &variables) but the column titles would still come after both, not in between the two.


Regards,

Darin



In FOCUS since 1991
WF Server: 7.7.04 on Linux and Z/OS, ReportCaster, Self-Service, MRE, Java, Flex
Data: DB2/UDB, Adabas, SQL Server Output: HTML,PDF,EXL2K/07, PS, AHTML, Flex
WF Client: 77 on Linux w/Tomcat
 
Posts: 2298 | Location: Salt Lake City, Utah | Registered: February 02, 2007Report This Post
Platinum Member
posted Hide Post
This was really not my idea but from Carol's post. What this does is if real report was empty then use the Car file (or any other file that you know is not empty) and print a blank field to add the column titles corresponding to each field on the empty report. Becasue there is one record on this report Focus can then add the footing. My experience leads me to use &lines and not &records. I have encountered instances where an empty report happens and &records is not zero. One case where this happens is the real report could have had qualifying records and thus &records is not zero but there was an if/where total test that eliminated all the records and &lines is equal to zero.

TABLE FILE CAR
PRINT COUNTRY
IF TOTAL COUNTRY EQ ' '
END
NUMBER OF RECORDS IN TABLE= 5 LINES= 5 <======== 5 records
(BEFORE TOTAL TESTS)
? stat
STATISTICS OF LAST COMMAND

RECORDS = 5 &records SEGS DELTD = 0
LINES = 0 &lines NOMATCH = 0
BASEIO = 3 DUPLICATES = 0
TRACKIO = 0 FORMAT ERRORS = 0
SORTIO = 3 INVALID CONDTS = 0
SORT PAGES = 4 OTHER REJECTS = 0
READS = 0 CACHE READS = 0
TRANSACTIONS = 0 MERGES = 0
ACCEPTED = 0 SORT STRINGS = 1
SEGS INPUT = 0 INDEXIO = 0
SEGS CHNGD = 0

INTERNAL MATRIX CREATED: YES AUTOINDEX USED: NO
SORT USED: FOCUS AUTOPATH USED: NO
AGGREGATION BY EXT.SORT: NO HOLD FROM EXTERNAL SORT: NO
MINIO USED:

NO
Good luck


FOCUS 7.6 MVS PDF,HTML,EXCEL
 
Posts: 115 | Location: Chicago, IL | Registered: May 28, 2004Report This Post
Guru
posted Hide Post
In WebFocus 7.1x there is a value -

SET EMPTYREPORT = ANSI

This will produce a footer, since it places a line in every report (where all data is missing).


(Prod: WebFOCUS 7.7.03: Win 2008 & AIX hub/Servlet Mode; sub: AS/400 JDE; mostly Self Serve; DBs: Oracle, JDE, SQLServer; various output formats)
 
Posts: 391 | Location: California | Registered: April 14, 2003Report This Post
Expert
posted Hide Post
quote:
SET EMPTYREPORT = ANSI


N.Selph! Something new to learn everyday!

It works in 5.3.2 as well.

SET EMPTYREPORT = ANSI
TABLE FILE CAR
FOOTING
"THIS IS THE FOOTING"
HEADING
"THIS IS THE HEADING"
ON TABLE SUBFOOT
"THIS IS THE TABLE FOOTING"
SUM SALES 
BY COUNTRY
WHERE COUNTRY EQ 'RUSSIA'
END


Francis


Give me code, or give me retirement. In FOCUS since 1991

Production: WF 7.7.05M, Dev Studio, BID, MRE, WebSphere, DB2 / Test: WF 8.1.05M, App Studio, BI Portal, Report Caster, jQuery, HighCharts, Apache Tomcat, MS SQL Server
 
Posts: 10577 | Location: Toronto, Ontario, Canada | Registered: April 27, 2005Report This Post
Expert
posted Hide Post
And it's in the manual:

SET EMPTYREPORT={ANSI|ON|OFF} where:

ANSI

Produces a single-line report and displays the missing data character or a zero if a COUNT is requested. in each case, &RECORDS will be 0, and &LINES will be 1.


If the SQL Translator is invoked, ANSI automatically replaces OFF as the default setting for EMPTYREPORT.


ON

Produces an empty report (column headings with no content). This was the default behavior in prior releases.


OFF

Produces no report output. OFF is the default value except for SQL Translator requests. When the SQL Translator is invoked, ANSI replaces OFF as the default setting for the EMPTYREPORT parameter, so the results are the same as for the ANSI setting.


The command can also be issued from within a request:

ON TABLE SET EMPTYREPORT ANSI


Francis


Give me code, or give me retirement. In FOCUS since 1991

Production: WF 7.7.05M, Dev Studio, BID, MRE, WebSphere, DB2 / Test: WF 8.1.05M, App Studio, BI Portal, Report Caster, jQuery, HighCharts, Apache Tomcat, MS SQL Server
 
Posts: 10577 | Location: Toronto, Ontario, Canada | Registered: April 27, 2005Report This Post
Virtuoso
posted Hide Post
Francis,

Thanks. As usual, when you have tried everything and nothing works, RTM (read the manual)!


Daniel
In Focus since 1982
wf 8.202M/Win10/IIS/SSA - WrapApp Front End for WF

 
Posts: 1980 | Location: Tel Aviv, Israel | Registered: March 23, 2006Report This Post
Platinum Member
posted Hide Post
Ahh this was my own fault. I use ANSI in my self service reports and used ON for who knows what reason cause I was adding it to a reporting object.

Thanks guys.


dev: WF 7.6.5 w/IIS + Tomcat

prod: WF 7.6.5 w/IIS + Tomcat
 
Posts: 153 | Location: Chicago, IL | Registered: February 24, 2006Report This Post
Guru
posted Hide Post
ANSI is not an option for EMPTYREPORT when working in graph mode. New people like me relying on code generation will assume ON/OFF are the only options. But it works even without counting! Thank you all!


Developer Studio 7.6.11
AS400 - V5R4
HTML,PDF,XLS
 
Posts: 305 | Location: Winnipeg,MB | Registered: May 12, 2008Report This Post
Guru
posted Hide Post
quote:
Originally posted by Francis Mariani:
And it's in the manual:

SET EMPTYREPORT={ANSI|ON|OFF} where:

ANSI

Produces a single-line report and displays the missing data character or a zero if a COUNT is requested. in each case, &RECORDS will be 0, and &LINES will be 1.


If the SQL Translator is invoked, ANSI automatically replaces OFF as the default setting for EMPTYREPORT.


ON

Produces an empty report (column headings with no content). This was the default behavior in prior releases.


OFF

Produces no report output. OFF is the default value except for SQL Translator requests. When the SQL Translator is invoked, ANSI replaces OFF as the default setting for the EMPTYREPORT parameter, so the results are the same as for the ANSI setting.


The command can also be issued from within a request:

ON TABLE SET EMPTYREPORT ANSI



Hi, Have you noticed this not working in newer releases. All of a sudden EMPTYREPORT=OFF is not working. Still getting the heading and col headings as well as my zero records message. Any ideas??

Thanks

Michelle


WebFOCUS Server 8.1.05
Windows 2008 Server
WebFOCUS AppStudio 8.1.05
Windows 7 Professional
IE 11 and Chrome Version 43.0.2357.124 m.
Mostly HTML, PDF, Excel, and AHTML
 
Posts: 272 | Location: Kalamazoo, Michigan | Registered: September 30, 2010Report This Post
Virtuoso
posted Hide Post
Michelle,

I've used EMPTYREPORT in different versions of WebFOCUS and have always seen it working as documented.

See for instance:
TABLE FILE CAR
PRINT CAR
      SEATS
BY COUNTRY
HEADING
"List of Cars"
FOOTING
"Page <TABPAGENO"
WHERE COUNTRY EQ 'AUSTRALIA'
ON TABLE SET EMPTYREPORT ANSI
ON TABLE SET PAGE-NUM NOPAGE
END


This request above has no matching records but yet produces "complete" output due to EMPTYREPORT ANSI:
List of Cars
COUNTRY     CAR               SEATS
-------     ---               -----
.           .                     .
Page     .


Switching EMPTYREPORT to OFF produces no report output -as expected- in WF 7.7.03:

? REL
TABLE FILE CAR
PRINT CAR
      SEATS
BY COUNTRY
HEADING
"List of Cars"
FOOTING
"Page <TABPAGENO"
WHERE COUNTRY EQ 'AUSTRALIA'
ON TABLE SET EMPTYREPORT OFF
ON TABLE SET PAGE-NUM NOPAGE
END


Result:

--------------------------------------------------------------------------------
Your request did not return any output to display.
Possible causes:
- No data rows matched the specified selection criteria.
- Output was directed to a destination such as a file or printer.
- An error occurred during the parsing or running of the request. 
--------------------------------------------------------------------------------
EDA7703 Release * Current Software:
 EDA7703 Release RELEASE = R727703B
 EDA7703 Release GEN_NUM = 567
 EDA7703 Release SOURCE_DATE = 06/02/2011 18:09:19
 EDA7703 Release BUILD_DATE = 06/02/2011 21:07:19
 EDA7703 Release INSTALLATION_DATE = 8/26/2011 15:27:32
 0 NUMBER OF RECORDS IN TABLE=        0  LINES=      0


Could you post the code you are using (including any settings) showing the behaviour you describe?



Prod/Dev: WF Server 8008/Win 2008 - WF Client 8008/Win 2008 - Dev. Studio: 8008/Windows 7 - DBMS: Oracle 11g Rel 2
Test: Dev. Studio 8008 /Windows 7 (Local) Output:HTML, EXL2K.
 
Posts: 1533 | Registered: August 12, 2005Report This Post
Guru
posted Hide Post
quote:
ON TABLE SET EMPTYREPORT OFF


My Code:
-* File maybe_cancel.fex
-*---------------------------------------------------------------------------------
-* Programmer:  Michelle Adams
-* Date:  July 28, 2011
-*---------------------------------------------------------------------------------
-* Program Purpose: Produces a list of courses with less than 50 percent enrollment.
-*
-*
-*---------------------------------------------------------------------------------
-* Output type: User defined
-*---------------------------------------------------------------------------------
-* Confidentiality Indicator used: No
-*---------------------------------------------------------------------------------
-* Dead Indicator used: No
-*---------------------------------------------------------------------------------
-* Other Procedures/Files: Displayed with HTML launch page,
-* maybe_cancel_courses.html
-*---------------------------------------------------------------------------------
-* Parameters:  Term Code, Campus Code, Subject Code, Output.
-*
-*---------------------------------------------------------------------------------
-* Tables: STG_CURR_REG_TERM, COURSE_HISTORY_DIM, COURSE_MEETING_HISTORY_DIM,
-*         FACULTY_ASSIGNMENT_FACT, PEOPLE_FACULTY_DIM
-*---------------------------------------------------------------------------------
-* UPDATES:
-*
-*
-*
-*---------------------------------------------------------------------------------
? R
SET NODATA = na
SET DROPBLNKLINE = OFF
SET PRINTPLUS = ON
SET SQUEEZE = OFF
SET ORIENTATION = LANDSCAPE
SET PAGE-NUM = NOPAGE
SET PAGESIZE = LETTER
SET UNITS = INCHES
SET EMPTYREPORT=OFF
-SET &MYSTYLE = IF &WFFMT EQ PDF THEN 'kvcc_wf.sty' ELSE 'kvcc_wf_no_logo.sty';
-SET &USR = GETUSER(USERID);
 
JOIN
 STG_CURR_REG_TERM.STG_CURR_REG_TERM.CURR_REG_TERM IN STG_CURR_REG_TERM
 TO MULTIPLE COURSE_HISTORY_DIM.COURSE_HISTORY_DIM.TERM_CODE
 IN COURSE_HISTORY_DIM TAG J0 AS J0
 END
JOIN
 J0.COURSE_HISTORY_DIM.COURSE_HISTORY_KEY IN STG_CURR_REG_TERM TO MULTIPLE
 COURSE_MEETING_HISTORY_DIM.COURSE_MEETING_HISTORY_DIM.COURSE_HISTORY_KEY
 IN COURSE_MEETING_HISTORY_DIM TAG J3 AS J3
 END
JOIN
 J3.COURSE_MEETING_HISTORY_DIM.COURSE_HISTORY_KEY
 AND J3.COURSE_MEETING_HISTORY_DIM.MEETING_SCHEDULE_CODE IN STG_CURR_REG_TERM
 TO MULTIPLE FACULTY_ASSIGNMENT_FACT.FACULTY_ASSIGNMENT_FACT.COURSE_HISTORY_KEY
 AND FACULTY_ASSIGNMENT_FACT.FACULTY_ASSIGNMENT_FACT.SCHEDULE_CODE
 IN FACULTY_ASSIGNMENT_FACT TAG J4 AS J4
 END
JOIN
 J4.FACULTY_ASSIGNMENT_FACT.PEOPLE_KEY AND J4.FACULTY_ASSIGNMENT_FACT.TERM_CODE
 IN STG_CURR_REG_TERM TO MULTIPLE
 PEOPLE_FACULTY_DIM.PEOPLE_FACULTY_DIM.PEOPLE_KEY
 AND PEOPLE_FACULTY_DIM.PEOPLE_FACULTY_DIM.TEACHING_TERM IN PEOPLE_FACULTY_DIM
 TAG J5 AS J5
 END
 
DEFINE FILE STG_CURR_REG_TERM
NEW_DAY_TIME/HMTDYYIA=HGETC(8, NEW_DAY_TIME);
CR_HRS/P9.1=J0.COURSE_HISTORY_DIM.CREDIT_HOURS;
BLNKCOLUMN/A25=' ';
Course/A12=J0.COURSE_HISTORY_DIM.SUBJECT_CODE | J0.COURSE_HISTORY_DIM.COURSE_NUMBER;
BEGIN_OUT/A8V=IF J3.COURSE_MEETING_HISTORY_DIM.BEGIN_TIME EQ MISSING OR J3.COURSE_MEETING_HISTORY_DIM.BEGIN_TIME EQ ' ' THEN 'na' ELSE J3.COURSE_MEETING_HISTORY_DIM.BEGIN_TIME;
END_OUT/A8V=IF J3.COURSE_MEETING_HISTORY_DIM.END_TIME EQ MISSING OR J3.COURSE_MEETING_HISTORY_DIM.END_TIME LIKE ' ' THEN 'na' ELSE J3.COURSE_MEETING_HISTORY_DIM.END_TIME;
DAYS_OUT/A30V=IF J3.COURSE_MEETING_HISTORY_DIM.daysNoSpaces EQ MISSING OR J3.COURSE_MEETING_HISTORY_DIM.daysNoSpaces EQ ' ' THEN 'na' ELSE J3.COURSE_MEETING_HISTORY_DIM.daysNoSpaces;
percent_enrolled/I3=
IF J0.COURSE_HISTORY_DIM.ACTUAL_ENROLLMENT LT 1
OR J0.COURSE_HISTORY_DIM.MAX_ENROLLMENT LT 1
THEN 0
ELSE ((J0.COURSE_HISTORY_DIM.ACTUAL_ENROLLMENT / J0.COURSE_HISTORY_DIM.MAX_ENROLLMENT) * 100);
ROOM_OUT/A10V=LCWORD(10, J3.COURSE_MEETING_HISTORY_DIM.ROOM_NUMBER, 'A10V');
END
 
TABLE FILE STG_CURR_REG_TERM
PRINT
     J3.COURSE_MEETING_HISTORY_DIM.ROOM_OUT AS 'Rm'
     J3.COURSE_MEETING_HISTORY_DIM.DAYS_OUT AS 'Days'
     J3.COURSE_MEETING_HISTORY_DIM.BEGIN_OUT AS 'Begin,Time'
     J3.COURSE_MEETING_HISTORY_DIM.END_OUT AS 'End,Time'
     J0.COURSE_HISTORY_DIM.COURSE_STATUS_DESC AS 'Course,Status'
BY  LOWEST J0.COURSE_HISTORY_DIM.TERM_CODE NOPRINT
BY  LOWEST J3.COURSE_MEETING_HISTORY_DIM.CAMPUS_CODE NOPRINT  AS 'Camp'
BY  LOWEST J3.COURSE_MEETING_HISTORY_DIM.BUILDING_CODE NOPRINT  AS 'Bldg'
BY  LOWEST J0.COURSE_HISTORY_DIM.COLLEGE_CODE NOPRINT  AS 'Coll'
BY  J0.COURSE_HISTORY_DIM.Course NOPRINT  AS 'Crse'
BY  J0.COURSE_HISTORY_DIM.COURSE_TITLE NOPRINT  AS 'Title:'
BY  LOWEST J0.COURSE_HISTORY_DIM.CRN NOPRINT  AS 'CRN:'
BY  LOWEST J5.PEOPLE_FACULTY_DIM.FULL_NAME NOPRINT  AS 'Instructor:'
BY TOTAL COMPUTE MYCNTR/I5C = IF J0.COURSE_HISTORY_DIM.COURSE_HISTORY_KEY EQ LAST J0.COURSE_HISTORY_DIM.COURSE_HISTORY_KEY THEN 0 ELSE 1; NOPRINT
BY  LOWEST BLNKCOLUMN AS ''
BY  LOWEST BLNKCOLUMN AS ''
BY  LOWEST J0.COURSE_HISTORY_DIM.CR_HRS AS 'Cr,Hrs'
BY  LOWEST J0.COURSE_HISTORY_DIM.PART_OF_TERM_CODE AS 'Prt,Trm'
BY  LOWEST J0.COURSE_HISTORY_DIM.MAX_ENROLLMENT AS 'Max,Seats'
BY  LOWEST J0.COURSE_HISTORY_DIM.ACTUAL_ENROLLMENT AS 'Act,Reg'
BY  LOWEST J0.COURSE_HISTORY_DIM.percent_enrolled AS '%,Enrl'
BY  HIGHEST J3.COURSE_MEETING_HISTORY_DIM.MEETING_SCHEDULE_DESC AS 'Schedule'
 
ON J3.COURSE_MEETING_HISTORY_DIM.CAMPUS_CODE SUBHEAD
"Campus: <J3.COURSE_MEETING_HISTORY_DIM.CAMPUS_DESC"
 
ON J3.COURSE_MEETING_HISTORY_DIM.BUILDING_CODE SUBHEAD
"Building:<+0> <J3.COURSE_MEETING_HISTORY_DIM.BUILDING_DESC"
 
ON J0.COURSE_HISTORY_DIM.COLLEGE_CODE SUBHEAD
"College:<+0> <J0.COURSE_HISTORY_DIM.COLLEGE_DESC"
 
ON J0.COURSE_HISTORY_DIM.Course SUBHEAD
" "
"   Course Number:<+0> <J0.COURSE_HISTORY_DIM.Course"
 
ON J0.COURSE_HISTORY_DIM.COURSE_TITLE SUBHEAD
"   Course:<+0> <J0.COURSE_HISTORY_DIM.COURSE_TITLE"
 
ON J0.COURSE_HISTORY_DIM.CRN SUBHEAD
"   CRN:<+0> <J0.COURSE_HISTORY_DIM.CRN"
 
ON J5.PEOPLE_FACULTY_DIM.FULL_NAME SUBHEAD
"      Instructor:<+0> <J5.PEOPLE_FACULTY_DIM.FULL_NAME"
HEADING
 
"<NEW_DAY_TIME "
" "
"Potential Cancellations Due To Low Enrollment"
"<J0.COURSE_HISTORY_DIM.TERM_DESC"
-IF &CAMPUS_CODE EQ _FOC_NULL THEN GOTO ALLCAMP;
"<J3.COURSE_MEETING_HISTORY_DIM.CAMPUS_DESC"
-GOTO NEXTUP;
-ALLCAMP
"All Campuses"
-NEXTUP
-IF &SUBJECT_CODE EQ _FOC_NULL THEN GOTO ALLSUBS;
"Subject: <J0.COURSE_HISTORY_DIM.SUBJECT_CODE_DESC "
-GOTO KEEPGOING;
-ALLSUBS
"All Subjects"
-KEEPGOING
" "
 
FOOTING BOTTOM
"Page <TABPAGENO of <TABLASTPAGE"
ON TABLE SUBFOOT
" "
"Total Courses:  <CT.MYCNTR"
" "
" "
" "
"Parameters Chosen:"
"Term Code: &TERM_CODE"
-IF &CAMPUS_CODE EQ _FOC_NULL THEN GOTO ALLCAMPFOOT;
"Campus Code: &CAMPUS_CODE"
-GOTO MOVEON;
-ALLCAMPFOOT
"Campus Code: All"
-MOVEON
-IF &SUBJECT_CODE EQ _FOC_NULL THEN GOTO ALLSUBJFOOT;
"Subject Code: &SUBJECT_CODE"
-GOTO THEEND;
-ALLSUBJFOOT
"Subject Code: All"
-THEEND
"Output: &WFFMT"
" "
" "
"Report Name:<+0> &FOCFEXNAME"
"Run By:<+0> &USR"
"- end of report - "
WHERE J0.COURSE_HISTORY_DIM.ACTIVE_FLAG EQ 1;
WHERE J3.COURSE_MEETING_HISTORY_DIM.ACTIVE_FLAG EQ 1;
WHERE TOTAL J0.COURSE_HISTORY_DIM.percent_enrolled LT 50;
WHERE J0.COURSE_HISTORY_DIM.TERM_CODE EQ '&TERM_CODE';
WHERE J3.COURSE_MEETING_HISTORY_DIM.CAMPUS_CODE EQ '&CAMPUS_CODE';
WHERE J0.COURSE_HISTORY_DIM.SUBJECT_CODE EQ '&SUBJECT_CODE';
WHERE J0.COURSE_HISTORY_DIM.COURSE_NUMBER NE '278';
WHERE J0.COURSE_HISTORY_DIM.PART_OF_TERM_CODE NE 'M' OR 'N' OR 'P' OR 'X' OR 'W';
ON TABLE SET PAGE-NUM NOPAGE
ON TABLE SET EMPTYREPORT OFF
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT &WFFMT.(<HTML,HTML>,<PDF,PDF>,<Excel,EXL07>,< Active HTML,AHTML>).Select type of display output.
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
	 INCLUDE = &MYSTYLE,
$
     LEFTMARGIN=0.250000,
     RIGHTMARGIN=0.250000,
     TOPMARGIN=0.500000,
     BOTTOMMARGIN=0.000000,
     ORIENTATION=LANDSCAPE,
$
TYPE=REPORT,
     GRID=OFF,
     FONT='VERDANA',
     SIZE=9,
     COLOR='BLACK',
     STYLE=NORMAL,
     LEFTGAP=0.000000,
     TOPGAP=0.000000,
     BOTTOMGAP=0.000000,
$
TYPE=DATA,
     FONT='VERDANA',
     SIZE=9,
$
TYPE=DATA,
     COLUMN=N21,
     FONT='VERDANA',
     SIZE=9,
     JUSTIFY=LEFT,
$
TYPE=DATA,
     COLUMN=N20,
     FONT='VERDANA',
     SIZE=9,
     JUSTIFY=LEFT,
$
TYPE=DATA,
     COLUMN=N10,
     JUSTIFY=RIGHT,
$
TYPE=DATA,
     COLUMN=N11,
     JUSTIFY=RIGHT,
$
TYPE=DATA,
     COLUMN=N12,
     JUSTIFY=RIGHT,
$
TYPE=DATA,
     COLUMN=N13,
     JUSTIFY=RIGHT,
$
TYPE=DATA,
     COLUMN=N14,
     JUSTIFY=RIGHT,
$
TYPE=DATA,
     COLUMN=N5,
     JUSTIFY=LEFT,
$
TYPE=DATA,
     COLUMN=N7,
     JUSTIFY=LEFT,
$
TYPE=DATA,
     COLUMN=N6,
     JUSTIFY=LEFT,
$
TYPE=DATA,
     COLUMN=N19,
     JUSTIFY=LEFT,
$
TYPE=DATA,
     COLUMN=N17,
     JUSTIFY=LEFT,
$
TYPE=DATA,
     COLUMN=N16,
     JUSTIFY=RIGHT,
$
TYPE=DATA,
     COLUMN=N15,
     JUSTIFY=RIGHT,
$
TYPE=DATA,
     COLUMN=N18,
     JUSTIFY=LEFT,
$
TYPE=DATA,
     COLUMN=N9,
     JUSTIFY=LEFT,
$
TYPE=DATA,
     COLUMN=N8,
     JUSTIFY=LEFT,
$
TYPE=DATA,
     COLUMN=ROWTOTAL(*),
     FONT='VERDANA',
     SIZE=9,
$
TYPE=TITLE,
     FONT='VERDANA',
     SIZE=9,
     STYLE=NORMAL,
$
TYPE=TITLE,
     COLUMN=N21,
     FONT='VERDANA',
     SIZE=9,
     JUSTIFY=LEFT,
$
TYPE=TITLE,
     COLUMN=N20,
     FONT='VERDANA',
     SIZE=9,
     JUSTIFY=LEFT,
$
TYPE=TITLE,
     COLUMN=N10,
     JUSTIFY=LEFT,
$
TYPE=TITLE,
     COLUMN=N11,
     JUSTIFY=LEFT,
$
TYPE=TITLE,
     COLUMN=N12,
     JUSTIFY=LEFT,
$
TYPE=TITLE,
     COLUMN=N13,
     JUSTIFY=LEFT,
$
TYPE=TITLE,
     COLUMN=N14,
     JUSTIFY=LEFT,
$
TYPE=TITLE,
     COLUMN=N5,
     JUSTIFY=LEFT,
$
TYPE=TITLE,
     COLUMN=N7,
     JUSTIFY=LEFT,
$
TYPE=TITLE,
     COLUMN=N6,
     JUSTIFY=LEFT,
$
TYPE=TITLE,
     COLUMN=N19,
     JUSTIFY=LEFT,
$
TYPE=TITLE,
     COLUMN=N17,
     JUSTIFY=LEFT,
$
TYPE=TITLE,
     COLUMN=N16,
     JUSTIFY=LEFT,
$
TYPE=TITLE,
     COLUMN=N15,
     JUSTIFY=LEFT,
$
TYPE=TITLE,
     COLUMN=N18,
     JUSTIFY=LEFT,
$
TYPE=TITLE,
     COLUMN=N9,
     JUSTIFY=LEFT,
$
TYPE=TITLE,
     COLUMN=N8,
     JUSTIFY=LEFT,
$
TYPE=TITLE,
     COLUMN=ROWTOTAL(*),
     FONT='VERDANA',
     SIZE=9,
     STYLE=NORMAL,
$
TYPE=TABFOOTING,
     LINE=13,
     OBJECT=TEXT,
     ITEM=1,
     STYLE=UNDERLINE,
$
TYPE=TABFOOTING,
	 LINE=14,
	 OBJECT=TEXT,
	 ITEM=1,
	 STYLE=UNDERLINE,
$
TYPE=TABFOOTING,
	 LINE=14,
	 ITEM=2,
	 STYLE=NORMAL,
$
TYPE=TABFOOTING,
     LINE=15,
     JUSTIFY=CENTER,
$
TYPE=HEADING,
     LINE=1,
     JUSTIFY=RIGHT,
$
TYPE=HEADING,
     LINE=3,
     JUSTIFY=CENTER,
$
TYPE=HEADING,
     LINE=4,
     JUSTIFY=CENTER,
$
TYPE=HEADING,
     LINE=5,
     JUSTIFY=CENTER,
$
TYPE=HEADING,
     LINE=6,
     JUSTIFY=CENTER,
$
TYPE=HEADING,
     LINE=7,
     JUSTIFY=CENTER,
$
TYPE=SUBHEAD,
     BY=2,
     LINE=1,
     OBJECT=TEXT,
     ITEM=1,
     STYLE=BOLD,
$
TYPE=SUBHEAD,
     BY=2,
     LINE=1,
     OBJECT=FIELD,
     ITEM=1,
     STYLE=BOLD,
$
TYPE=SUBHEAD,
     BY=3,
     LINE=1,
     OBJECT=TEXT,
     ITEM=1,
     STYLE=BOLD,
$
TYPE=SUBHEAD,
     BY=4,
     LINE=1,
     OBJECT=TEXT,
     ITEM=1,
     STYLE=BOLD,
$
TYPE=SUBHEAD,
     BY=5,
     LINE=2,
     OBJECT=TEXT,
     ITEM=1,
     STYLE=BOLD,
$
TYPE=SUBHEAD,
     BY=6,
     LINE=1,
     OBJECT=TEXT,
     ITEM=1,
     STYLE=BOLD,
$
TYPE=SUBHEAD,
     BY=7,
     LINE=1,
     OBJECT=TEXT,
     ITEM=1,
     STYLE=BOLD,
$
TYPE=SUBHEAD,
     BY=8,
     LINE=1,
     OBJECT=TEXT,
     ITEM=1,
     STYLE=BOLD,
$
TYPE=ACROSSVALUE,
     FONT='VERDANA',
     SIZE=9,
     COLOR='BLACK',
     STYLE=NORMAL,
     TOPGAP=0.000000,
     BOTTOMGAP=0.000000,
$
TYPE=ACROSSTITLE,
     FONT='VERDANA',
     SIZE=9,
     COLOR='BLACK',
     STYLE=NORMAL,
     TOPGAP=0.000000,
     BOTTOMGAP=0.000000,
$
TYPE=REPORT,
     COLUMN=N20,
     FONT='VERDANA',
     SIZE=9,
     COLOR='BLACK',
     STYLE=NORMAL,
$
TYPE=REPORT,
     COLUMN=N10,
     FONT='VERDANA',
     SIZE=9,
     COLOR='BLACK',
     STYLE=NORMAL,
     SQUEEZE=1.055556,
$
TYPE=REPORT,
     COLUMN=N11,
     FONT='VERDANA',
     SIZE=9,
     COLOR='BLACK',
     STYLE=NORMAL,
     SQUEEZE=1.416667,
$
TYPE=REPORT,
     COLUMN=N12,
     FONT='VERDANA',
     SIZE=9,
     COLOR='BLACK',
     STYLE=NORMAL,
$
TYPE=REPORT,
     COLUMN=N13,
     FONT='VERDANA',
     SIZE=9,
     COLOR='BLACK',
     STYLE=NORMAL,
$
TYPE=REPORT,
     COLUMN=N14,
     FONT='VERDANA',
     SIZE=9,
     COLOR='BLACK',
     STYLE=NORMAL,
$
TYPE=REPORT,
     COLUMN=N7,
     FONT='VERDANA',
     SIZE=9,
     COLOR='BLACK',
     STYLE=NORMAL,
$
TYPE=REPORT,
     COLUMN=N6,
     WRAP=0.805556,
$
TYPE=REPORT,
     COLUMN=N19,
     FONT='VERDANA',
     SIZE=9,
     COLOR='BLACK',
     STYLE=NORMAL,
$
TYPE=REPORT,
     COLUMN=N17,
     FONT='VERDANA',
     SIZE=9,
     COLOR='BLACK',
     STYLE=NORMAL,
$
TYPE=REPORT,
     COLUMN=N16,
     FONT='VERDANA',
     SIZE=9,
     COLOR='BLACK',
     STYLE=NORMAL,
$
TYPE=REPORT,
     COLUMN=N15,
     FONT='VERDANA',
     SIZE=9,
     COLOR='BLACK',
     STYLE=NORMAL,
$
TYPE=REPORT,
     COLUMN=N18,
     FONT='VERDANA',
     SIZE=9,
     COLOR='BLACK',
     STYLE=NORMAL,
$
TYPE=REPORT,
     COLUMN=N9,
     SQUEEZE=0.680556,
$
TYPE=REPORT,
     COLUMN=N8,
     FONT='VERDANA',
     SIZE=9,
     COLOR='BLACK',
     STYLE=NORMAL,
$
TYPE=REPORT,
     COLUMN=N25,
     WRAP=1.500000,
$
TYPE=REPORT,
     COLUMN=N23,
     WRAP=1.500000,
$
TYPE=REPORT,
     COLUMN=ROWTOTAL(*),
     FONT='VERDANA',
     SIZE=9,
     COLOR='BLACK',
     STYLE=NORMAL,
$
ENDSTYLE
END
-*-INCLUDE norecords.fex


*******************************************************************

With -INCLUDE norecords.fex commented out I get this result: (heading and column title with no data)

September 19 2011 8:09AM

Potential Cancellations Due To Low Enrollment
Fall 2011
Off Campus
Subject: History




Cr Prt Max Act % Begin End Course
Hrs Trm Seats Reg Enrl Schedule Rm Days Time Time Status


***********************************************************************************************

With my include file uncommented I get: (accept all I see displayed is the date line, first line of heading
and the Sorry message. It appears to be acting like empty report
is set to ON and displaying my No records message when &LINES EQ 0)


September 19 2011 8:06AM

Potential Cancellations Due To Low Enrollment
Fall 2011
Off Campus
Subject: History




Cr Prt Max Act % Begin End Course
Hrs Trm Seats Reg Enrl Schedule Rm Days Time Time Status



Sorry !
There are no matching records.
Please review and try again.


*****************************************************************************

Here is the code for my no records include file:

-IF &LINES EQ 0 THEN GOTO NORECS
- ELSE GOTO EXIT;
-NORECS
-IF &WFFMT EQ PDF THEN GOTO PDF
- ELSE GOTO HTML;
-HTML
-HTMLFORM norecords.htm
-GOTO EXIT
-PDF
-INCLUDE norecords_pdf_2.fex
-EXIT

****************************************************************

I appreciate you looking at my code. I am hoping you can see what the problem is. I have used this
no records include with all of my other reports with no problems, I am not sure why it is behaving like this now. Which makes me wonder if the Empty Report is not functioning properly since the last upgrade.

Thank you
Michelle


WebFOCUS Server 8.1.05
Windows 2008 Server
WebFOCUS AppStudio 8.1.05
Windows 7 Professional
IE 11 and Chrome Version 43.0.2357.124 m.
Mostly HTML, PDF, Excel, and AHTML
 
Posts: 272 | Location: Kalamazoo, Michigan | Registered: September 30, 2010Report This Post
Virtuoso
posted Hide Post
I can't spot any obvious reasons that explain why you are getting a report with HEADING and column titles even though you are sure no records match the selection criteria and EMPTYREPORT is indeed set to OFF.

Can you replicate that behaviour with the CAR table? if so, this is definitely a bug and you should open a case with Tech Support. I am also running 7.7.03 and have not seen this happening though.

Could you try breaking your request using a HOLD file in between to try and see where the problem might be?

JOIN ....
DEFINE FILE STG_CURR_REG_TERM
...
END
TABLE FILE STG_CURR_REG_TERM
PRINT ...
WHERE ...
ON TABLE SET EMPTYREPORT OFF
ON TABLE SET HOLDLIST PRINTONLY
ON TABLE HOLD AS HDATA
END
-EXIT


Running that would allow you to see that indeed 0 records were read and 0 records were written to the HOLD file, but if this is not the case then maybe something else is going on ...

If that works as expected, you can now try and produce your report our of the HOLD file:
TABLE FILE HDATA
PRINT ....
HEADING ...
FOOTING ...
ON TABLE SET EMPTYREPORT OFF
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET STYLE *
...
ENDSTYLE
END
-RUN


If you still get an actual report event though you know that the HOLD file has no records whatsoever and that EMPTYREPORT is OFF, then a case before Tech Support will be a must.



Prod/Dev: WF Server 8008/Win 2008 - WF Client 8008/Win 2008 - Dev. Studio: 8008/Windows 7 - DBMS: Oracle 11g Rel 2
Test: Dev. Studio 8008 /Windows 7 (Local) Output:HTML, EXL2K.
 
Posts: 1533 | Registered: August 12, 2005Report This Post
Guru
posted Hide Post
Thank you so much. I will give that try and let you know.


WebFOCUS Server 8.1.05
Windows 2008 Server
WebFOCUS AppStudio 8.1.05
Windows 7 Professional
IE 11 and Chrome Version 43.0.2357.124 m.
Mostly HTML, PDF, Excel, and AHTML
 
Posts: 272 | Location: Kalamazoo, Michigan | Registered: September 30, 2010Report This Post
Virtuoso
posted Hide Post
Try adding a -RUN before your -INCLUDE. Or put -RUN as the first command in your norecords.fex.


WebFOCUS 7.7.05
 
Posts: 1213 | Location: Seattle, Washington - USA | Registered: October 22, 2007Report This Post
Guru
posted Hide Post
Thank you Dan, but that didn't work either. I'm really stumped. I did a fex that shows I truly have no data and should not be getting the heading and titles.


WebFOCUS Server 8.1.05
Windows 2008 Server
WebFOCUS AppStudio 8.1.05
Windows 7 Professional
IE 11 and Chrome Version 43.0.2357.124 m.
Mostly HTML, PDF, Excel, and AHTML
 
Posts: 272 | Location: Kalamazoo, Michigan | Registered: September 30, 2010Report This Post
Virtuoso
posted Hide Post
Some other suggestions in trying to determine the cause:

Place the command '? SET EMPTYREPORT' both before and after the report query code to ensure the setting is turned off.

Comment out each of the other SET commands, including the PAGE-NUM NOPAGE, to see if one of them is in conflict with the EMPTYREPORT setting.

Create a simple report using the CAR file that generates zero records (example: WHERE COUNTRY EQ 'USA') and see how EMPTYREPORT=OFF and your 'No Records' message behave with that query.


If none of the above offer any possible solutions/ideas, open a case with IBI Tech Support.


WebFOCUS 7.7.05
 
Posts: 1213 | Location: Seattle, Washington - USA | Registered: October 22, 2007Report This Post
Guru
posted Hide Post
Thank you so much. I will try your suggestions.


WebFOCUS Server 8.1.05
Windows 2008 Server
WebFOCUS AppStudio 8.1.05
Windows 7 Professional
IE 11 and Chrome Version 43.0.2357.124 m.
Mostly HTML, PDF, Excel, and AHTML
 
Posts: 272 | Location: Kalamazoo, Michigan | Registered: September 30, 2010Report This Post
Virtuoso
posted Hide Post
This may be a silly question but it's better to ask anyway.

Could there something else out there that might be changing your settings during the execution of TABLE FILE?

For instance, do you by any chance use MFD_PROFILE in your master file to enforce security?



Prod/Dev: WF Server 8008/Win 2008 - WF Client 8008/Win 2008 - Dev. Studio: 8008/Windows 7 - DBMS: Oracle 11g Rel 2
Test: Dev. Studio 8008 /Windows 7 (Local) Output:HTML, EXL2K.
 
Posts: 1533 | Registered: August 12, 2005Report This Post
Guru
posted Hide Post
quote:
Originally posted by Dan Satchell:
Some other suggestions in trying to determine the cause:

Place the command '? SET EMPTYREPORT' both before and after the report query code to ensure the setting is turned off.

Comment out each of the other SET commands, including the PAGE-NUM NOPAGE, to see if one of them is in conflict with the EMPTYREPORT setting.

Create a simple report using the CAR file that generates zero records (example: WHERE COUNTRY EQ 'USA') and see how EMPTYREPORT=OFF and your 'No Records' message behave with that query.


If none of the above offer any possible solutions/ideas, open a case with IBI Tech Support.



This is what I get; shows it OFF

EMPTYREPORT OFF
0 HOLDING HTML FILE ON PC DISK ...10
NUMBER OF RECORDS IN TABLE= 1 LINES= 0
EMPTYREPORT OFF
WebFOCUS Version 7.7.03 compiled and linked on Mon Jun 6 01:04:45 EDT 2011 (Gen branch7703:126)


WebFOCUS Server 8.1.05
Windows 2008 Server
WebFOCUS AppStudio 8.1.05
Windows 7 Professional
IE 11 and Chrome Version 43.0.2357.124 m.
Mostly HTML, PDF, Excel, and AHTML
 
Posts: 272 | Location: Kalamazoo, Michigan | Registered: September 30, 2010Report This Post
Guru
posted Hide Post
For everyone that helped me and those interested, this is what I found out. I am posting my CAR file example for you to try. If there is a WHERE TOTAL clause in the fex I get the above mentioned errors. Take out the word TOTAL and the report runs fine and I get the norecords message(Sorry message as I call it).

Thank you Dan, your suggestions led me to find this. I had commented out everything pretty much and decided to see if the TOTAL was the issue, as I don't even remember putting it in.

-* File test_emptyreport.fex
? SET EMPTYREPORT
SET NODATA = na
SET DROPBLNKLINE = OFF
SET PRINTPLUS = ON
SET SQUEEZE = OFF
SET ORIENTATION = LANDSCAPE
SET PAGE-NUM = NOPAGE
SET PAGESIZE = LETTER
SET UNITS = INCHES
SET EMPTYREPORT=OFF
-SET &MYSTYLE = IF &WFFMT EQ PDF THEN 'kvcc_wf.sty' ELSE 'kvcc_wf_no_logo.sty';
-SET &USR = GETUSER(USERID);
TABLE FILE CAR
BY  LOWEST CAR.ORIGIN.COUNTRY NOPRINT 
BY  LOWEST CAR.COMP.CAR NOPRINT 
BY  LOWEST CAR.CARREC.MODEL NOPRINT  AS 'Model'
BY  CAR.BODY.SEATS
BY  CAR.BODY.DEALER_COST
     
ON CAR.ORIGIN.COUNTRY SUBHEAD
"<CAR.ORIGIN.COUNTRY "
     
ON CAR.COMP.CAR SUBHEAD
"<CAR.COMP.CAR "
     
ON CAR.CARREC.MODEL SUBHEAD
"<CAR.CARREC.MODEL "
HEADING
"This is the page heading"
FOOTING
"Page <TABPAGENO of<TABLASTPAGE "
ON TABLE SUBFOOT
" this is the footing"
WHERE TOTAL CAR.CARREC.MODEL EQ 'blue';
ON TABLE SET EMPTYREPORT OFF
ON TABLE SET PAGE-NUM OFF 
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT &WFFMT.(<HTML,HTML>,<PDF,PDF>,<Excel,EXL07>,< Active HTML,AHTML>).Select type of display output.
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     INCLUDE = kvcc_wf,
$
TYPE=TABFOOTING,
     LINE=1,
     JUSTIFY=LEFT,
$
ENDSTYLE
END
-INCLUDE norecords.fex
? SET EMPTYREPORT




NORECORDS.FEX ...............


-IF &LINES EQ 0 THEN GOTO NORECS
- ELSE GOTO EXIT;
-NORECS
-IF &WFFMT EQ PDF THEN GOTO PDF
- ELSE GOTO HTML;
-HTML
-HTMLFORM norecords.htm
-GOTO EXIT
-PDF
-INCLUDE norecords_pdf_2.fex    **change this** 
-EXIT



norecords.htm CODE



<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN">
<HTML>
<HEAD>
<META id=mycharsetmeta content="text/html; charset=ISO-8859-1" http-equiv=Content-Type>
<META id=Generation content="Created in release 7701, Generation 3.0">
<SCRIPT id=IBI_RelCallBack type=text/javascript>function AdjustChildrenPosition(){
}
</SCRIPT>
 
<SCRIPT id=IBI_OptionsScript type=text/javascript>
var cgipath = "cgipath";
var ibirls = "ibirls3";
 
var rltdyncalendar = "rltdyncalendar";
var gmap = "ibigmap";
var olap="olap";
var olappanebase="olappanebase";
var olapdrill="olapdrill";
 
var ibixmltree="ibixmltree";
 
var ibiOptions = new Array(cgipath,ibirls);
</SCRIPT>
 
<SCRIPT id=IBI_nls type=text/javascript src="/ibi_html/javaassist/nls.js"></SCRIPT>
 
<SCRIPT id=IBI_nlsVars type=text/javascript src="/ibi_html/javaassist/nlsvars.js"></SCRIPT>
 
<SCRIPT id=IBI_ibigbl type=text/javascript src="/ibi_html/javaassist/ibi/html/js/ibigbl.js"></SCRIPT>
 
<SCRIPT id=IBI_ibigblloadCss type=text/javascript>
ibigblloadCss(null);
addIntlTranslatedJS("composertrans.js");
</SCRIPT>
<TITLE>Error Page</TITLE>
<SCRIPT id=clientEventHandlersJS type=text/javascript>
//Begin function window_onload
function window_onload() {
 
UpdateData();
 
// TODO: Add your event handler code here
//add onInitialUpdate() function to make changes before initial run of the reports
 
}
//End function window_onload
</SCRIPT>
 
<SCRIPT for=window type=text/javascript eventname="onload">window.onload = function() { window_onload(); }</SCRIPT>
</HEAD>
<BODY style="Z-INDEX: 0; BACKGROUND-COLOR: white; OVERFLOW: auto" thumbnailscale="4" elementtype="21" edaconnectionrequired="false">  
<SPAN style="Z-INDEX: 2; POSITION: absolute; TEXT-ALIGN: center; LINE-HEIGHT: normal; BACKGROUND-COLOR: white; WIDTH: 832px; FONT-FAMILY: Verdana; LETTER-SPACING: normal; HEIGHT: 180px; COLOR: #0091cc; FONT-SIZE: 18pt; VERTICAL-ALIGN: middle; TOP: 110px; FONT-WEIGHT: bold; LEFT: 90px" id=text1 tabIndex=2 defaultselection="1">
<BR>
<BR>There are no matching records. 
<BR>Please review and try again. 
<LABEL style="Z-INDEX: 3; POSITION: absolute; WIDTH: 300px; FONT-FAMILY: Verdana; HEIGHT: 60px; COLOR: #0091cc; FONT-SIZE: 24pt; TOP: 0px; CURSOR: default; LEFT: 260px" id=label1 tabIndex=3>Sorry !</LABEL></SPAN>  
<INPUT style="POSITION: absolute; TOP: -100px; LEFT: -100px" id=layoutinfo type=hidden>
<INPUT style="POSITION: absolute; TOP: -100px; LEFT: -100px" id=ibiapp_app value=michelle type=hidden name="ibiapp_app">
<INPUT style="POSITION: absolute; TOP: -100px; LEFT: -100px" id=ibic_server value=EDASERVE type=hidden isdataserversarea="1" name="ibic_server">
<xml id=focus_xmlelement>
<script type="text/xml">
 
<rootxmlnode focoption="_FOC_NULL">
  
<variables></variables>
  
<input_controls></input_controls>
  
<other_bound_objects></other_bound_objects>
  
<requests></requests></rootxmlnode></script>
</xml></BODY>
<SCRIPT id=IBI_loader type=text/javascript>
doBeforeLoad();
</SCRIPT>
</HTML>



**
I hope this helps someone else someday. This original post was from 2007 and I was surprised to get responses. Thank you!

Michelle


WebFOCUS Server 8.1.05
Windows 2008 Server
WebFOCUS AppStudio 8.1.05
Windows 7 Professional
IE 11 and Chrome Version 43.0.2357.124 m.
Mostly HTML, PDF, Excel, and AHTML
 
Posts: 272 | Location: Kalamazoo, Michigan | Registered: September 30, 2010Report This Post
  Powered by Social Strata Page 1 2  

Read-Only Read-Only Topic

Focal Point    Focal Point Forums  Hop To Forum Categories  WebFOCUS/FOCUS Forum on Focal Point     Displaying footer with empty report?

Copyright © 1996-2020 Information Builders