Newbie here.

I have a need to take data out of one Oracle table and put it into another Oracle table. I know how to do this with SQL. My question how do you accomplish the same thing in Webfocus code. I don’t have any problems. I just want to know what commands to use to get the job done.

This message has been edited. Last edited by: FP Mod Chuck,

Do you have access to the Reporting Server Console? If so, you can use either Quick Copy or Custom Copy to accomplish this.

Alternatively, you can write a WebFOCUS request that has the answer set you want and add

ON TABLE HOLD AS tablename FORMAT SQLORA

https://webfocusinfocenter.inf...source/oracle376.htm

You can use SQL PASSTHRU to accomplish that. Using this you write your code in SQL and then use FOCUS the execute.

You could also use MODIFY which is something developed by IB to Insert and Update DB.

Or even use

TABLE FILE "myOldOracleTbl"
...
ON TABLE HOLD AS "myNewOracleTbl" FORMAT SQLORA
END

There is a product called Maintain whose main purpose is to Update date to the database.

There's also MODIFY.

This focexec runs every night updating a SQL Server table DateRange.

TABLE FILE DR2
SUM
  DR_MIN_DATE AS 'DR_MIN_DATE'
  DR_MIN_TIME AS 'DR_MIN_TIME'
  DR_AVE_DATE AS 'DR_AVE_DATE'
  DR_AVE_TIME AS 'DR_AVE_TIME'
  DR_MAX_DATE AS 'DR_MAX_DATE'
  DR_MAX_TIME AS 'DR_MAX_TIME'
BY DR_YEAR AS 'DR_YEAR'
BY DR_PROJECT AS 'DR_PROJECT'
BY DR_RELEASE AS 'DR_RELEASE'
BY DR_SYSTEM AS 'DR_SYSTEM'
BY DR_SPECIES AS 'DR_SPECIES'
BY DR_RELEASESITE AS 'DR_RELEASESITE'
BY DR_RELEASEDATETIME AS 'DR_RELEASEDATETIME'
BY DR_ORDER AS 'DR_ORDER'
ON TABLE HOLD AS DATERANGE_HOLD
END
-RUN

-******************************************************************************
MODIFY FILE DATERANGE
LOG DUPL MSG OFF
FIXFORM FROM DATERANGE_HOLD
MATCH DR_YEAR DR_PROJECT DR_RELEASE DR_SYSTEM DR_SPECIES
ON MATCH UPDATE *
ON NOMATCH INCLUDE
DATA ON DATERANGE_HOLD
END
-******************************************************************************

DateRange.acx
 SEGNAME=DATERANGE, TABLENAME=GPUD_Reporting.dbo.DATERANGE, 
   CONNECTION=SunhillowSqlServer, KEYS=5, $

DateRange.mas
FILENAME=DATERANGE, SUFFIX=SQLMSS  , $
  SEGMENT=DATERANGE, SEGTYPE=S0, $
    FIELDNAME=DR_YEAR, ALIAS=DR_YEAR, USAGE=A4V, ACTUAL=A4V, $
    FIELDNAME=DR_PROJECT, ALIAS=DR_PROJECT, USAGE=A10V, ACTUAL=A10V, $
    FIELDNAME=DR_RELEASE, ALIAS=DR_RELEASE, USAGE=A4V, ACTUAL=A4V, $
    FIELDNAME=DR_SYSTEM, ALIAS=DR_SYSTEM, USAGE=A4V, ACTUAL=A4V, $
    FIELDNAME=DR_SPECIES, ALIAS=DR_SPECIES, USAGE=A2V, ACTUAL=A2V, $
    FIELDNAME=DR_RELEASESITE, ALIAS=DR_RELEASESITE, USAGE=A2V, ACTUAL=A2V, $
    FIELDNAME=DR_RELEASEDATETIME, ALIAS=DR_RELEASEDATETIME, USAGE=HYYMDs, ACTUAL=HYYMDs,
      MISSING=ON, $
    FIELDNAME=DR_ORDER, ALIAS=DR_ORDER, USAGE=I6, ACTUAL=I2, $
    FIELDNAME=DR_MIN_DATE, ALIAS=DR_MIN_DATE, USAGE=HYYMDs, ACTUAL=HYYMDs, $
    FIELDNAME=DR_MIN_TIME, ALIAS=DR_MIN_TIME, USAGE=A5, ACTUAL=A5, $
    FIELDNAME=DR_AVE_DATE, ALIAS=DR_AVE_DATE, USAGE=HYYMDs, ACTUAL=HYYMDs, $
    FIELDNAME=DR_AVE_TIME, ALIAS=DR_AVE_TIME, USAGE=A5, ACTUAL=A5, $
    FIELDNAME=DR_MAX_DATE, ALIAS=DR_MAX_DATE, USAGE=HYYMDs, ACTUAL=HYYMDs, $
    FIELDNAME=DR_MAX_TIME, ALIAS=DR_MAX_TIME, USAGE=A5, ACTUAL=A5, $