I have a simple table req. using the CAR FILE which numbers the values when the country sort value changes.

DEFINE FILE CAR
CRCNT/I5 WITH COUNTRY = IF COUNTRY EQ LAST COUNTRY THEN CRCNT ELSE CRCNT + 1;
END
-*
TABLE FILE CAR
HEADING CENTER
"Try This Stuff"
" "
PRINT
CAR
BY CRCNT
BY COUNTRY
END
-RUN
-EXIT

As expected, I am getting this output:

CRCNT COUNTRY CAR
1 ENGLAND JAGUAR
JENSEN
TRIUMPH
2 FRANCE PEUGEOT
3 ITALY ALFA ROMEO
MASERATI
4 JAPAN DATSUN
TOYOTA
5 W GERMANY AUDI
BMW

What I'd like to do is have report actually like this:

CRCNT COUNTRY CAR
1 ENGLAND JAGUAR
1 JENSEN
1 TRIUMPH
2 FRANCE PEUGEOT
3 ITALY ALFA ROMEO
3 MASERATI
4 JAPAN DATSUN
4 TOYOTA
5 W GERMANY AUDI
5 BMW

I have been trying LAST and not it is not quite working...

Any ideas?

THANKS!

This message has been edited. Last edited by: Kerry,

Tom,

Try this:

 
DEFINE FILE CAR
CRCNT/I5 WITH COUNTRY = IF COUNTRY EQ LAST COUNTRY THEN CRCNT ELSE CRCNT + 1;
END
-*
TABLE FILE CAR
HEADING CENTER
"Try This Stuff"
" "
PRINT
CAR
BY CRCNT
BY COUNTRY
-*
ON TABLE SET BYDISPLAY ON
-*
END
-RUN
-EXIT

the code ON TABLE SET BYDISPLAY ON forces WF to display the repeating BY values. ON TABLE SET BYDISPLAY OFF is the default, so by not setting it the repeating BY values are not displayed.

Hope this helps,

Dirk your suggestion is AWESOME!!! I wrote more code to solve this problem, but I like yours better....

Here is my code for the old schoolers:

DEFINE FILE CAR
CRCNT/I5 WITH COUNTRY = IF COUNTRY EQ LAST COUNTRY THEN CRCNT ELSE CRCNT + 1;
-*
XCNT/I5 WITH COUNTRY = IF CRCNT EQ 1 AND COUNTRY NE LAST COUNTRY THEN 1
ELSE IF CRCNT EQ LAST CRCNT AND COUNTRY EQ LAST COUNTRY THEN XCNT
ELSE IF CRCNT GT 1 AND COUNTRY NE LAST COUNTRY THEN CRCNT ELSE 0;
END
-*
-*
TABLE FILE CAR
HEADING CENTER
"Try This Stuff"
" "
PRINT
XCNT AS '#'
CAR
-*
BY COUNTRY NOPRINT
ON TABLE PCHOLD FORMAT PDF
END
-RUN

Thanks!!!

Tom,

Just for the fun of it. This code worked even before the "BYDISPLAY" command was introduced.


DEFINE FILE CAR
CRCNT/I5 WITH COUNTRY = IF COUNTRY EQ LAST COUNTRY THEN CRCNT ELSE CRCNT + 1;
END
-*
TABLE FILE CAR
HEADING CENTER
"Try This Stuff"
" "
PRINT
CRCNT
COUNTRY
CAR
BY CRCNT NOPRINT
BY COUNTRY NOPRINT
-*
END
-RUN
-EXIT

Have fun,

Ahh, the days before "BYDISPLAY"... A lot has changed since then, hasn't it.

Keep in mind that, if the COUNTRY is not in the order that you want, you may need to add "BY COUNTRY NOPRINT" before your "BY CRCNT", as in:

PRINT
CAR
BY COUNTRY NOPRINT <-- here
BY CRCNT
BY COUNTRY <-- would we need this then?

Thanks JJI, for the FUN reminder. It's good to keep those old methods in mind. It helps us to realize how far we've come and how far we can go.

The following code does exactly what you wanted to do according to your first post:

TABLE FILE CAR
HEADING CENTER
"Try This Stuff"
" "
PRINT
COMPUTE CRCNT/I5 WITH COUNTRY = IF COUNTRY EQ LAST COUNTRY THEN CRCNT ELSE CRCNT + 1; AS '#'
COMPUTE CRCNTRY/A10 WITH CAR = IF COUNTRY EQ LAST COUNTRY THEN ' ' ELSE COUNTRY; AS 'COUNTRY'
CAR
BY COUNTRY NOPRINT
BY CRCNT NOPRINT
END 

Hope this helps ...

quote:

Thanks JJI, for the FUN reminder. It's good to keep those old methods in mind. It helps us to realize how far we've come and how far we can go.

Hi Doug,
Thanks for your appreciation. These oldies come in handy from time to time and make sometimes the difference in getting the report you want or not. That's why I like this forum so much. We can all learn from each other and this forum can also inspire the developers to further improve the WF products.