Focal Point Banner


As of December 1, 2020, Focal Point is retired and repurposed as a reference repository. We value the wealth of knowledge that's been shared here over the years. You'll continue to have access to this treasure trove of knowledge, for search purposes only.

Join the TIBCO Community
TIBCO Community is a collaborative space for users to share knowledge and support one another in making the best use of TIBCO products and services. There are several TIBCO WebFOCUS resources in the community.

  • From the Home page, select Predict: WebFOCUS to view articles, questions, and trending articles.
  • Select Products from the top navigation bar, scroll, and then select the TIBCO WebFOCUS product page to view product overview, articles, and discussions.
  • Request access to the private WebFOCUS User Group (login required) to network with fellow members.

Former myibi community members should have received an email on 8/3/22 to activate their user accounts to join the community. Check your Spam folder for the email. Please get in touch with us at community@tibco.com for further assistance. Reference the community FAQ to learn more about the community.


Focal Point    Focal Point Forums  Hop To Forum Categories  WebFOCUS/FOCUS Forum on Focal Point     [CLOSED]SET ACCROSS TITLE SIDE with OVER

Read-Only Read-Only Topic
Go
Search
Notify
Tools
[CLOSED]SET ACCROSS TITLE SIDE with OVER
 Login/Join
 
Mikey
Gold member
posted
Can someone tell me how to get 'Reporting Period' to the left of the dates and above the OVER column?

 
SET NODATA = NA
TABLE FILE EMPLOYEE
PRINT 
     EMPLOYEE.FUNDTRAN.BANK_NAME OVER
     EMPLOYEE.FUNDTRAN.BANK_CODE OVER
     EMPLOYEE.FUNDTRAN.BANK_ACCT OVER
     EMPLOYEE.FUNDTRAN.EFFECT_DATE
BY  LOWEST EMPLOYEE.EMPINFO.DEPARTMENT NOPRINT
ACROSS LOWEST EMPLOYEE.EMPINFO.HIRE_DATE AS 'Reporting Period'
ON TABLE SET ACROSSTITLE SIDE
ON TABLE SET PAGE-NUM NOLEAD 
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
ENDSTYLE
END

This message has been edited. Last edited by: <Emily McAllister>,


8007
Windows 7, PDF, Excel
 
Posts: 75 | Registered: September 03, 2013Report This Post
BabakNYC
Virtuoso
posted Hide Post
ACROSSTITLE=SIDE is for the BY field. If you get rid of the NOPRINT, you'll see it work.


WebFOCUS 8206, Unix, Windows
 
Posts: 1853 | Location: New York City | Registered: December 30, 2015Report This Post
Danny-SRL
Virtuoso
posted Hide Post
Babak,
Mikey doesn't want to see the department name, hence the NOPRINT.

Mikey,
Here is a solution. There might be others:
  
-* File MIKEY.fex
DEFINE FILE EMPLOYEE
BN/A20=BANK_NAME;
BC/A20=FPRINT(BANK_CODE, 'I6S', 'A20');
BA/A20=FPRINT(BANK_ACCT, 'I9S', 'A20');
ED/A20=FPRINT(EFFECT_DATE, 'I6YMD', 'A20');
LBN/A12='BANKNAME';
LBC/A12='BANK_CODE';
LBA/A12='BANK_ACCT';
LED/A12='EFFECT_DATE';
END

TABLE FILE EMPLOYEE
PRINT 
     EMPLOYEE.EMPINFO.DEPARTMENT 
     EMPLOYEE.EMPINFO.HIRE_DATE 
     LBN BN
     LBA BA
     LBC BC
     LED ED
ON TABLE SAVE AS MIKEY 
END
?FF MIKEY
-RUN
EX -LINES 9 EDAPUT MASTER,MIKEY,C,MEM
FILENAME=MIKEY,  SUFFIX=FIX
 SEGNAME=MIKEY,  SEGTYPE=S0
  FIELDNAME=DEPARTMENT, FORMAT=A10, ACTUAL=A10, $
  FIELDNAME=HIRE_DATE, FORMAT=I6YMD, ACTUAL=A6, $
 SEGNAME=LDATA, PARENT=MIKEY,  OCCURS=VARIABLE
  FIELDNAME=LBL, FORMAT=A12, ACTUAL=A12, $
  FIELDNAME=BDATA, FORMAT=A20, ACTUAL=A20, $
  FIELDNAME=ORD, ALIAS=ORDER, FORMAT=I2, ACTUAL=I4, $
-RUN
TABLE FILE MIKEY
SUM BDATA
BY DEPARTMENT NOPRINT
BY ORD NOPRINT
BY LBL AS ' '
ACROSS HIRE_DATE AS 'Reporting Period'
ON TABLE SET ACROSSTITLE SIDE
ON TABLE SET PAGE-NUM NOLEAD 
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
ENDSTYLE
END


Daniel
In Focus since 1982
wf 8.202M/Win10/IIS/SSA - WrapApp Front End for WF

 
Posts: 1980 | Location: Tel Aviv, Israel | Registered: March 23, 2006Report This Post
Mikey
Gold member
posted Hide Post
I get this error when I run that code
Error
Cannot include resource specified -LINES


8007
Windows 7, PDF, Excel
 
