Focal Point Banner
Community Center Education Summit Technical Support User Groups
Let's Get Social!

Facebook Twitter LinkedIn YouTube
Focal Point    Focal Point Forums  Hop To Forum Categories  WebFOCUS/FOCUS Forum on Focal Point     [SOLVED] Style subtotal field BY
Go
New
Search
Notify
Tools
Reply
  
[SOLVED] Style subtotal field BY
 Login/Join
 
Guru
posted
Hello,

How do I style the first BY on a subtotal?

 -* File: IBFS:/WebFOCUS 8X DEV/WFC/Repository/vesir218/std_reports/vesirreports/Procedure1.fex Created by WebFOCUS AppStudio

SET SUBTOTALS=ABOVE
TABLE FILE HTAB54X

SUM
VOL_1 AS 'Jan'
VOL_2 AS 'Fev'
VOL_3 AS 'Mar'
VOL_4 AS 'Abr'
VOL_5 AS 'Mai'
VOL_6 AS 'Jun'
VOL_7 AS 'Jul'
VOL_8 AS 'Ago'
VOL_9 AS 'Set'
VOL_10 AS 'Out'
VOL_11 AS 'Nov'
VOL_12 AS 'Dez'
BY REGIONAL 
BY DEALER 
BY SRSD39_GROUP_X AS 'Modelo'
IF SRSD02_REGIONAL_C EQ '&SRSD02_REGIONAL_C'

ON REGIONAL SUBTOTAL AS ''
ON DEALER SUBTOTAL AS ''
ON TABLE  SUBFOOT
"Grand Total:<+0><+0><+0><TOT.VOL_1<TOT.VOL_2<TOT.VOL_3<TOT.VOL_4<TOT.VOL_5<TOT.VOL_6<TOT.VOL_7<TOT.VOL_8<TOT.VOL_9<TOT.VOL_10<TOT.VOL_11<TOT.VOL_12"
HEADING CENTER
""
""
"&TIPO - Mês a Mês &ANO"
"&TITULO <REGIONAL "
ON TABLE PCHOLD FORMAT XLSX &EXCEL_BREAK
ON TABLE ROW-TOTAL AS 'YTD'
ON TABLE NOTOTAL
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE SET STYLE *
TYPE=REPORT,
TITLETEXT='Regional &SRSD02_REGIONAL_C',
SIZE=6,
PAGESIZE=A3,
-*SQUEEZE=ON,
ORIENTATION=PORTRAIT,
GRID=OFF,
$
TYPE=TABFOOTING, HEADALIGN=BODY, $

TYPE=HEADING,
     IMAGE=IBFS:/WFC/Repository/vesir218/std_reports/vesirreports/ford_logo.jpg,
     POSITION=(+0.000000 +0.000000),
     SIZE=(0.597222 0.250000),
$


TYPE=HEADING,
LINE=3,
STYLE=BOLD,
SIZE=10,
$
TYPE=HEADING,
LINE=4,
STYLE=BOLD,
SIZE=9,
$

TYPE=TITLE,
STYLE=BOLD,
SIZE=8,
BACKCOLOR=RGB(46 157 198),
$
TYPE=TABFOOTING,
-*BACKCOLOR=RGB(192 192 192),
BACKCOLOR='LIGHT GREY',
STYLE=BOLD,
$

TYPE=DATA,
COLUMN=SRSD39_GROUP_X,
JUSTIFY=RIGHT,
$
TYPE=SUBTOTAL,
BY=1,
COLUMN=REGIONAL,
COLOR='RED',
COLSPAN=3,
STYLE=BOLD,
$



END
 

This message has been edited. Last edited by: Ricardo Augusto,


WebFOCUS 8.1.05 / APP Studio
 
Posts: 272 | Location: Brazil | Registered: October 31, 2006Reply With QuoteReport This Post
Guru
posted Hide Post
Hello, I need to manipulate the SUBTOTALS, but I can only apply style to the values.

I need to apply style on the SUBTOTAL field REGIONAL. I will try to reproduce it using files from ibisamp.

thanks


WebFOCUS 8.1.05 / APP Studio
 
Posts: 272 | Location: Brazil | Registered: October 31, 2006Reply With QuoteReport This Post
Guru
posted Hide Post
I got it.


