In past, I tried to do column groups as follows but did not do it because of one extra line that
used to appear between the headings (problem only with HTML CSS ON).

     CAR        SalesStatistics           Measurements       
              DealerCost RetailCost       Height Width

Recently I figured out a way to it. Here I post the code for comments/sharing -

Fex File:

SET CSSURL='car.css';
TABLE FILE CAR
PRINT BHP AS '' MPG AS '' LENGTH AS '' WIDTH AS '' HEIGHT AS ''
BY TOTAL COMPUTE CDUMMY/I11=1; NOPRINT
ON CDUMMY SUBHEAD
"ENGINE<+0>BODY"
"BHP<+0>MPG<+0>LENGTH<+0>WIDTH<+0>HEIGHT"
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TYPE=REPORT,
     FONT='ARIAL', SIZE=8,
     BORDER=LIGHT, BORDER-STYLE=SOLID, BORDER-COLOR=RGB(130 130 130),
$
TYPE=SUBHEAD,
     BY=CDUMMY,
     HEADALIGN=BODY,
     STYLE=BOLD,
     JUSTIFY=CENTER,
     BORDER-STYLE=SOLID,
     BACKCOLOR=RGB(220 220 255),
     CLASS=table_heading1,
$
TYPE=SUBHEAD, BY=CDUMMY, LINE=1, OBJECT=TEXT, ITEM=1, COLSPAN=2,  CLASS=table_heading1, $
TYPE=SUBHEAD, BY=CDUMMY, LINE=1, OBJECT=TEXT, ITEM=2, COLSPAN=3,  CLASS=table_heading1, $
TYPE=SUBHEAD, BY=CDUMMY, LINE=2, CLASS=table_heading2, $
END

car.css:

.table_heading1 {
   border: 1 solid rgb(130 130 130);
   text-align: center;
   font: normal normal bold 8pt arial;
   padding:5pt;
   color:#000000;
   background-color:#DCDCFF;
   text-align:center;
}

.table_heading2 {
   border: 1 solid rgb(130 130 130);
   text-align: center;
   font: normal normal normal 8pt arial;
   padding:3pt;
   color:#000000;
   background-color:#DCDCFF;
   text-align:center;
}

sweet.
works in IE, as well.