Hi,
I want to arrange the subtotal of sorted fields.
I need the subtotal of a column to be displayed below that column instead in the starting.
I am using the below code, please suggest how to do this?
-SET &ECHO = ALL;
SET SHOWBLANKS = ON
SET NODATA = '';
SET EMPTYREPORT=ON
SET BYDISPLAY = OFF

TABLE FILE CAR
SUM
DEALER_COST AS 'Dealer Cost'
RETAIL_COST AS 'Retail Cost'
BY COUNTRY
BY CAR
BY MODEL
ON TABLE SUBHEAD
" "
ON TABLE SET PAGE-NUM OFF
ON COUNTRY SUBTOTAL AS 'Total -'
ON CAR SUBTOTAL AS 'Total -'
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
UNITS=IN,
SQUEEZE=ON,
ORIENTATION=PORTRAIT,
$
TYPE=REPORT,
GRID=ON,
FONT='VERDANA',
SIZE=10,
COLOR='BLACK',
BACKCOLOR='NONE',
STYLE=NORMAL,
$
UNITS=IN,SQUEEZE=ON,ORIENTATION=PORTRAIT,
$
TYPE=TITLE,
FONT='VERDANA',
BACKCOLOR=RGB(190 190 190),
STYLE=-UNDERLINE+BOLD,
JUSTIFY=CENTER,
$
TYPE=TABHEADING,
STYLE=BOLD,
$
TYPE=SUBTOTAL,
BY = COUNTRY,
FONT='VERDANA',
BACKCOLOR=RGB(200 220 170),
STYLE=BOLD,
$
TYPE=SUBTOTAL,
BY = CAR,
FONT='VERDANA',
BACKCOLOR= RGB(110 130 250),
STYLE=BOLD,
$
ENDSTYLE
END
-RUN

Thanks in advance.

This message has been edited. Last edited by: Mayank Agrawal,

Mayank,

Try this:

  
-SET &ECHO = ALL;
SET SHOWBLANKS = ON
SET NODATA = '';
SET EMPTYREPORT=ON
SET BYDISPLAY = OFF
DEFINE FILE CAR
TCOUNTRY/A16='Total-' | COUNTRY;
TCAR/A24='Total-' | CAR;
END
TABLE FILE CAR
SUM
DEALER_COST AS 'Dealer Cost'
RETAIL_COST AS 'Retail Cost'
BY COUNTRY
BY CAR
BY MODEL
ON TABLE SUBHEAD
" "
ON TABLE SET PAGE-NUM OFF
ON COUNTRY SUBFOOT
"<TCOUNTRY <+0> <ST.DEALER_COST<ST.RETAIL_COST"
ON CAR SUBFOOT
" <TCAR <ST.DEALER_COST<ST.RETAIL_COST"
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TYPE=SUBFOOT, HEADALIGN=BODY, JUSTIFY=RIGHT, $
TYPE=SUBFOOT, BY=COUNTRY, LINE=1,ITEM=1, JUSTIFY=LEFT, $
TYPE=SUBFOOT, BY=CAR, LINE=1,ITEM=2, JUSTIFY=LEFT, $
END

Thanks Danny ....!!
It is Really very helpful and it is as per my requirement.
Thanks again....!!

Can anyone tell me how to mark my query as Resolved?

Just go back to your original post. At the bottom right you will see a little pencil-eraser icon. Click it and you can edit the post - including changing the first word(s) of the subject line to: [CLOSED]or [RESOLVED] or even [ANNOYED THAT THERE IS NO SOLUTION TO MY PROBLEM BUT I GIVE UP]