TYPE=SUBTOTAL,
BY=1,
OBJECT=TAG,
BACKCOLOR='LIGHT GREY',
JUSTIFY=CENTER,
COLSPAN=2,
STYLE=BOLD,
$

TYPE=SUBTOTAL,
BY=1,
BACKCOLOR='LIGHT GREY',
STYLE=BOLD,
$

TYPE=SUBTOTAL,
BY=2,
OBJECT=TAG,
BACKCOLOR=RGB(192 192 192),
JUSTIFY=CENTER,
COLSPAN=2,
STYLE=BOLD,
$
TYPE=SUBTOTAL,
BY=2,
BACKCOLOR=RGB(192 192 192),
STYLE=BOLD,
$


WebFOCUS 8.1.05 / APP Studio
 
Posts: 272 | Location: Brazil | Registered: October 31, 2006Reply With QuoteReport This Post
Virtuoso
posted Hide Post
Wouldn't this be what you want?
 
-* File ricardo04.fex
TABLE FILE CAR
PRINT 
     SALES
     DEALER_COST
     RETAIL_COST
BY  LOWEST COUNTRY
BY  LOWEST CAR
BY  MODEL
     
ON COUNTRY SUBTOTAL AS '*Total Country'
     
ON CAR SUBTOTAL AS '*Total Car'
ON TABLE SET PAGE-NUM NOLEAD 
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     INCLUDE = endeflt,
$
TYPE=SUBTOTAL,
     BY=1,
     COLOR='RED',
$
ENDSTYLE
END


Daniel
In Focus since 1982
wf 8.202M/Win10/IIS/SSA - WrapApp Front End for WF

 
Posts: 1934 | Location: Tel Aviv, Israel | Registered: March 23, 2006Reply With QuoteReport This Post
Guru
posted Hide Post
I want something like this, but it didnt work on my code.

 

TABLE FILE CAR
PRINT 
     SALES
     DEALER_COST
     RETAIL_COST
BY  LOWEST COUNTRY
BY  LOWEST CAR
BY  MODEL
     
ON COUNTRY SUBTOTAL AS ''
     
ON CAR SUBTOTAL AS ''
ON TABLE SET PAGE-NUM NOLEAD 
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT XLSX
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     INCLUDE = endeflt,
$
TYPE=SUBTOTAL,
     BY=1,
     COLOR='RED',
	 OBJECT=TAG,
	 JUSTIFY=CENTER,
	 COLSPAN=2,
$
ENDSTYLE
END
 


WebFOCUS 8.1.05 / APP Studio
 
Posts: 272 | Location: Brazil | Registered: October 31, 2006Reply With QuoteReport This Post
Guru
posted Hide Post
Did you understand what I need?

I need to apply a specific style on the B1 of subtotal and also change COLSPAN.

It doesn´t work on this code.

 
-* File: IBFS:/localhost/EDA/EDASERVE/APPPATH/vesir21815/dev/Procedure1.fex Created by WebFOCUS AppStudio

-SET &ECHO=ALL;

TABLE FILE CAR
SUM SALES
BY COUNTRY
ON TABLE COLUMN-TOTAL
ON TABLE PCHOLD FORMAT XLSX OPEN NOBREAK  AS 'REPORT'
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *

TYPE=REPORT,
TITLETEXT='Summary',
SIZE=6,
PAGESIZE=A3,
-*SQUEEZE=ON,
ORIENTATION=PORTRAIT,
GRID=OFF,

$
TYPE=HEADING,
     IMAGE=ford_logo.jpg,
     POSITION=(+0.000000 +0.000000),
     SIZE=(0.597222 0.250000),
$


TYPE=HEADING,
LINE=3,
STYLE=BOLD,
SIZE=10,
$
TYPE=TITLE,
COLUMN=COUNTRY,
COLSPAN=2,
$

TYPE=TITLE,
STYLE=BOLD,
SIZE=8,
BACKCOLOR=RGB(46 157 198),
$
TYPE=GRANDTOTAL,
BACKCOLOR=RGB(192 192 192),
STYLE=BOLD,
$
ENDSTYLE
END





TABLE FILE CAR
PRINT 
     SALES
     DEALER_COST
     RETAIL_COST
