Focal Point Banner


As of December 1, 2020, Focal Point is retired and repurposed as a reference repository. We value the wealth of knowledge that's been shared here over the years. You'll continue to have access to this treasure trove of knowledge, for search purposes only.

Join the TIBCO Community
TIBCO Community is a collaborative space for users to share knowledge and support one another in making the best use of TIBCO products and services. There are several TIBCO WebFOCUS resources in the community.

  • From the Home page, select Predict: WebFOCUS to view articles, questions, and trending articles.
  • Select Products from the top navigation bar, scroll, and then select the TIBCO WebFOCUS product page to view product overview, articles, and discussions.
  • Request access to the private WebFOCUS User Group (login required) to network with fellow members.

Former myibi community members should have received an email on 8/3/22 to activate their user accounts to join the community. Check your Spam folder for the email. Please get in touch with us at community@tibco.com for further assistance. Reference the community FAQ to learn more about the community.


Focal Point    Focal Point Forums  Hop To Forum Categories  WebFOCUS/FOCUS Forum on Focal Point     [Solved] Stacked and clustered bar in one graph

Read-Only Read-Only Topic
Go
Search
Notify
Tools
[Solved] Stacked and clustered bar in one graph
 Login/Join
 
Silver Member
posted
Hello All,


I have a Bar-graph:

I want the first two bars stacked.
and the rest clustered.

How to make a stacked graph I know.
How to make clustered one also.

But a combination of the two. I don't know.
Is there a way 2 combine the two in one graph.

My code:

GRAPH FILE BENUTTING_POLI_MM_WERK
-* Created by Advanced Graph Assistant
SUM P_DUUR_MIN AS 'Toegewezen spreekuur tijd'
COMPUTE Expres2Blok/I11 = IF W_DUUR_BLOK GT P_DUUR_MIN THEN P_DUUR_MIN ELSE W_DUUR_BLOK; AS 'Duur blokkades'
COMPUTE NietAfwBlok2/I11=IF W_DUUR_BLOK GE DUUR_PLEK_DDPOS THEN 0 ELSE(DUUR_PLEK_DDPOS - W_DUUR_BLOK) ; AS 'Afspraakrooster'
W_DUUR_AFSP AS 'Geplande bezetting'
W_DUUR_VOLDAAN AS 'gerealiseerde geplande bezetting'
SU_REG_DUUR_WERKELIJK AS 'Gerealiseerde spreekuurbenutting'
BY MAAND
WHERE ( DATUM EQ DT(&SDATUM) ) OR ( DATUM EQ DT(&EDATUM) );
WHERE LOCATIE EQ &LOCATIE.(OR(FIND LOCATIE,GETAGENDASFOC.SEG01.LOCATIE IN GETAGENDASFOC)).LOCATIE.;
WHERE AGENDA_OMSCHR EQ &AGENDA.(OR(FIND AGENDA_OMSCHR,GETAGENDASFOC.SEG01.AGENDA_OMSCHR IN GETAGENDASFOC)).AGENDA.;
WHERE SUBAGENDA EQ &SUBAGENDA.(OR(FIND SUBAGENDA,GETAGENDASFOC.SEG01.SUBAGENDA IN GETAGENDASFOC)).SUBAGENDA.;
HEADING
"In minuten"
ON TABLE HOLD AS GRAP1 FORMAT HTMTABLE
ON GRAPH SET HTMLENCODE ON
ON GRAPH SET GRAPHDEFAULT OFF
ON GRAPH SET VZERO OFF
ON GRAPH SET HAXIS 1200
ON GRAPH SET VAXIS 631
ON GRAPH SET UNITS PIXELS
ON GRAPH SET LOOKGRAPH VBAR
ON GRAPH SET GRMERGE ADVANCED
ON GRAPH SET GRMULTIGRAPH 0
ON GRAPH SET GRLEGEND 0
ON GRAPH SET GRXAXIS 1
ON GRAPH SET GRAPHSTYLE *
setTemplateFile("/images/tdg/template/IBISouthWestern.txt");
setReportParsingErrors(false);
setSelectionEnableMove(false);
setTransparentBorderColor(getSeries(0),true);
setTransparentBorderColor(getSeries(1),true);
setTransparentBorderColor(getSeries(2),true);
setTransparentBorderColor(getSeries(3),true);
setTransparentBorderColor(getSeries(4),true);
setTransparentBorderColor(getSeries(5),true);
setTransparentBorderColor(getSeries(6),true);
setTransparentBorderColor(getSeries(7),true);
setTransparentBorderColor(getSeries(8),true);
setTransparentBorderColor(getSeries(9),true);
setTransparentBorderColor(getSeries(10),true);
setDepthRadius(5);
setTransparentBorderColor(getChartBackground(),true);
setPlace(true);
setDisplay(getDataText(),false);
setDataTextPosition(1);
ENDSTYLE

