I know this topic has been covered lots of times. I apologise for reopening the discussion. I was not able to get a concrete solution after going thru the topics. After going thru the topics in the forum, I found out that SET PAGE-NUM = ON is the only option to display the page numbering. And it appears in the top left corner of the report.
Our users want the page number to be displayed at the bottom right.
and my compound report consists of 3 FEXs. So , i cannot use TABPAGENO. , it will display inconsistent pageno. which will be confusing.
Is there any way where we can control the page-breaks ourselves in all the three output formats . HTML , PDF , EXL2K . Then , accordinlgy , count the total pages store it in a variable . Then have another variable and increment it one by one till it reaches the final count.
(I tried SET LINES clause and it is not working in a compund report. )
Is it possible ??
Thank you very muchThis message has been edited. Last edited by: Kerry,
WebFOCUS 714 Windows XP Output: HTML,PDF,Excel
July 14, 2008, 02:05 AM
Tony A
Arvind,
Search on FOCFIRSTPAGE and you will find many suggestions on how to achieve what you want to do.
T
In FOCUS since 1986
WebFOCUS Server 8.2.01M, thru 8.2.07 on Windows Svr 2008 R2
WebFOCUS App Studio 8.2.06 standalone on Windows 10
July 14, 2008, 03:16 AM
arvind
HI TONY,
Thanks a lot for your tip.. But , when i use the clause FOCFIRSTPAGE AND consequently hte parameter &focnextpage. The page number gets displayed only at the top right??
When i use TABPAGENO variable i cannot use FOCFIRSTPAGE , so it is either one of the two..
Can you please suggest a way where the page number can be displayed at the bottom using FOCFIRSTPAGE..
Thank you for your patience T
WebFOCUS 714 Windows XP Output: HTML,PDF,Excel
July 14, 2008, 04:37 AM
Tony A
[IOTW]
quote:
SET PAGE-NUM = ON is the only option to display the page numbering
Simply not true, but then if you had any training you would probably have known that.
quote:
When i use TABPAGENO variable i cannot use FOCFIRSTPAGE , so it is either one of the two..
Really? I have many fexes that use this combination, but then I don't use SET PAGE-NUM = ON.
I really think that it is about time you either refreshed any training you might have had or went for the basic training courses available.
T
In FOCUS since 1986
WebFOCUS Server 8.2.01M, thru 8.2.07 on Windows Svr 2008 R2
WebFOCUS App Studio 8.2.06 standalone on Windows 10
In the above link , it is mentioned that if I use both TABPAGENO , theN FOCFIRSTPAGE is ignored. ???
Please explain.
WebFOCUS 714 Windows XP Output: HTML,PDF,Excel
July 14, 2008, 06:37 AM
StuBouyer
It does say that, however it doesn't appear to be the case
Try this and see if it's ignored.
SET FOCFIRSTPAGE = 5
TABLE FILE CAR
PRINT
MODEL
SEATS
RETAIL_COST
BY COUNTRY
BY CAR
ON COUNTRY PAGE-BREAK
HEADING
""
FOOTING
"Page <TABPAGENO"
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
END
cheers
Stu
WebFOCUS 8.2.03 (8.2.06 in testing)
July 14, 2008, 06:44 AM
Danny-SRL
Arvind,
I ran this in DS 765 and it numbers the pages sequentially:
-* File compound_pdf.fex
TABLE FILE CAR
PRINT SALES
BY COUNTRY PAGE-BREAK
BY CAR
BY BODY
ON TABLE SET COMPOUND OPEN
ON TABLE PCHOLD FORMAT PDF
FOOTING BOTTOM
"<40>Page <TABPAGENO>"
" "
ON TABLE SET STYLE *
TYPE=FOOTING, STYLE=BOLD, $
END
TABLE FILE CAR
PRINT SALES
BY COUNTRY PAGE-BREAK
BY CAR
BY BODY
ON TABLE PCHOLD FORMAT PDF
FOOTING BOTTOM
"<40>Page <TABPAGENO>"
" "
ON TABLE SET STYLE *
TYPE=FOOTING, STYLE=BOLD, $
END
TABLE FILE CAR
PRINT SALES
BY COUNTRY PAGE-BREAK
BY CAR
BY BODY
ON TABLE SET COMPOUND CLOSE
ON TABLE PCHOLD FORMAT PDF
FOOTING BOTTOM
"<40>Page <TABPAGENO>"
" "
ON TABLE SET STYLE *
TYPE=FOOTING, STYLE=BOLD, $
END
Daniel In Focus since 1982 wf 8.202M/Win10/IIS/SSA - WrapApp Front End for WF
July 14, 2008, 06:57 AM
Tony A
At last, proof that you are actually looking things up and reading the content! The question is - did you try it anyway?
Try this code -
TABLE FILE CAR
SUM RCOST
DCOST
BY COUNTRY
BY CAR
BY MODEL
WHERE COUNTRY EQ 'ENGLAND'
FOOTING
"Page <TABPAGENO </1"
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET PAGE NOLEAD
ON TABLE SET STYLE *
GRID=OFF, SIZE=9, $
TYPE=FOOTING, JUSTIFY=RIGHT, $
ENDSTYLE
END
TABLE FILE CAR
SUM RCOST
DCOST
BY COUNTRY
BY CAR
BY MODEL
WHERE COUNTRY EQ 'ENGLAND'
FOOTING
"Page <TABPAGENO </1"
ON TABLE SET FOCFIRSTPAGE 2
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET PAGE NOLEAD
ON TABLE SET STYLE *
GRID=OFF, SIZE=9, $
TYPE=FOOTING, JUSTIFY=RIGHT, $
ENDSTYLE
END
TABLE FILE CAR
SUM RCOST
DCOST
BY COUNTRY
BY CAR
BY MODEL
WHERE COUNTRY EQ 'ENGLAND'
FOOTING
"Page <TABPAGENO "
ON TABLE SET FOCFIRSTPAGE 3
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET PAGE NOLEAD
ON TABLE SET STYLE *
GRID=OFF, SIZE=9, $
TYPE=FOOTING, JUSTIFY=RIGHT, $
ENDSTYLE
END
You will notice the page numbers are 1, 2 and 3. If you place a -RUN between the individual Table requests then you can use the syntax ON TABLE SET FOCFIRSTPAGE &FOCNEXTPAGE. Ok, this is HTML output but use in a PDF compound document and see how it behaves. e.g. try it for yourself.
Now obviously this is in conflict with what the manual states and it could, in future releases, stop working this way. But the point is that you try it for yourself and not wait for someone to tell you a method of doing it. If you play with the code you will start to learn more about how the language functions.
There are some great examples of posters who read the documentation and then try out what it states, raising a question when it doesn't work the way the manual says it should and documenting what they have tried. This helps us all learn that little bit more and contributes to the Forum.
Happy prototyping.
T
In FOCUS since 1986
WebFOCUS Server 8.2.01M, thru 8.2.07 on Windows Svr 2008 R2
WebFOCUS App Studio 8.2.06 standalone on Windows 10
July 14, 2008, 07:40 AM
arvind
Thank you STU , DANIEL , TONY
This forum is one big happy family.
..I will work with the code ...
WebFOCUS 714 Windows XP Output: HTML,PDF,Excel
July 14, 2008, 09:16 AM
GinnyJakes
This won't help Arvind but in 7.6 you can create a Page Master for the PDF Layout Painter and put a page number in it. Since the page master is used globally for all reports in a document, it numbers the entire document regardless of the report.
The PDF report I'm working with contains two coordinated flowing reports in page layout1. Page layout2 is a single fixed report with a small summary of data presented in tabular form. The page master contains page x of y in a text field that is positioned properly for display above all report page content but within the page master margins. It simply will not display the page numbering. Any ideas?