I created an Excel report with 5 columns. The titles of the columns are A, B, C, D and E. I would like to add another title on top of columns C, D and E only.
Second Title
A B C D E

Is this possible?

This message has been edited. Last edited by: <Kathryn Henning>,

I don't think in the sense that you want, here is a kind of / sort of way.

TABLE FILE CAR
PRINT
COUNTRY CAR MODEL BODYTYPE SEATS DEALER_COST RETAIL_COST AS 'SECOND,RETAIL_COST'
SALES AS 'TITLE,SALES'
ON TABLE SET ONLINE-FMT EXL2K
END

Here is some code that will do what I think you're trying to do:

TABLE FILE CAR
SUM
     RETAIL_COST
     DEALER_COST
BY
     COUNTRY
BY
     CAR
HEADING
"TEST1<+0>TEST2"
"EXL2K"
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET STYLE *
TYPE=HEADING,HEADALIGN=BODY,$
TYPE=HEADING,LINE=1,ITEM=1,COLSPAN=2,JUSTIFY=LEFT,$
TYPE=HEADING,LINE=1,ITEM=2,COLSPAN=2,JUSTIFY=LEFT,$
ENDSTYLE
END

You need to use COLSPAN and HEADALIGN to make this work.

This message has been edited. Last edited by: <Maryellen>,

We should at least give Lia an example which closely approximates what was asked.

This appears to be more along the lines of what you're looking for.

TABLE FILE CAR
SUM RETAIL_COST AS 'C'
DEALER_COST AS 'D'
SALES AS 'E'
BY COUNTRY AS 'A'
BY CAR AS 'B'
HEADING
" <+0>SECOND TITLE"
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET STYLE *
TYPE=HEADING,HEADALIGN=BODY,$
TYPE=HEADING,LINE=1,ITEM=1,COLSPAN=2,JUSTIFY=LEFT,$
TYPE=HEADING,LINE=1,ITEM=2,COLSPAN=3,JUSTIFY=CENTER,$
TYPE=TITLE, JUSTIFY=CENTER,$
ENDSTYLE
END

Ken

Thank you all so much.
Placing the title on a specific column worked!

Hi All,

I have a similar requirement as above. But in addition to this I have a Bottom Border Styling to the TITLE. If I add any border styling to the TITLE, it inserts an extra row between Heading Row and Title row. I want to supress/eliminate that row.
Find below the code with Title styling.

TABLE FILE CAR
SUM RETAIL_COST AS 'C'
DEALER_COST AS 'D'
SALES AS 'E'
BY COUNTRY AS 'A'
BY CAR AS 'B'
HEADING
" <+0>SECOND TITLE"
ON TABLE NOTOTAL
ON TABLE SET PAGE NOLEAD

ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET STYLE *
TYPE=HEADING,HEADALIGN=BODY,$
TYPE=HEADING,LINE=1,ITEM=1,COLSPAN=2,JUSTIFY=LEFT,$
TYPE=HEADING,LINE=1,ITEM=2,COLSPAN=3,JUSTIFY=CENTER,$
TYPE=TITLE,
FONT='ARIAL',
STYLE=BOLD,
SIZE=10,
BORDER-COLOR=WHITE,
BORDER-TOP=LIGHT,
BORDER-LEFT=LIGHT,
BORDER-RIGHT=LIGHT,
BORDER-BOTTOM=LIGHT,
BORDER-BOTTOM-COLOR=RGB(59 104 159),

$
ENDSTYLE
END

Thanks in advance.

quote:

If I add any border styling to the TITLE, it inserts an extra row between Heading Row and Title row. I want to supress/eliminate that row.

No, can't do. That's an issue that's been hanging for ages and never been fixed. Add borders and you instantly get those silly blank lines below the HEADING and above FOOTING.

IBI introduced a new setting in 7.7.05 I think:

SET DROPBLNKLINE = HEADING

Which actually removes the blank line below the HEADING when using borders. Of course, my excitement came to a quick end when I realized that setting was only applicable to PDF output EXL2K and HTML are still showing the old behaviour.