Hello,
We use joins in almost all of our Dev Studio reports. APP HOLD is new to us.

We create 2 APP HOLD files. A separate hold file is created with criteria. We want to join the last hold file (step3) to the 2 APP HOLDs (step 1 and step 2). I can create the joins but when I go back into the join, it is no longer joined. The subsequent hold file cannot be created for this reason. The first 2 steps are scheduled reports. The last tries to access the scheduled reports which run without error.

What do we need to change to make this work? A search of the forum did not find anything similar. I could not find anything similar in ibisamp to use as the example.

-*>>>>>>>STEP 1

APP HOLD MASTERS_PRD_ONLY

TABLE FILE KNVP
PRINT
KNVP.KNVP.KNVP_KUNNR
KNVP.KNVP.KNVP_VKORG
KNVP.KNVP.KNVP_PARVW
KNVP.KNVP.KNVP_KUNN2
WHERE KNVP_PARVW EQ 'ZV' OR 'RG' ;
WHERE KNVP.KNVP.KNVP_VKORG EQ '6460';
ON TABLE HOLD AS PART01
END

DEFINE FILE PART01
RGNMBR/A10 = IF PART01.PART01.KNVP_PARVW EQ 'RG' THEN PART01.PART01.KNVP_KUNN2 ELSE '';
ZVNMBR/A10 = IF PART01.PART01.KNVP_PARVW EQ 'ZV' THEN PART01.PART01.KNVP_KUNN2 ELSE '';
END

TABLE FILE PART01
SUM
MAX.PART01.PART01.RGNMBR AS 'PART01.PART01.RGNMBR'
MAX.PART01.PART01.ZVNMBR AS 'PART01.PART01.ZVNMBR'
BY PART01.PART01.KNVP_KUNNR
BY PART01.PART01.KNVP_VKORG

HEADING
""
FOOTING
""
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE NOTOTAL
ON TABLE HOLD AS S_PARTNERS2 FORMAT FOCUS INDEX 'PART01.PART01.KNVP_KUNNR' 'PART01.PART01.KNVP_VKORG'
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
INCLUDE = endeflt,
$
ENDSTYLE
END

-*>>>>>>>STEP 2

APP HOLD MASTERS_PRD_ONLY

SET BYDISPLAY = ON
SET ASNAMES = ON

TABLE FILE KNA1
PRINT
'KNA1.KNA1.KNA1_MANDT'
'KNA1.KNA1.KNA1_NAME1'
'KNA1.KNA1.KNA1_NAME2'
'KNA1.KNA1.KNA1_KTOKD' AS 'CUST_TYPE'
BY 'KNA1.KNA1.KNA1_KUNNR'
WHERE ( KNA1.KNA1.KNA1_MANDT EQ '340' );
WHERE KNA1.KNA1.KNA1_KTOKD EQ 'Z001' OR 'Z002' OR 'Z990' OR 'ZCSS' OR 'Z990' OR 'Z991' OR 'ZGC' OR 'ZPTR' OR 'ZSYS';
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE NOTOTAL
ON TABLE HOLD AS S_NAME_CUSTOMERS FORMAT FOCUS INDEX 'KNA1.KNA1.KNA1_KUNNR'
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
INCLUDE = endeflt,
$
ENDSTYLE
END


-*>>>>>>>STEP 3

TABLE FILE KNVV
PRINT
KNVV.KNVV.KNVV_ERNAM
BY LOWEST KNVV.KNVV.KNVV_KUNNR
BY LOWEST KNVV.KNVV.KNVV_VKORG
WHERE KNVV.KNVV.KNVV_VKORG EQ '6460';
ON TABLE HOLD AS HOLDME1
END

JOIN
HOLDME1.HOLDME1.KNVV_KUNNR IN HOLDME1 TO UNIQUE S_PARTNERS2.SEG01.KNVP_KUNNR
IN S_PARTNERS2 TAG J4 AS J4
END
JOIN
HOLDME1.HOLDME1.KNVV_VKORG IN HOLDME1 TO UNIQUE S_PARTNERS2.SEG01.KNVP_VKORG
IN S_PARTNERS2 TAG J5 AS J5
END
JOIN
J4.SEG01.RGNMBR IN HOLDME1 TO UNIQUE S_NAME_CUSTOMERS.SEG01.KNA1_KUNNR
IN S_NAME_CUSTOMERS TAG J6 AS J6
END

-*CREATE HOLDME1 FILE BELOW

This message has been edited. Last edited by: Geri,

Step 3 should include an explicit USE, specifying where the two Focus hold files are located.

It would also be a good idea for it to list the contents of the Hold app folder (via !dir or !ls), to verify existence and vintage of the .foc and .mas files.

Hello,

I cannot search on the word USE. Can you please give me an example?

I found in Dev Studio help the following:
-UNIX ls -l grep fex
-DOS dir *.fex
However, none end with !. Would this be what you are suggesting?

Thank you.

So the two run and then you come in later and run the 3rd one?

The third one needs to know where to find the hold files.
APP PATH MASTERS_PRD_ONLY
You need in the APP PATH where the HOLD files are located and where the other masters you are joining are located.

Also did you look in APP HOLD MASTERS_PRD_ONLY

and make sure the hold files are there?

Prarie,

I confirmed the masters are in APP PATH MASTERS_PRD_ONLY from step1 and step2.

My apppath show MASTERS_PRD_ONLY as the first file with masters. However adding the APP PATH MASTERS_PRD_ONLY statement at the top of the fex made this work.

Thank You!

Great!

quote:

I cannot search on the word USE.

Use the dev studio Help files. Choose Index, search on USE.

The ! is a synonym for UNIX or WINNT.