Hi,

I am trying to make this example that comes with the webfocus documentation works but I am not able.
This example is supposed to generate a report that concatenate to other reports : Report1 and Report2:
When I run report 3 I got just the result of report 2 but not report1.

Any suggestion will be greatly appreciated

The code of Report1 is :
GRAPH FILE SHORT
SUM PROJECTED_RETURN AS 'Return on Investment'
BY HOLDER
ACROSS CONTINENT
ON GRAPH SET LOOKGRAPH 3D_BAR
ON GRAPH SET GRAPHEDIT SERVER
ON GRAPH HOLD AS SLSGRPH1 FORMAT GIF
END
SET COMPOUND='OPEN NOBREAK'
TABLE FILE SHORT
SUM PROJECTED_RETURN AS 'Return on Investment'
BY CONTINENT
BY HOLDER
HEADING
"Investment Report"
" "
ON TABLE SET STYLE *


TYPE=DATA, BACKCOLOR=( BY=B2 'SILVER' 'WHITE' ), $
TYPE=HEADING, SIZE=14, STYLE=BOLD, $
TYPE=REPORT, IMAGE=SLSGRPH1.gif, POSITION=(4.5 0.5), SIZE=(3.5 2.5), $
ENDSTYLE
ON TABLE PCHOLD FORMAT PDF
END

The code of Report2 is:

GRAPH FILE TRADES
SUM AMOUNT
BY CONTINENT
ON GRAPH SET LOOKGRAPH PIE
ON GRAPH SET GRAPHEDIT SERVER
ON GRAPH HOLD AS TRDSGR1 FORMAT GIF
END

-*SET COMPOUND=NOBREAK
TABLE FILE TRADES
SUM AMOUNT AS 'Amount'
BY CONTINENT AS 'Continent'
BY REGION AS 'Region'
HEADING
"Trades Report"
" "
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TYPE=DATA, BACKCOLOR=( BY=B2 'SILVER' 'WHITE' ), $
TYPE=HEADING, SIZE=14, STYLE=BOLD, $
TYPE=REPORT, IMAGE=TRDSGR1.gif, POSITION=(4 3), SIZE=(4 2.5), $
ENDSTYLE
ON TABLE PCHOLD FORMAT HTML
END

The code of Report 3 is :


GRAPH FILE SHORT
SUM BALANCE
BY CONTINENT
ON GRAPH SET LOOKGRAPH 3D_BAR
ON GRAPH SET GRAPHEDIT SERVER
ON GRAPH SET STYLE *
TYPE=DATA, COLOR=RED,$
ENDSTYLE
ON GRAPH HOLD AS BALGR1 FORMAT GIF
END

SET COMPOUND=CLOSE
TABLE FILE SHORT
SUM BALANCE AS 'Balance'
BY CONTINENT AS 'Continent'
BY REGION AS 'Region'
HEADING
"Balance by Region"
" "
ON TABLE SET STYLE *
TYPE=DATA, BACKCOLOR=( BY=B2 'SILVER' 'WHITE' ), $
TYPE=HEADING, SIZE=14, STYLE=BOLD, $
TYPE=REPORT, IMAGE=BALGR1.gif, POSITION=(4 6), SIZE=(4 2.5), $
ENDSTYLE
ON TABLE PCHOLD FORMAT EXL2K
END

Majid,

Since you have 762, have you looked into using the PDF Layout Painter to combine your reports. You can find the documentation in the New Features manual for 7.6.

I recommend creating your reports and graphs separately in their own focexecs and doing an external reference in the painter.

Also hold your graphs with a 4character name in SVG format.

The most glaring reason - compound reports are for generating multiple reports as a single report - meaning that they are all in the same format. Your report opens a PDF report and creates report one in PDf format. So far, so good. Then you create report2 in HTML format. It will never get into your PDF document. And, it sends the report back to the browser - end of story. Then you close the PDF document but never run another PDF report so it has no way of returning a PDF document. Next you generate report3 in EXL2K format.

Not exactly sure from your code what it is you are trying to accomplish. Try changing all of the outputs to PDF (except holding the graphs - and I would suggest SVG format as Ginny suggests) and see what you get.

Also, if you want the output in Excel, you can use the PDF Layout Painter to do that. It will put each graph and report in its own worksheet.

I have done this in 762 and it works very well.

Hi,

This is not my code. I am just trying to follow the webfocus documentation. This code is in the documentation.
So if the code inside the documentation is wrong, what other documentation should I read.
I was trying to understand the compound reports chapter.

Regards.

Majid.

Darin is correct. You can only produce PDF output with the compound syntax, not Excel.

If you want Excel, you'll have to use the PDF Layout Painter.

Majid

you are right, as to the documentation

page 1190

quote:

Combining Report Formats and Graphs in a Compound Report
This request generates a compound report from three different report types (PDF, HTML,
and EXL2K), and embeds a graph in each report. Notice that each graph is saved as a GIF
file in the graph request; the graph is then identified, sized, and positioned within the
StyleSheet declaration (TYPE=REPORT, IMAGE=graphname...) of the report in which it is
being embedded). Variations on the SET COMPOUND= syntax (OPEN, NOBREAK, CLOSE)
combine the three reports on the same page. Key lines of code are highlighted in the following
request.

It should be possible, and also this should work in 7.1.3, but my experience is that the format in the 3 reports should be all pdf, than you can be sure it will work, and also the pageformat can IMHO not be mixed portrait and landscape or letter and A4. At least in 7.1 that caused problems too.

We successfully mix landscape and portrait, but haven't tried mixed paper sizes