Posts: 75 | Registered: September 03, 2013Report This Post
Danny-SRL
Virtuoso
posted Hide Post
You are most probably running in the Portal...
Try on the server.

Or try this in the Portal:
  
-* File mikey2.fex
DEFINE FILE EMPLOYEE
BN/A20=BANK_NAME;
BC/A20=FPRINT(BANK_CODE, 'I6S', 'A20');
BA/A20=FPRINT(BANK_ACCT, 'I9S', 'A20');
ED/A20=FPRINT(EFFECT_DATE, 'I6YMD', 'A20');
LBN/A12='BANKNAME';
LBC/A12='BANK_CODE';
LBA/A12='BANK_ACCT';
LED/A12='EFFECT_DATE';
END
 
TABLE FILE EMPLOYEE
PRINT 
     EMPLOYEE.EMPINFO.DEPARTMENT 
     EMPLOYEE.EMPINFO.HIRE_DATE 
     LBN BN
	 LBA BA
	 LBC BC
	 LED ED
ON TABLE SAVE AS MIKEY 
END
-RUN
FILEDEF MIKEYMAS DISK MIKEY.MAS
-RUN
-WRITE MIKEYMAS FILENAME=MIKEY,  SUFFIX=FIX
-WRITE MIKEYMAS  SEGNAME=MIKEY,  SEGTYPE=S0
-WRITE MIKEYMAS   FIELDNAME=DEPARTMENT, FORMAT=A10, ACTUAL=A10, $
-WRITE MIKEYMAS   FIELDNAME=HIRE_DATE, FORMAT=I6YMD, ACTUAL=A6, $
-WRITE MIKEYMAS  SEGNAME=LDATA, PARENT=MIKEY,  OCCURS=VARIABLE
-WRITE MIKEYMAS   FIELDNAME=LBL, FORMAT=A12, ACTUAL=A12, $
-WRITE MIKEYMAS   FIELDNAME=BDATA, FORMAT=A20, ACTUAL=A20, $
-WRITE MIKEYMAS   FIELDNAME=ORD, ALIAS=ORDER, FORMAT=I2, ACTUAL=I4, $
-RUN
TABLE FILE MIKEY
SUM BDATA
BY DEPARTMENT NOPRINT
BY ORD NOPRINT
BY LBL AS ' '
ACROSS HIRE_DATE AS 'Reporting Period'
ON TABLE SET ACROSSTITLE SIDE
ON TABLE SET PAGE-NUM NOLEAD 
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
ENDSTYLE
END


Daniel
In Focus since 1982
wf 8.202M/Win10/IIS/SSA - WrapApp Front End for WF

 
Posts: 1980 | Location: Tel Aviv, Israel | Registered: March 23, 2006Report This Post
Mikey
Gold member
posted Hide Post
I ran in DevStudio. I think we don't use FILEDEF for security reasons, but Im waiting on that answer.


8007
Windows 7, PDF, Excel
 
Posts: 75 | Registered: September 03, 2013Report This Post
Francis Mariani
Expert
posted Hide Post
Here's an example using jQuery and will work for HTML only:

SET NODATA = NA
TABLE FILE EMPLOYEE
PRINT
     EMPLOYEE.FUNDTRAN.BANK_NAME OVER
     EMPLOYEE.FUNDTRAN.BANK_CODE OVER
     EMPLOYEE.FUNDTRAN.BANK_ACCT OVER
     EMPLOYEE.FUNDTRAN.EFFECT_DATE
BY  LOWEST EMPLOYEE.EMPINFO.DEPARTMENT NOPRINT
ACROSS LOWEST EMPLOYEE.EMPINFO.HIRE_DATE AS 'Reporting Period'
ON TABLE SET ACROSSTITLE SIDE
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE NOTOTAL
ON TABLE HOLD AS HREPORT1 FORMAT HTMTABLE
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
ENDSTYLE
END
-RUN

-HTMLFORM BEGIN
<html>
<head>
<script src="https://ajax.googleapis.com/ajax/libs/jquery/1.11.2/jquery.min.js"></script>

<script type="text/javascript">
$(document).ready(function()
{
    // Copy the Hire Date column title to the appropriate table cell
    $("body table:eq(0) tr:nth(1) td:first").html( $( "body table:eq(0) tr:first td:nth(1)" ).html() );
    // Remove the table row that contained the original column title
    $( "body table:eq(0) tr:first" ).remove();
});
</script>
</head>

<body>
!IBI.FIL.HREPORT1;
</body>

</html>
-HTMLFORM END


Francis


Give me code, or give me retirement. In FOCUS since 1991

Production: WF 7.7.05M, Dev Studio, BID, MRE, WebSphere, DB2 / Test: WF 8.1.05M, App Studio, BI Portal, Report Caster, jQuery, HighCharts, Apache Tomcat, MS SQL Server
 
Posts: 10577 | Location: Toronto, Ontario, Canada | Registered: April 27, 2005Report This Post
  Powered by Social Strata  

Read-Only Read-Only Topic

Focal Point    Focal Point Forums  Hop To Forum Categories  WebFOCUS/FOCUS Forum on Focal Point     [CLOSED]SET ACCROSS TITLE SIDE with OVER

Copyright © 1996-2020 Information Builders