I want to create a dynamic default setting in my prompts fo date values.
this issue is brought up before, but I was trying this:

-* File datumcreatie.fex
FILEDEF DATUMS DISK baseapp/datumwaarden.fex
SET HOLDLIST=PRINTONLY
DEFINE FILE CAR
D1/YYMD WITH COUNTRY=DATEMOV('&YYMD','EOM');
D2/YYMD WITH COUNTRY=DATEMOV('&YYMD','BOM')-1;
D3/YYMD WITH COUNTRY=DATEMOV(D2,'BOM')-1;
END
TABLE FILE CAR
PRINT
     COUNTRY NOPRINT
HEADING
"-DEFAULT &|PRODATUM1= <D2 ;"
"-DEFAULT &|PRODATUM2= <D3 ;"
FOOTING
""
WHERE COUNTRY EQ 'ITALY';
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL
ON TABLE SAVE AS DATUMS FORMAT WP
END

This code seems to work, but my output file is not as it should be.

this is what I get

1

  -DEFAULT &PRODATUM1= 2009/12/31 ;
  -DEFAULT &PRODATUM2= 2009/11/30 ;

Looks rather good, but the spaces in front of the dash is giving me some trouble.
Any other idea based on this would be helpfull.

This message has been edited. Last edited by: Kerry,

Not necessarily simpler but would this option work perhaps?

  
-* File datumcreatie.fex
FILEDEF DATUMS DISK baseapp/datumwaarden.fex
SET HOLDLIST=PRINTONLY
DEFINE FILE CAR
D1/YYMD WITH COUNTRY=DATEMOV('&YYMD','EOM');
D2/YYMD WITH COUNTRY=DATEMOV('&YYMD','BOM')-1;
D3/YYMD WITH COUNTRY=DATEMOV(D2,'BOM')-1;
-*
-* Define as many dates as needed based on DATE_SQ
DATE_SQ/I4 WITH COUNTRY = DATE_SQ + 1;
DEF_DATE/A32 = IF DATE_SQ EQ 1 THEN '-DEFAULT &|PRODATUM1 = ' | DATECVT(D2, 'YYMD', 'A8YYMD') | ';' ELSE
               IF DATE_SQ EQ 2 THEN '-DEFAULT &|PRODATUM2 = ' | DATECVT(D3, 'YYMD', 'A8YYMD') | ';' ELSE ' ';
END
TABLE FILE CAR
PRINT
     COUNTRY NOPRINT
     DEF_DATE
WHERE RECORDLIMIT EQ 2
ON TABLE SAVE AS DATUMS FORMAT ALPHA
END

It gets around the formatting issue (the unwanted page number and leading blanks).

You may define as many dates as you need by tweaking DEF_DATE and RECORDLIMIT provided the supporting table (CAR in this case) has as many available records; otherwise McGyver can come to the rescue

- Neftali.

This message has been edited. Last edited by: njsden,

If it's just to find out the end of the two previous months, then you could do this just as easily in DM only:

-SET &YYM = EDIT(&YYMD,'999999');
-SET &D0  = EDIT(&YYMD,'999999') | '01';
-SET &D1  = AYM(&YYM,-1,'I6') * 100 + 1;
-SET &D2I = AYMD(&D0,-1,'I8');
-SET &D3I = AYMD(&D1,-1,'I8');
-SET &D2  = EDIT(&D2I,'9999/99/99');
-SET &D3  = EDIT(&D3I,'9999/99/99');

APP FI DATUMS DISK BASEAPP/datumwaarden.fex
-RUN
-WRITE DATUMS -DEFAULT &|PRODATUM1 = &D2
-WRITE DATUMS -DEFAULT &|PRODATUM2 = &D3

Hope this helps...