BY  LOWEST COUNTRY
BY  LOWEST CAR
BY  MODEL
     
ON COUNTRY SUBTOTAL AS ''
     
ON CAR SUBTOTAL AS ''
ON TABLE COLUMN-TOTAL
ON TABLE PCHOLD FORMAT XLSX CLOSE
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *

TYPE=REPORT,
TITLETEXT='Summary',
SIZE=6,
PAGESIZE=A3,
-*SQUEEZE=ON,
ORIENTATION=PORTRAIT,
GRID=OFF,

$
TYPE=HEADING,
     IMAGE=ford_logo.jpg,
     POSITION=(+0.000000 +0.000000),
     SIZE=(0.597222 0.250000),
$


TYPE=HEADING,
LINE=3,
STYLE=BOLD,
SIZE=10,
$
TYPE=TITLE,
COLUMN=COUNTRY,
COLSPAN=2,
$

TYPE=TITLE,
STYLE=BOLD,
SIZE=8,
BACKCOLOR=RGB(46 157 198),
$
TYPE=GRANDTOTAL,
BACKCOLOR=RGB(192 192 192),
STYLE=BOLD,
$

TYPE=SUBTOTAL,
     BY=1,
     COLOR='RED',
	 OBJECT=TAG,
	 JUSTIFY=CENTER,
	 COLSPAN=2,
$
ENDSTYLE
END
 


WebFOCUS 8.1.05 / APP Studio
 
Posts: 272 | Location: Brazil | Registered: October 31, 2006Reply With QuoteReport This Post
Virtuoso
posted Hide Post
Ricardo,
Why do you need COLSPAN?


Daniel
In Focus since 1982
wf 8.202M/Win10/IIS/SSA - WrapApp Front End for WF

 
Posts: 1934 | Location: Tel Aviv, Israel | Registered: March 23, 2006Reply With QuoteReport This Post
Guru
posted Hide Post
I need to set the size of that column to be 2 cells on the XLSX report.


WebFOCUS 8.1.05 / APP Studio
 
Posts: 272 | Location: Brazil | Registered: October 31, 2006Reply With QuoteReport This Post
Virtuoso
posted Hide Post
Ricardo,
As much as I know, COLSPAN is not a valid attribute for TYPE=SUBTOTAL.
If it is a necessity, I'm afraid you'll have to use SUBFOOT instead.
Maybe something like this:
  
-* File ricardo05.fex
DEFINE FILE CAR
SUBFCOUNTRY/A26='*Total Country ' | COUNTRY;
END
TABLE FILE CAR
PRINT
     SALES
     DEALER_COST
     RETAIL_COST
BY  LOWEST COUNTRY
BY SUBFCOUNTRY NOPRINT
BY  LOWEST CAR
BY  MODEL
ON COUNTRY SUBFOOT 
"<SUBFCOUNTRY <ST.SALES<ST.DEALER_COST<ST.RETAIL_COST"
ON CAR SUBTOTAL AS '*Total Car'
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT XLSX
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     INCLUDE = endeflt,
$
TYPE=SUBFOOT,
     HEADALIGN=BODY,
$
TYPE=SUBFOOT,
     BY=1, object=FIELD,
	 ITEM=1,
	 JUSTIFY=LEFT,
     COLOR='blue',
	 COLSPAN=2,
$
TYPE=SUBFOOT,
     BY=1,
     COLOR='RED',
	 JUSTIFY=RIGHT,
$
ENDSTYLE
END

This message has been edited. Last edited by: Danny-SRL,


Daniel
In Focus since 1982
wf 8.202M/Win10/IIS/SSA - WrapApp Front End for WF

 
Posts: 1934 | Location: Tel Aviv, Israel | Registered: March 23, 2006Reply With QuoteReport This Post
Guru
posted Hide Post
Thanks Danny.

Good One


WebFOCUS 8.1.05 / APP Studio
 
Posts: 272 | Location: Brazil | Registered: October 31, 2006Reply With QuoteReport This Post
  Powered by Social Strata  
 

Focal Point    Focal Point Forums  Hop To Forum Categories  WebFOCUS/FOCUS Forum on Focal Point     [SOLVED] Style subtotal field BY

Copyright © 1996-2018 Information Builders, leaders in enterprise business intelligence.