END

This message has been edited. Last edited by: Nordin Ben Ahmed,


7.7.03
OS is Windows 7
We create al sorts of outputs depending on the demand, HTML (most cases), Excel (some cases) and PDF (some cases)
 
Posts: 32 | Location: Utrecht, Holland | Registered: December 10, 2008Report This Post
Silver Member
posted Hide Post
Hi Guys,

I know it is a busy month.
But not one reaction Sweating


7.7.03
OS is Windows 7
We create al sorts of outputs depending on the demand, HTML (most cases), Excel (some cases) and PDF (some cases)
 
Posts: 32 | Location: Utrecht, Holland | Registered: December 10, 2008Report This Post
Virtuoso
posted Hide Post
Well, technically, there have been 40 reactions to your post so far but apparently none of those know how to do what you're asking, or even if it's even possible, myself included. Frowner



Prod/Dev: WF Server 8008/Win 2008 - WF Client 8008/Win 2008 - Dev. Studio: 8008/Windows 7 - DBMS: Oracle 11g Rel 2
Test: Dev. Studio 8008 /Windows 7 (Local) Output:HTML, EXL2K.
 
Posts: 1533 | Registered: August 12, 2005Report This Post
<Kathryn Henning>
posted
Hi Nordin Ben Ahmed,

Please open a case on InfoResponse Online so that you can get a definitive answer on this.

Thanks and regards,

Kathryn
 
Report This Post
Member
posted Hide Post
This gets rather tedious if you have a lot of unstacked fields as it's creating a separate grouping/hold file for each one.
TABLE FILE CAR
PRINT
 COMPUTE GROUP/I11=LAST GROUP+3;
 COMPUTE GROUP2/I11=LAST GROUP+4;
 COMPUTE GROUP3/I11=LAST GROUP+5;
 HEIGHT
 WIDTH
 LENGTH
 WHEELBASE
BY MODEL
ON TABLE HOLD
END

TABLE FILE HOLD
PRINT
 MODEL
 GROUP
 HEIGHT
 WIDTH
 COMPUTE LENGTH/D5 MISSING ON=MISSING;
 COMPUTE WHEELBASE/D6.1 MISSING ON=MISSING;
ON TABLE HOLD AS H1
END

TABLE FILE HOLD
PRINT
 MODEL
 GROUP2
 COMPUTE HEIGHT/D5 MISSING ON=MISSING;
 COMPUTE WIDTH/D5 MISSING ON=MISSING;
 LENGTH
 COMPUTE WHEELBASE/D6.1 MISSING ON=MISSING;
ON TABLE HOLD AS H2
END

TABLE FILE HOLD
PRINT
 MODEL
 GROUP3
 COMPUTE HEIGHT/D5 MISSING ON=MISSING;
 COMPUTE WIDTH/D5 MISSING ON=MISSING;
 COMPUTE LENGTH/D5 MISSING ON=MISSING;
 WHEELBASE
ON TABLE HOLD AS H3
END

TABLE FILE H1
PRINT
 MODEL
 GROUP
 HEIGHT
 WIDTH
 LENGTH
 WHEELBASE
