By default in PDF output, SUBTOTALS are indented rather than left justified like the data rows above. Is there some setting that will remove the subtotal indentation?

Thanks,
Bethany

Can you give an example with the CAR file of what you are seeing?

Bethany,

Are you saying that the default subtotal break has a * as first character? If so, you can use the AS option:

  
-* File bethany4.fex
TABLE FILE CAR
PRINT SALES RETAIL_COST
BY COUNTRY BY CAR
ON COUNTRY SUBTOTAL AS 'Total'
ON TABLE PCHOLD FORMAT PDF
END

I figured out what was going on. Here's an example with the CAR table.

  TABLE FILE CAR
SUM
     RETAIL_COST
BY COUNTRY NOPRINT
BY BODYTYPE
BY CAR
ON COUNTRY SUBHEAD
"<COUNTRY "
ON COUNTRY SUBTOTAL AS 'TOTAL'
ON BODYTYPE SUBTOTAL AS 'TOTAL'
  ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
LEFTMARGIN=0.65,
RIGHTMARGIN=0.0,
TOPMARGIN=0.00,
BOTTOMMARGIN=0.00,
TOPGAP=0.015,
BOTTOMGAP=0.015,
RIGHTGAP=0.028,
LEFTGAP=0.028,
ORIENTATION=PORTRAIT,
SQUEEZE=ON,
$
TYPE=REPORT,FONT='TIMES NEW ROMAN',SIZE=8,COLOR='BLACK', BACKCOLOR='NONE', STYLE=NORMAL,$
TYPE=TITLE, BORDER-BOTTOM=LIGHT, STYLE=BOLD,JUSTIFY=CENTER,$
TYPE=SUBHEAD, STYLE=BOLD,$
TYPE=SUBTOTAL, BY=1, BORDER=LIGHT, BORDER-COLOR=WHITE, STYLE=BOLD,$
TYPE=SUBTOTAL, BY=2, BORDER=LIGHT, BORDER-COLOR=WHITE, STYLE=BOLD,$
TYPE=SUBTOTAL, BY=1, BORDER-TOP=LIGHT, BORDER-TOP-COLOR=BLACK, BORDER-BOTTOM=HEAVY, BORDER-BOTTOM-COLOR=BLACK,$
TYPE=SUBTOTAL, BY=1, COLUMN=LINE, BORDER-TOP=OFF,BORDER-BOTTOM=OFF,$
TYPE=SUBTOTAL, BY=2, BORDER-TOP=LIGHT, BORDER-TOP-COLOR=BLACK,$
TYPE=SUBTOTAL, BY=2, COLUMN=LINE, BORDER-TOP=OFF,BORDER-BOTTOM=OFF,$
ENDSTYLE
END

Using the above code, the TOTAL ENGLAND, TOTAL SEDAN, etc. were getting indented so they began to the right of the data rows information. I found that the formatting causing this is: TYPE=SUBTOTAL, BY=1, BORDER=LIGHT, BORDER-COLOR=WHITE, STYLE=BOLD,$ which is necessary to include so that you don't get a blank space above the subtotal and below the data that's being summed. Changing this piece of code to:

TYPE=SUBTOTAL, BY=1, BORDER-TOP=LIGHT, BORDER-COLOR=WHITE, STYLE=BOLD,$
TYPE=SUBTOTAL, BY=2, BORDER-TOP=LIGHT, BORDER-COLOR=WHITE, STYLE=BOLD,$

still kept the subtotal immediately beneath the data without the unwanted space and kept the TOTAL ENGLAND, TOTAL SEDAN of the subtotal justified left.

Bethany