Focal Point Banner


As of December 1, 2020, Focal Point is retired and repurposed as a reference repository. We value the wealth of knowledge that's been shared here over the years. You'll continue to have access to this treasure trove of knowledge, for search purposes only.

Join the TIBCO Community
TIBCO Community is a collaborative space for users to share knowledge and support one another in making the best use of TIBCO products and services. There are several TIBCO WebFOCUS resources in the community.

  • From the Home page, select Predict: WebFOCUS to view articles, questions, and trending articles.
  • Select Products from the top navigation bar, scroll, and then select the TIBCO WebFOCUS product page to view product overview, articles, and discussions.
  • Request access to the private WebFOCUS User Group (login required) to network with fellow members.

Former myibi community members should have received an email on 8/3/22 to activate their user accounts to join the community. Check your Spam folder for the email. Please get in touch with us at community@tibco.com for further assistance. Reference the community FAQ to learn more about the community.


Focal Point    Focal Point Forums  Hop To Forum Categories  WebFOCUS/FOCUS Forum on Focal Point     [CLOSED] NOSPLIT Ignored (Keywords: Bug Issue)

Read-Only Read-Only Topic
Go
Search
Notify
Tools
[CLOSED] NOSPLIT Ignored (Keywords: Bug Issue)
 Login/Join
 
Member
posted
I have a PDF report that is ignoring the NOSPLIT command. The report doesn't contain any of the documented conditions that causes it to fail (below)

[NOSPLIT documentation, from HELP]
If you use NOSPLIT with PAGE-BREAK, the PAGE-BREAK must apply to a higher-level sort field. Otherwise, NOSPLIT is ignored. NOSPLIT is also ignored when report output is stored in a HOLD, SAVE, or SAVB file. NOSPLIT is not compatible with the TABLEF command and generates an error message.

I've seen a lot of users helped by the PRINTPLUS command, but it hasn't helped me.

I was hoping someone might have other ideas. I'll post the code momentarily.

If you're interested, i can provide the fex, master file, and focus data file that reproduces the issue.

Thanks,
Chris

This message has been edited. Last edited by: Kerry,


Version 7.6.10
Windows 7 Pro
all output
 
Posts: 18 | Registered: May 20, 2010Report This Post
Member
posted Hide Post
Code:
  
-* File debug.fex
-* File payroll_journal.fex
SET NODATA=' '
 
-*Setup variables needed for report.
-DEFAULT &ACCENT_COLOR = 'RGB(244 115 33)'
-DEFAULT &AMOUNT_STYLE = '0.566667'
-DEFAULT &ITEMCODE_STYLE = '0.57000'
-DEFAULT &ITEMHOURS_STYLE = '0.43334'
-DEFAULT &OUTPUT = 'PDF'
 
-SET &OUTPUT = &OUTPUT;
-RUN
 
-*?FF
DEFINE FILE XSQLOUT
BaseDept_Text/A65V = IF RecordType EQ 'EE' THEN TRIM('L', PTOA(BaseDept_OrgCode, '(P15)',BaseDept_Text), 15, ' ', 1, 'A15V') || ' ' |BaseDept_OrgDesc ELSE '';
EarningRate/P15.2CS = EarningRate;
ItemHoursEarn/P14.2S = ItemHoursEarn;
ItemAmountEarn/P21.2CS = ItemAmountEarn;
GrossAmount/P21.2CS = GrossAmount;
TaxDesc/A10VS = TaxDesc;
TaxAmount/P21.2CS = TaxAmount;
DedAmount/P21.2CS = DedAmount;
DedDesc/A10V = DedDesc;
NetAmount/P21.2CS = NetAmount;
Period_End_Date/HMDYY = Period_End_Date;
Check_Date/HMDYY = Check_Date;
ClientID/I6 = ClientID;
MVChange/I4 = MV NE LAST MV;
END
 
 
-*Payroll Journal - Report
TABLE FILE XSQLOUT
PRINT
 COMPUTE EMPINFO/A50 = IF RecordType EQ 'EE' THEN (
         IF LineNumber EQ 1 THEN last_name|', '|first_name
        ELSE IF LineNumber EQ 2 THEN ' '|'EE# '|EDIT(Emp_Number)
        ELSE ' '
       ) ELSE IF RecordType EQ 'CT' THEN (
         IF ItemAmountEarnDesc EQ 'TOTALS' EQ 1 THEN 'Totals'
        ELSE ''
       )
       ELSE ' '; AS ''
