Is there a way to get 2 title rows on top of each other? I tried SUBHEAD, but it displays above the report header.

 
DEFINE FILE CAR
Error_Column/I3=IF SEATS EQ 2 THEN 1 
ELSE IF SEATS EQ 4 THEN 3
ELSE 5;
END
TABLE FILE CAR
PRINT 
     Error_Column
         CAR.COMP.CAR
     CAR.CARREC.MODEL
     CAR.BODY.BODYTYPE
     CAR.BODY.SEATS
     CAR.SPECS.LENGTH
     CAR.WARANT.WARRANTY
HEADING
"Standard Report"
"ABC123 CAR"
"Company XYZ"
ON TABLE SUBHEAD
" <+0>1<+0>2<+0>3<+0>4<+0>5<+0>6"
ON TABLE SET PAGE-NUM NOLEAD 
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT EXL07
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     INCLUDE = IBFS:/EDA/BIRS05/_EDAHOME/ETC/endeflt.sty,
$
TYPE=TABHEADING,
     HEADALIGN=BODY,
$
ENDSTYLE
END
 

This message has been edited. Last edited by: Mikey,

What do you mean title rows? Titles are the heading on a column. Titles you can put a comma where you want it to move to the next row.

PRINT 
     Error_Column AS "1st Row,2nd Row"
         CAR.COMP.CAR
     CAR.CARREC.MODEL
     CAR.BODY.BODYTYPE
     CAR.BODY.SEATS
     CAR.SPECS.LENGTH
     CAR.WARANT.WARRANTY

Are you wanting the 1,2,3,4,5,6 on their own row in Excel like in the picture below?

Using this code:

DEFINE FILE CAR
Error_Column/I3=IF SEATS EQ 2 THEN 1 
ELSE IF SEATS EQ 4 THEN 3
ELSE 5;
END
TABLE FILE CAR
PRINT 
     Error_Column
     CAR.COMP.CAR
     CAR.CARREC.MODEL
     CAR.BODY.BODYTYPE
     CAR.BODY.SEATS
     CAR.SPECS.LENGTH
     CAR.WARANT.WARRANTY
HEADING
"Standard Report"
"ABC123 CAR"
"Company XYZ"
" <+0>1<+0>2<+0>3<+0>4<+0>5<+0>6"
ON TABLE SET PAGE-NUM NOLEAD 
ON TABLE PCHOLD FORMAT EXL07

ON TABLE SET STYLE *
TYPE=REPORT, COLOR=RGB(66 70 73), FONT='TREBUCHET MS', SIZE=9, SQUEEZE=ON, ARICONSET='WHITE', GRID=ON, $
TYPE=HEADING, HEADALIGN=BODY, $
TYPE=HEADING, LINE=1, COLSPAN=7, STYLE=BOLD, JUSTIFY=CENTER, $
TYPE=HEADING, LINE=2, COLSPAN=7, STYLE=BOLD, JUSTIFY=CENTER, $
TYPE=HEADING, LINE=3, COLSPAN=7, STYLE=BOLD, JUSTIFY=CENTER, $
TYPE=HEADING, LINE=4, COLSPAN=1, STYLE=BOLD, BACKCOLOR=RGB(169 53 26), COLOR=RGB(255 255 255), $
TYPE=TITLE, BACKCOLOR=RGB(169 53 26), COLOR=RGB(255 255 255), STYLE=BOLD, $
ENDSTYLE

END

I get this result in Excel:

This message has been edited. Last edited by: Hallway,

That worked, thank you!

Put [SOLVED] in front of the title for your first post.