I'm trying to change the backcolor of R5 to red when the value of R6 is greater than 5.

Anyone have any ideas?

TABLE FILE GGSALES
SUM 
     DOLLARS
BY CATEGORY
BY ST
BY CITY
ACROSS DATE
FOR
     PRODUCT
'Capuccino' AS 'Capuccino' LABEL R1 OVER 
'Espresso' AS 'Espresso' LABEL R2 OVER 
'Latte' AS 'Latte' LABEL R3 OVER 
'Scone' AS 'Scone' LABEL R4 OVER 
RECAP R5(1,*,1)=(R1*(-1))+(R2*(-1))+R3+R4+R5(*-1); 
 AS 'Total' OVER 
RECAP R6(1,*,1)/P7.4=R5/R1; 
 AS ' ' NOPRINT
ON TABLE SET PAGE-NUM OFF 
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     UNITS=IN,
     SQUEEZE=ON,
     ORIENTATION=PORTRAIT,
$
TYPE=REPORT,
     GRID=OFF,
     FONT='ARIAL',
     SIZE=9,
$
TYPE=DATA,
     LABEL=R5,
     ACROSSCOLUMN=N1,
     BACKCOLOR='SILVER',
$
TYPE=TITLE,
     STYLE=BOLD,
$
TYPE=ACROSSVALUE,
     SIZE=9,
$
TYPE=ACROSSTITLE,
     STYLE=BOLD,
$
TYPE=GRANDTOTAL,
     BACKCOLOR=RGB(210 210 210),
     STYLE=BOLD,
$
ENDSTYLE
END

Wow - 65 views and no solutions.

I still wasn't able to get the styling to happen on individual cells for the recap, but I did rewrite the report creating a new field for each value and using OVER to get the report to show the same way and was able to apply the conditional styling.

DEFINE FILE GGSALES
NDATE/MTR = DATE;
BLANK/A1 = '';
Capuccino/D12.2 = IF PRODUCT EQ 'Capuccino' THEN DOLLARS ELSE 0;
Espresso/D12.2  = IF PRODUCT EQ 'Espresso'  THEN DOLLARS ELSE 0;
Latte/D12.2     = IF PRODUCT EQ 'Latte'     THEN DOLLARS ELSE 0;
Scone/D12.2     = IF PRODUCT EQ 'Scone'     THEN DOLLARS ELSE 0;
Total/D12.2     = Capuccino + (Espresso * (-1)) + Latte + Scone;
END
TABLE FILE GGSALES
SUM
     Capuccino OVER
	 Espresso OVER
	 Latte OVER
	 Scone OVER
	 Total OVER
COMPUTE	 Pctfield/D12.4 = Total / Capuccino; NOPRINT
BY CATEGORY
BY ST
BY CITY
ACROSS DATE
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TYPE=REPORT,
     GRID=OFF,
     FONT='ARIAL',
     SIZE=9,
$
TYPE=DATA, ACROSSCOLUMN=Total, BACKCOLOR=SILVER,$
TYPE=DATA, ACROSSCOLUMN=Total,
	WHEN=Pctfield GT 12,
	BACKCOLOR='RED',
$
TYPE=DATA, ACROSSCOLUMN=Total,
     WHEN=N9 GT 5,
     BACKCOLOR='YELLOW',
$
TYPE=TITLE,
     STYLE=BOLD,
$

TYPE=ACROSSTITLE,
     STYLE=BOLD,
$
ENDSTYLE
END