-*^^^ N10 ABOVE ^^^*-
 COMPUTE ORGCODE/P14S = IF RecordType EQ 'EE' AND LineNumber EQ 1 THEN BaseDept_OrgCode ELSE 0; AS ''
 COMPUTE EarningRate/P15.2CS = IF RecordType EQ ('TW') THEN 0 ELSE EarningRate; AS ''
 COMPUTE REGHOURS/P14.2S = IF EarnDesc EQ 'REG' THEN Hours ELSE 0; AS ''
 COMPUTE OTHOURS/P14.2S = IF EarnDesc EQ 'OT' THEN Hours ELSE 0; AS ''
 'XSQLOUT.SEG01.ItemHoursEarn' AS ''
-*^^^ N15 ABOVE ^^^*-
 COMPUTE CODEDHOURSCODE/A10V = IF ItemHoursEarn GT 0 THEN ItemAmountEarnDesc ELSE ' '; AS ''
 COMPUTE REGAMT/P21.2CS = IF EarnDesc EQ 'REG' THEN EarnAmount ELSE 0; AS ''
 COMPUTE OTAMT/P21.2CS = IF EarnDesc EQ 'OT' THEN EarnAmount ELSE 0; AS ''
 'XSQLOUT.SEG01.ItemAmountEarn' AS ''
 COMPUTE CODEDEARNCODE/A10V = IF (RecordType IN('EE','CT') AND ItemAmountEarn GT 0) THEN ItemAmountEarnDesc
           ELSE IF RecordType IN('TW','TP') THEN (
           IF RecordType EQ 'TW' AND EarnDesc EQ ' TOTAL' THEN ' Total' ELSE EarnDesc
          )
           ELSE ' '; AS ''
 -*^^^ N20 ABOVE ^^^*-
 COMPUTE GROSSAMOUNT/P21.2CS = IF RecordType IN('TW','TP') THEN 0 ELSE GrossAmount; AS ''
 'XSQLOUT.SEG01.TaxAmount' AS ''
 'XSQLOUT.SEG01.TaxDesc' AS ''
 COMPUTE DEDAMOUNT/P21.2CS = IF RecordType IN('TW','TP') THEN EarningRate ELSE DedAmount ; AS ''
 'XSQLOUT.SEG01.DedDesc' AS ''
 -*^^^ N25 ABOVE ^^^*-
 COMPUTE XNETAMOUNT/P21.2CS = IF RecordType IN('TW','TP') THEN GrossAmount ELSE NetAmount ; AS ''
 COMPUTE LINECT/I8 = LAST LINECT + 1; NOPRINT
 COMPUTE PAGE_CHANGE/I4 = IF TABPAGENO NE LAST TABPAGENO THEN 1 ELSE 0; NOPRINT
 COMPUTE SHOW_HORIZONTAL_LINE/I4 = IF LineNumber EQ 1 AND RecordType EQ 'EE' AND TABPAGENO EQ LAST TABPAGENO AND BaseDept_OrgCode EQ LAST BaseDept_OrgCode AND MVChange EQ 0 THEN 1 ELSE 0; NOPRINT
 COMPUTE IS_CT_TOTALS_LINE/I4 = IF RecordType EQ 'CT' AND ItemAmountEarnDesc EQ 'TOTALS' THEN 1 ELSE 0; NOPRINT
 -*^^^ N30 ABOVE ^^^*-
 COMPUTE IS_TW_TOTALS_LINE/I4 = IF RecordType EQ 'TW' AND EarnDesc EQ ' TOTAL' THEN 1 ELSE 0; NOPRINT
 COMPUTE TITLE/A22V = IF MV EQ 'Y' THEN 'MANUAL JOURNAL' ELSE 'PAYROLL JOURNAL'; NOPRINT
 'MVChange' NOPRINT AS ''
BY HIGHEST 'XSQLOUT.SEG01.MV' NOPRINT AS ''
BY 'XSQLOUT.SEG01.TK' NOPRINT AS ''
BY 'XSQLOUT.SEG01.BaseDept_OrgCode' NOPRINT AS ''
BY 'XSQLOUT.SEG01.RecordType' NOPRINT AS ''
BY 'XSQLOUT.SEG01.last_name' NOPRINT AS ''
-*^^^ N5 ABOVE ^^^*-
BY 'XSQLOUT.SEG01.first_name' NOPRINT AS ''
BY 'XSQLOUT.SEG01.empuid' NOPRINT AS ''
BY 'XSQLOUT.SEG01.Pay_Number' NOPRINT AS ''
BY 'XSQLOUT.SEG01.LineNumber' NOPRINT AS ''
 