ON TABLE HOLD
MORE
 FILE H2
MORE
 FILE H3
END
								 
GRAPH FILE HOLD
PRINT 
 HEIGHT
 WIDTH
 LENGTH
 WHEELBASE
ACROSS MODEL
ACROSS GROUP
ON GRAPH SET LOOKGRAPH VBRSTK1
ON GRAPH SET GRAPHEDIT SERVER
ON GRAPH SET 3D OFF
END


WebFOCUS 7.6.7
Linux
HTML, Excel, PDF
 
Posts: 11 | Registered: February 19, 2009Report This Post
Silver Member
posted Hide Post
quote:
Originally posted by Nick Hilt:
This gets rather tedious if you have a lot of unstacked fields as it's creating a separate grouping/hold file for each one.


Thanks. That is what I want.
But when I translate my fields in your code.

They all get stacked?

It is the same code. What am I oing wrong?




SET ASNAMES = ON
-DEFAULT &SDATUM='2013/10/21';
-DEFAULT &EDATUM='2013/11/12';
-DEFAULT &DAT='Utrecht';
-DEFAULT &PAT=2;
-DEFAULT &ARTSCODE2='FOC_NONE';
-DEFAULT &DRILL='FOC_NONE';
-DEFAULT &OPMTOE='FOC_NONE';
-DEFAULT &LOCATIE='FOC_NONE';
-DEFAULT &AGENDA='FOC_NONE';
-DEFAULT &SUBAGENDA='FOC_NONE' ;



DEFINE FILE BENUTTING_POLI_MM_WERK
GEENPLANDRAFS/I11=IF INDIC EQ 'Geen planning' THEN W_DUUR_AFSP ELSE 0;
GEENREALDAGDEEL/I11=IF INDIC EQ 'Geen realisatie' AND P_DUUR_MIN GT W_DUUR_BLOK THEN P_DUUR_MIN-W_DUUR_BLOK ELSE 0;
END



TABLE FILE BENUTTING_POLI_MM_WERK
SUM 
     P_DUUR_MIN AS 'TOEGEWEZEN_SPREEKUUR_TIJD'
     COMPUTE Expres2Blok/I11 = IF W_DUUR_BLOK GT P_DUUR_MIN THEN P_DUUR_MIN ELSE W_DUUR_BLOK; AS 'DUUR_BLOKKADES'
     COMPUTE NietAfwBlok2/I11 = IF W_DUUR_BLOK GE DUUR_PLEK_DDPOS THEN 0 ELSE ( DUUR_PLEK_DDPOS - W_DUUR_BLOK ); AS 'AFSPRAAKROOSTER'
     W_DUUR_AFSP AS 'GEPLANDE_BEZETTING'
     W_DUUR_VOLDAAN AS 'GEREALISEERDE_GEPLANDE_BEZETTING'
     SU_REG_DUUR_WERKELIJK AS 'GEREALISEERDE_SPREEKUURBENUTTING'
BY  MAAND
HEADING
"In minuten"
WHERE ( DATUM GE DT(&SDATUM) ) AND ( DATUM LE DT(&EDATUM) );
WHERE LOCATIE EQ &LOCATIE.(OR(FIND LOCATIE,GETAGENDASFOC.SEG01.LOCATIE IN GETAGENDASFOC)).LOCATIE.;
WHERE AGENDA_OMSCHR EQ &AGENDA.(OR(FIND AGENDA_OMSCHR,GETAGENDASFOC.SEG01.AGENDA_OMSCHR IN GETAGENDASFOC)).AGENDA.;
WHERE SUBAGENDA EQ &SUBAGENDA.(OR(FIND SUBAGENDA,GETAGENDASFOC.SEG01.SUBAGENDA IN GETAGENDASFOC)).SUBAGENDA.;
ON TABLE HOLD AS POLIBENUT FORMAT FOCUS
END