ON XSQLOUT.SEG01.MV REPAGE PAGE-BREAK
 
ON XSQLOUT.SEG01.empuid NOSPLIT
 
-*SubHead for top of page*-
ON XSQLOUT.SEG01.LineNumber SUBHEAD
"Employee<+0>Hours<+0>Earnings<+0>Gross<+0>Taxes<+0>Deductions<+0>Net Pay"
"<BaseDept_Text<+0>RATE<+0>REG<+0>OT<+0>CODED<+0>REG<+0>OT<+0>CODED"
WHEN (PAGE_CHANGE EQ 1 OR MVChange EQ 1 OR (LINECT EQ 1)) AND RecordType IN('CT','EE');
 
-*SubHead for top of page - Taxable Wages*-
ON XSQLOUT.SEG01.LineNumber SUBHEAD
"Employee<+0>Hours<+0>Earnings<+0>Gross<+0>Taxes<+0>Deductions<+0>Net Pay"
" <+0> <+0> <+0> <+0> <+0> <+0> <+0>TAXABLE WAGES<+0>RATE%<+0>EMPLOYER LIABILITY"
WHEN (PAGE_CHANGE EQ 1 OR MVChange EQ 1 OR (LINECT EQ 1)) AND RecordType EQ 'TW';
 
-*SubHead for top of page - Tips*-
ON XSQLOUT.SEG01.LineNumber SUBHEAD
"Employee<+0>Hours<+0>Earnings<+0>Gross<+0>Taxes<+0>Deductions<+0>Net Pay"
" <+0> <+0> <+0> <+0> <+0> <+0> <+0>TIP CREDIT"
WHEN (PAGE_CHANGE EQ 1 OR MVChange EQ 1 OR (LINECT EQ 1)) AND RecordType EQ 'TP';
 
-*SubHead for department change mid page*-
ON XSQLOUT.SEG01.LineNumber SUBHEAD
""
"<BaseDept_Text<+0>RATE<+0>REG<+0>OT<+0>CODED<+0>REG<+0>OT<+0>CODED"
WHEN BaseDept_OrgCode NE LAST BaseDept_OrgCode AND LINECT NE 1 AND PAGE_CHANGE NE 1 AND RecordType IN('CT','EE') AND MVChange NE 1;
 
-*SubHead for change to taxable wages mid page*-
ON XSQLOUT.SEG01.LineNumber SUBHEAD
""
" <+0> <+0> <+0> <+0> <+0> <+0> <+0>TAXABLE WAGES<+0>RATE%<+0>EMPLOYER LIABILITY"
WHEN BaseDept_OrgCode NE LAST BaseDept_OrgCode AND LINECT NE 1 AND PAGE_CHANGE NE 1 AND RecordType EQ 'TW' AND MVChange NE 1;
 
-*SubHead for change to tips mid page*-
ON XSQLOUT.SEG01.LineNumber SUBHEAD
""
" <+0> <+0> <+0> <+0> <+0> <+0> <+0>TIP CREDIT"
WHEN BaseDept_OrgCode NE LAST BaseDept_OrgCode AND LINECT NE 1 AND PAGE_CHANGE NE 1 AND RecordType EQ 'TP' AND MVChange NE 1;
 
HEADING
"&DATEMDYY"
"&TOD"
"Client: <ClientID <+0> <name - <PayrollName"
 
FOOTING BOTTOM
"<name                 <+0>Period Ending:<+0> <Period_End_Date          <+0>PayDate:<+0> <Check_Date                  <TITLE<+0>      <+0>Page<+0> <TABPAGENO"
 
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT &OUTPUT
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TITLETEXT='Prepost Payroll Journal', UNITS=IN, PAGESIZE='Letter', SQUEEZE=ON, ORIENTATION=LANDSCAPE, TOPMARGIN=0.15000, BOTTOMMARGIN=0.15000, RIGHTMARGIN=0.25000, $
DEFMACRO=COND_FIRST_ROW_FOR_EMPLOYEE, MACTYPE=RULE, WHEN=N29 EQ 1, $
DEFMACRO=COND_PAGE_CHANGED, MACTYPE=RULE, WHEN=N28 EQ 1, $
DEFMACRO=COND_MVCHANGED, MACTYPE=RULE, WHEN=N33 EQ 1, $
DEFMACRO=COND_IS_FIRST_LINE_OF_REPORT, MACTYPE=RULE, WHEN=N27 EQ 1, $
DEFMACRO=COND_SHOW_TOTAL_LINE_FORMAT, MACTYPE=RULE, WHEN=N30 EQ 1, $
DEFMACRO=COND_IS_TW_TOTAL_LINE, MACTYPE=RULE, WHEN=N31 EQ 1, $
DEFMACRO=COND_IS_EMPLOYEE, MACTYPE=RULE, WHEN=N4 EQ 'EE', $
DEFMACRO=COND_LINE_NUMBER_IS_ONE, MACTYPE=RULE, WHEN=N9 EQ 1, $
TYPE=REPORT, FONT='ARIAL', SIZE=8, COLOR='BLACK', STYLE=NORMAL, RIGHTGAP=0.041667, LEFTGAP=0.000000, BORDER-COLOR='&ACCENT_COLOR', $
TYPE=DATA, BORDER-TOP=OFF, BORDER-RIGHT=OFF, FONT='ARIAL', SIZE=7, STYLE=NORMAL, $
TYPE=DATA, COLUMN=N10, STYLE=BOLD, SIZE=9, MACRO=COND_LINE_NUMBER_IS_ONE, WHEN=N4 EQ 'CT', $
TYPE=DATA, BORDER-TOP=LIGHT, BORDER-TOP-COLOR='GRAY', MACRO=COND_FIRST_ROW_FOR_EMPLOYEE, $
TYPE=DATA, COLUMN=N10, BORDER-TOP=LIGHT, BORDER-TOP-COLOR='GRAY', MACRO=COND_FIRST_ROW_FOR_EMPLOYEE, $
TYPE=DATA, COLUMN=N13, BORDER-TOP=LIGHT, BORDER-TOP-COLOR='GRAY', MACRO=COND_FIRST_ROW_FOR_EMPLOYEE, $
TYPE=DATA, COLUMN=N14, BORDER-TOP=LIGHT, BORDER-TOP-COLOR='GRAY', MACRO=COND_FIRST_ROW_FOR_EMPLOYEE, $
TYPE=DATA, COLUMN=N15, BORDER-TOP=LIGHT, BORDER-TOP-COLOR='GRAY', MACRO=COND_FIRST_ROW_FOR_EMPLOYEE, $
TYPE=DATA, COLUMN=N17, BORDER-TOP=LIGHT, BORDER-TOP-COLOR='GRAY', MACRO=COND_FIRST_ROW_FOR_EMPLOYEE, $
TYPE=DATA, COLUMN=N18, BORDER-TOP=LIGHT, BORDER-TOP-COLOR='GRAY', MACRO=COND_FIRST_ROW_FOR_EMPLOYEE, $
TYPE=DATA, COLUMN=N19, BORDER-TOP=LIGHT, BORDER-TOP-COLOR='GRAY', MACRO=COND_FIRST_ROW_FOR_EMPLOYEE, $
TYPE=DATA, COLUMN=N22, BORDER-TOP=LIGHT, BORDER-TOP-COLOR='GRAY', MACRO=COND_FIRST_ROW_FOR_EMPLOYEE, $
TYPE=DATA, COLUMN=N24, BORDER-TOP=LIGHT, BORDER-TOP-COLOR='GRAY', MACRO=COND_FIRST_ROW_FOR_EMPLOYEE, $
TYPE=DATA, COLUMN=N26, BORDER-TOP=LIGHT, BORDER-TOP-COLOR='GRAY', MACRO=COND_FIRST_ROW_FOR_EMPLOYEE, $
TYPE=DATA, COLUMN=N12, BORDER-RIGHT=LIGHT, MACRO=COND_IS_EMPLOYEE, $
TYPE=DATA, COLUMN=N16, BORDER-RIGHT=LIGHT, MACRO=COND_IS_EMPLOYEE, $
TYPE=DATA, COLUMN=N20, BORDER-RIGHT=LIGHT, MACRO=COND_IS_EMPLOYEE, $
TYPE=DATA, COLUMN=N21, BORDER-RIGHT=LIGHT, MACRO=COND_IS_EMPLOYEE, $
TYPE=DATA, COLUMN=N23, BORDER-RIGHT=LIGHT, MACRO=COND_IS_EMPLOYEE, $
TYPE=DATA, COLUMN=N25, BORDER-RIGHT=LIGHT, MACRO=COND_IS_EMPLOYEE, $
TYPE=DATA, COLUMN=N11, BORDER-RIGHT=OFF, $
TYPE=DATA, BORDER-TOP=LIGHT, MACRO=COND_SHOW_TOTAL_LINE_FORMAT, $
TYPE=DATA, COLUMN=N10, STYLE=BOLD+ITALIC, COLOR='WHITE', SIZE=10, MACRO=COND_SHOW_TOTAL_LINE_FORMAT, BACKCOLOR='&ACCENT_COLOR', $
TYPE=DATA, COLUMN=N12, BORDER-TOP=LIGHT, MACRO=COND_SHOW_TOTAL_LINE_FORMAT, $
TYPE=DATA, COLUMN=N13, BORDER-TOP=LIGHT, MACRO=COND_SHOW_TOTAL_LINE_FORMAT, $
TYPE=DATA, COLUMN=N14, BORDER-TOP=LIGHT, MACRO=COND_SHOW_TOTAL_LINE_FORMAT, $
TYPE=DATA, COLUMN=N15, BORDER-TOP=LIGHT, MACRO=COND_SHOW_TOTAL_LINE_FORMAT, $
TYPE=DATA, COLUMN=N16, BORDER-TOP=LIGHT, MACRO=COND_SHOW_TOTAL_LINE_FORMAT, $
TYPE=DATA, COLUMN=N17, BORDER-TOP=LIGHT, MACRO=COND_SHOW_TOTAL_LINE_FORMAT, $
TYPE=DATA, COLUMN=N18, BORDER-TOP=LIGHT, MACRO=COND_SHOW_TOTAL_LINE_FORMAT, $
TYPE=DATA, COLUMN=N19, BORDER-TOP=LIGHT, MACRO=COND_SHOW_TOTAL_LINE_FORMAT, $
TYPE=DATA, COLUMN=N20, BORDER-TOP=LIGHT, MACRO=COND_SHOW_TOTAL_LINE_FORMAT, $
TYPE=DATA, COLUMN=N21, STYLE=BOLD, BORDER-TOP=LIGHT, MACRO=COND_SHOW_TOTAL_LINE_FORMAT, $
TYPE=DATA, COLUMN=N22, STYLE=BOLD, BORDER-TOP=LIGHT, MACRO=COND_SHOW_TOTAL_LINE_FORMAT, $
TYPE=DATA, COLUMN=N23, BORDER-TOP=LIGHT, MACRO=COND_SHOW_TOTAL_LINE_FORMAT, $
TYPE=DATA, COLUMN=N24, STYLE=BOLD, BORDER-TOP=LIGHT, MACRO=COND_SHOW_TOTAL_LINE_FORMAT, $
TYPE=DATA, COLUMN=N25, BORDER-TOP=LIGHT, MACRO=COND_SHOW_TOTAL_LINE_FORMAT, $
TYPE=DATA, COLUMN=N26, STYLE=BOLD, BORDER-TOP=LIGHT, MACRO=COND_SHOW_TOTAL_LINE_FORMAT, $
TYPE=DATA, COLUMN=N20, STYLE=BOLD+ITALIC, BACKCOLOR='&ACCENT_COLOR', COLOR='WHITE', MACRO=COND_IS_TW_TOTAL_LINE, $
TYPE=DATA, COLUMN=N21, BORDER-TOP=LIGHT, MACRO=COND_IS_TW_TOTAL_LINE, $
TYPE=DATA, COLUMN=N22, BORDER-TOP=LIGHT, MACRO=COND_IS_TW_TOTAL_LINE, $
TYPE=DATA, COLUMN=N23, BORDER-TOP=LIGHT, MACRO=COND_IS_TW_TOTAL_LINE, $
TYPE=DATA, COLUMN=N24, BORDER-TOP=LIGHT, MACRO=COND_IS_TW_TOTAL_LINE, $
TYPE=DATA, COLUMN=N25, BORDER-TOP=LIGHT, MACRO=COND_IS_TW_TOTAL_LINE, $
TYPE=DATA, COLUMN=N26, BORDER-TOP=LIGHT, MACRO=COND_IS_TW_TOTAL_LINE, $
TYPE=HEADING, SIZE=10, STYLE=BOLD, $
TYPE=HEADING, LINE=1, JUSTIFY=RIGHT, STYLE=-BOLD, SIZE=7, $
TYPE=HEADING, LINE=2, JUSTIFY=RIGHT, STYLE=-BOLD, SIZE=7, $
TYPE=HEADING, LINE=3, JUSTIFY=CENTER, STYLE=+ITALIC, $
TYPE=SUBHEAD,LINE=1,BORDER-TOP=OFF,FONT='ARIAL',SIZE=9,STYLE=BOLD, $
TYPE=SUBHEAD,LINE=1,BORDER-TOP=LIGHT,MACRO=COND_PAGE_CHANGED,$
TYPE=SUBHEAD,LINE=1,BORDER-TOP=LIGHT,MACRO=COND_MVCHANGED,$
TYPE=SUBHEAD,LINE=1,BORDER-TOP=LIGHT,MACRO=COND_IS_FIRST_LINE_OF_REPORT,$
TYPE=SUBHEAD,LINE=1,OBJECT=TEXT,ITEM=1,WIDTH=3.12,$
TYPE=SUBHEAD,LINE=1,OBJECT=TEXT,ITEM=2,WIDTH=2.15,$
TYPE=SUBHEAD,LINE=1,OBJECT=TEXT,ITEM=3,WIDTH=1.66,$
TYPE=SUBHEAD,LINE=1,OBJECT=TEXT,ITEM=4,WIDTH=0.91,$
TYPE=SUBHEAD,LINE=1,OBJECT=TEXT,ITEM=5,WIDTH=1.01,$
TYPE=SUBHEAD,LINE=1,OBJECT=TEXT,ITEM=6,WIDTH=1.14,$
TYPE=SUBHEAD,LINE=2,OBJECT=FIELD,ITEM=1,WIDTH=1.90, $
TYPE=SUBHEAD,LINE=2,OBJECT=TEXT,ITEM=1,WIDTH=0.65, $
TYPE=SUBHEAD,LINE=2,OBJECT=TEXT,ITEM=2,WIDTH=0.47, $
TYPE=SUBHEAD,LINE=2,OBJECT=TEXT,ITEM=3,WIDTH=0.50, $
TYPE=SUBHEAD,LINE=2,OBJECT=TEXT,ITEM=4,WIDTH=1.00, $
TYPE=SUBHEAD,LINE=2,OBJECT=TEXT,ITEM=5,WIDTH=0.75, $
TYPE=SUBHEAD,LINE=2,OBJECT=TEXT,ITEM=6,WIDTH=0.70, $
TYPE=SUBHEAD,LINE=2,OBJECT=TEXT,ITEM=7,WIDTH=2.05, $
TYPE=SUBHEAD,LINE=2,OBJECT=TEXT,ITEM=8,WIDTH=2.70, $
TYPE=SUBHEAD,LINE=2,OBJECT=TEXT,ITEM=9,WIDTH=0.52, $
TYPE=SUBHEAD,LINE=2, STYLE=BOLD, JUSTIFY=LEFT, COLOR='WHITE', BACKCOLOR='&ACCENT_COLOR',$
TYPE=FOOTING, LINE=1, BORDER-TOP=LIGHT, JUSTIFY=RIGHT, BOTTOMGAP=0.00000, $
TYPE=FOOTING, LINE=1, OBJECT=FIELD, ITEM=1, STYLE=BOLD+ITALIC, SIZE=10, $
TYPE=FOOTING, LINE=1, OBJECT=TEXT, ITEM=2, STYLE=BOLD, $
TYPE=FOOTING, LINE=1, OBJECT=TEXT, ITEM=5, STYLE=BOLD, $
TYPE=FOOTING, LINE=1, OBJECT=TEXT, ITEM=6, STYLE=BOLD, $
TYPE=FOOTING, LINE=1, OBJECT=FIELD, ITEM=4, COLOR='WHITE', SIZE=12, WIDTH=2.305, STYLE=BOLD, $
TYPE=REPORT, OBJECT=BOX, name='line1', position = (7.80 7.99), dimension = (2.305 0.25), backcolor='&ACCENT_COLOR', border-color='&ACCENT_COLOR', $
TYPE=FOOTING, LINE=1, OBJECT=TEXT, ITEM=9, STYLE=BOLD, WIDTH=0.6, $
TYPE=REPORT, COLUMN=N10, SQUEEZE=1.000000, $
TYPE=REPORT, COLUMN=N11, SQUEEZE=0.621340, $
TYPE=REPORT, COLUMN=N12, SQUEEZE=&AMOUNT_STYLE, $
TYPE=REPORT, COLUMN=N13, SQUEEZE=&ITEMHOURS_STYLE, $
TYPE=REPORT, COLUMN=N14, SQUEEZE=&ITEMHOURS_STYLE, $
TYPE=REPORT, COLUMN=N15, SQUEEZE=&ITEMHOURS_STYLE, $
TYPE=REPORT, COLUMN=N16, SQUEEZE=&ITEMCODE_STYLE, $
TYPE=REPORT, COLUMN=N17, SQUEEZE=&AMOUNT_STYLE, $
TYPE=REPORT, COLUMN=N18, SQUEEZE=&AMOUNT_STYLE, $
TYPE=REPORT, COLUMN=N19, SQUEEZE=&AMOUNT_STYLE, $
TYPE=REPORT, COLUMN=N20, SQUEEZE=&ITEMCODE_STYLE, $
TYPE=REPORT, COLUMN=N21, SQUEEZE=0.691670, $
TYPE=REPORT, COLUMN=N22, SQUEEZE=0.504170, $
TYPE=REPORT, COLUMN=N23, SQUEEZE=0.507500, $
TYPE=REPORT, COLUMN=N24, SQUEEZE=0.629170, $
TYPE=REPORT, COLUMN=N25, SQUEEZE=&ITEMCODE_STYLE, $
TYPE=REPORT, COLUMN=N26, SQUEEZE=0.660000, $
ENDSTYLE
END
 
 