TABLE FILE POLIBENUT
PRINT
 COMPUTE GROUP/I11=LAST GROUP+3;
 COMPUTE GROUP2/I11=LAST GROUP+4;
 COMPUTE GROUP3/I11=LAST GROUP+5;
-* HEIGHT
-* WIDTH
-* LENGTH
-* WHEELBASE
DUUR_BLOKKADES
TOEGEWEZEN_SPREEKUUR_TIJD
AFSPRAAKROOSTER
GEPLANDE_BEZETTING
BY   MAAND
ON TABLE HOLD
END







TABLE FILE HOLD
PRINT
 MAAND
 GROUP
 DUUR_BLOKKADES
 TOEGEWEZEN_SPREEKUUR_TIJD
 COMPUTE AFSPRAAKROOSTER/D5 MISSING ON=MISSING;
 COMPUTE GEPLANDE_BEZETTING/D6.1 MISSING ON=MISSING;
ON TABLE HOLD AS H1
END

TABLE FILE HOLD
PRINT
 MAAND
 GROUP2
 COMPUTE DUUR_BLOKKADES/D5 MISSING ON=MISSING;
 COMPUTE TOEGEWEZEN_SPREEKUUR_TIJD/D5 MISSING ON=MISSING;
 AFSPRAAKROOSTER
 COMPUTE GEPLANDE_BEZETTING/D6.1 MISSING ON=MISSING;
ON TABLE HOLD AS H2
END

TABLE FILE HOLD
PRINT
 MAAND
 GROUP3
 COMPUTE DUUR_BLOKKADES/D5 MISSING ON=MISSING;
 COMPUTE TOEGEWEZEN_SPREEKUUR_TIJD/D5 MISSING ON=MISSING;
 COMPUTE AFSPRAAKROOSTER/D5 MISSING ON=MISSING;
 GEPLANDE_BEZETTING
ON TABLE HOLD AS H3
END

TABLE FILE H1
PRINT
 MAAND
 GROUP
 DUUR_BLOKKADES
 TOEGEWEZEN_SPREEKUUR_TIJD
 AFSPRAAKROOSTER
 GEPLANDE_BEZETTING
ON TABLE HOLD
MORE
 FILE H2
MORE
 FILE H3
END

GRAPH FILE HOLD
PRINT
 DUUR_BLOKKADES
 TOEGEWEZEN_SPREEKUUR_TIJD
 AFSPRAAKROOSTER
 GEPLANDE_BEZETTING
ACROSS MAAND
ACROSS GROUP
ON GRAPH SET LOOKGRAPH VBRSTK1
ON GRAPH SET GRAPHEDIT SERVER
ON GRAPH SET 3D OFF
END

This message has been edited. Last edited by: Nordin Ben Ahmed,


7.7.03
OS is Windows 7
We create al sorts of outputs depending on the demand, HTML (most cases), Excel (some cases) and PDF (some cases)
 
Posts: 32 | Location: Utrecht, Holland | Registered: December 10, 2008Report This Post
Member
posted Hide Post
The formats of the COMUPTEd empty fields need to be the same as those of the real fields they are a placeholder for or the MOREs won't work right. The last TABLE is probably giving an error, and then the GRAPH is using the first HOLD. That's what I get for reusing file names.


WebFOCUS 7.6.7
Linux
HTML, Excel, PDF
 
Posts: 11 | Registered: February 19, 2009Report This Post
Silver Member
posted Hide Post
Nick,

You made my day. Smiler

It works, I am grateful.

@ all happy holidays and till next year!


7.7.03
OS is Windows 7
We create al sorts of outputs depending on the demand, HTML (most cases), Excel (some cases) and PDF (some cases)
 
Posts: 32 | Location: Utrecht, Holland | Registered: December 10, 2008Report This Post
  Powered by Social Strata  

Read-Only Read-Only Topic

Focal Point    Focal Point Forums  Hop To Forum Categories  WebFOCUS/FOCUS Forum on Focal Point     [Solved] Stacked and clustered bar in one graph

Copyright © 1996-2020 Information Builders