Version 7.6.10
Windows 7 Pro
all output
 
Posts: 18 | Registered: May 20, 2010Report This Post
Expert
posted Hide Post
Hi Chris,

If this is a bug issue, the proper channel to confirm and/or to fix is via a case with Customer Support Services. You may report this issue to 1-800-736-6130, or access online at InfoResponse.

Cheers,

Kerry


Kerry Zhan
Focal Point Moderator
Information Builders, Inc.
 
Posts: 1948 | Location: New York | Registered: November 16, 2004Report This Post
Virtuoso
posted Hide Post
You have the column-name quoted in the BY clause, but not in the ON clause:

BY HIGHEST 'XSQLOUT.SEG01.MV' NOPRINT AS ''
. . .
BY 'XSQLOUT.SEG01.empuid' NOPRINT AS ''

ON XSQLOUT.SEG01.MV REPAGE PAGE-BREAK
ON XSQLOUT.SEG01.empuid NOSPLIT
. . . 



See what happens if you code it consistently.


- Jack Gross
WF through 8.1.05
 
Posts: 1925 | Location: NYC | In FOCUS since 1983 | Registered: January 11, 2005Report This Post
Expert
posted Hide Post
I wonder why the fields were guoted ?, usually this is because of field names with nasty characters, like spaces.


Waz...

Prod:WebFOCUS 7.6.10/8.1.04Upgrade:WebFOCUS 8.2.07OS:LinuxOutputs:HTML, PDF, Excel, PPT
In Focus since 1984
Pity the lost knowledge of an old programmer!

 
Posts: 6347 | Location: 33°49'23.0"S, 151°11'41.0"E | Registered: October 31, 2006Report This Post
Member
posted Hide Post
Thanks for the suggestions, I've tried removing the quotes on the fields names to make it more consistent, but it's still splitting.

There is a case open about this with customer support as well, I'll post the findings when I get them

Thanks for the suggestions!
Chris


Version 7.6.10
Windows 7 Pro
all output
 
Posts: 18 | Registered: May 20, 2010Report This Post
  Powered by Social Strata  

Read-Only Read-Only Topic

Focal Point    Focal Point Forums  Hop To Forum Categories  WebFOCUS/FOCUS Forum on Focal Point     [CLOSED] NOSPLIT Ignored (Keywords: Bug Issue)

Copyright © 1996-2020 Information Builders