Focal Point Banner
Community Center Education Summit Technical Support User Groups
Let's Get Social!

Facebook Twitter LinkedIn YouTube
Focal Point    Focal Point Forums  Hop To Forum Categories  WebFOCUS/FOCUS Forum on Focal Point     [CLOSED] Rogue Blank Line After Heading and Before Column Titles.
Go
New
Search
Notify
Tools
Reply
  
[CLOSED] Rogue Blank Line After Heading and Before Column Titles.
 Login/Join
 
Master
posted
Running this and I see NO blank line after the HEADING:
APP PREPENDPATH IBISAMP
TABLE FILE GGSALES
"Alerts as of &DATEMtrDYY"
PRINT ST
      REGION
IF RECORDLIMIT EQ 3
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET LINES 10
ON TABLE SET DROPBLNKLINE ALL
ON TABLE SET STYLE *
TYPE=REPORT,GRID=ON,FONT='Arial',SIZE=8,COLOR=RGB(50 50 50),  
$
END  


Adding a BORDER stylesheet attribute, and I see a blank line after the HEADING:
APP PREPENDPATH IBISAMP
TABLE FILE GGSALES
"Alerts as of &DATEMtrDYY"
PRINT ST
      REGION
IF RECORDLIMIT EQ 3
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET LINES 10
ON TABLE SET DROPBLNKLINE ALL
ON TABLE SET STYLE *
TYPE=REPORT,GRID=ON,FONT='Arial',SIZE=8,COLOR=RGB(50 50 50), BORDER=LIGHT, 
$
END  


I thought the DROPBLNKLINE setting would remove the blank line, even with a border style.

I am running WF 8.0.07, in IE 9.

(I saw other posts discussing this issue, but didn't seem to find a solution/conclusion.)

This message has been edited. Last edited by: <Kathryn Henning>,
 
Posts: 733 | Registered: April 23, 2003Reply With QuoteReport This Post
Expert
posted Hide Post
It's probably the one line that is not dropped!

DROPBLNKLINE - "suppresses blank lines around subtotals, subheadings, and subfootings "

Nothing about headings. Too bad.


Francis


Give me code, or give me retirement. In FOCUS since 1991

Production: WF 7.7.05M, Dev Studio, BID, MRE, WebSphere, DB2 / Test: WF 8.1.05M, App Studio, BI Portal, Report Caster, jQuery, HighCharts, Apache Tomcat, MS SQL Server
 
Posts: 10577 | Location: Toronto, Ontario, Canada | Registered: April 27, 2005Reply With QuoteReport This Post
Expert
posted Hide Post
Version 8.0.0.7 is slightly improved, though still does not work for HTML!!!

quote:

The DROPBLNKLINE parameter suppresses blank lines around subtotals, subheadings, and subfootings when formatting a report for output. In addition, certain data lines may be blank and appear as blank lines on the report output. You can eliminate these blank lines from the report output using the SET DROPBLNKLINE=ON command.

This setting does not apply to the following output formats: HOLD/PCHOLD/SAVE formats, ALPHA, INTERNAL, BINARY, COM, COMT, COMMA, TAB, TABT, FIX, DFIX, all DBMS, VSAM, LOTUS, SYLK, DIF, FOCUS, and XFOCUS.

The syntax is:
SET DROPBLNKLINE = {OFF|ON|BODY|HEADING|ALL}

where:
OFF - Inserts system-generated blank lines as well as empty data lines. OFF is the default value.
ON|BODY - Removes system-generated blank lines within the body of the report, for example, before and after subheads. In addition, certain data lines that may be blank and appear as blank lines on the report output will be removed from the output. BODY is a synonym for ON.
HEADING - Removes the blank lines between headings and titles and between the report body and the footing. Works in positioned formats (PDF, PS, DHTML, PPT) when a request has a border or backcolor StyleSheet attribute anywhere in the report.
ALL - Provides both the ON and HEADING behaviors.


Francis


Give me code, or give me retirement. In FOCUS since 1991

Production: WF 7.7.05M, Dev Studio, BID, MRE, WebSphere, DB2 / Test: WF 8.1.05M, App Studio, BI Portal, Report Caster, jQuery, HighCharts, Apache Tomcat, MS SQL Server
 
Posts: 10577 | Location: Toronto, Ontario, Canada | Registered: April 27, 2005Reply With QuoteReport This Post
Master
posted Hide Post
Thanks for your thoughts Francis.

Yep, the section of the 8.0.07 manual you site, was something I was pouring over as well.
 
Posts: 733 | Registered: April 23, 2003Reply With QuoteReport This Post
Master
posted Hide Post
I noticed that the blank line between the report heading and the column titles is assigned a class of 'x3'.

Given this, if I add a CSS 'display:none' style to 'x3', the blank line is not displayed.

In my case:
APP PREPENDPATH IBISAMP
TABLE FILE GGSALES
"Report Heading as of &DATEMtrDYY"
PRINT ST
      REGION
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE HOLD FORMAT HTML
ON TABLE SET LINES 999999
ON TABLE SET HTMLCSS ON
ON TABLE SET DROPBLNKLINE ALL
ON TABLE SET STYLE *
TYPE=REPORT,GRID=OFF,FONT='Arial',SIZE=8,COLOR=RGB(50 50 50),
BORDER=LIGHT,
$
TYPE=HEADING,
BORDER=LIGHT,BORDER-COLOR=RGB(200 200 220),BORDER-STYLE=OUTSET,
BACKCOLOR='RED',STYLE=BOLD,SIZE=10,$
$
TYPE=TITLE,SIZE=9,STYLE=-UNDERLINE+BOLD,BACKCOLOR='BLUE',COLOR='WHITE',
BORDER-STYLE=OUTSET,BORDER=LIGHT,BORDER-COLOR=RGB(255 255 255),$
$
TYPE=DATA,
BORDER-LEFT-STYLE=NONE,BORDER-LEFT=MEDIUM,BORDER-LEFT-COLOR=RGB(255 255 255),
BORDER-RIGHT-STYLE=NONE,BORDER-RIGHT=LIGHT,BORDER-RIGHT-COLOR=RGB(255 255 255),
BORDER-BOTTOM-STYLE=NONE,BORDER-BOTTOM=LIGHT,
BORDER-BOTTOM-COLOR=RGB(255 255 255),
BACKCOLOR=( 'WHITE' 'PINK' ),
$
ENDSTYLE
END
-RUN
-HTMLFORM BEGIN
<html>
<head>
<title></title>
<style>
 .x3 {
  display:none;
 }
</style>
</title>
<body>
 !IBI.FIL.HOLD;
</body>
</html>
-HTMLFORM END
-EXIT  

Does anyone know how/if I could specifically assign a class to the rogue blank line?

Without this, I wouldn't necessarily consider this a workaround, although it seems to work in my particular scenario.




Test: WebFOCUS 8.1.05M Prod: WebFOCUS 8.1.05M Server: Windows Server 2012/Tomcat Standalone Workstation: Windows 7/IE 11 Database: Oracle 12c/Netezza Output: AHTML/XLSX/HTML/PDF/JSCHART Tools: WFDS, Repository Content, BI Portal Designer, & ReportCaster
 
Posts: 733 | Registered: April 23, 2003Reply With QuoteReport This Post
Expert
posted Hide Post
OK, this is weird and I cannot explain why it works (at least now). But, remove the "GRID=OFF," from your first STYLE line and see what happens...
TYPE=REPORT,GRID=OFF,FONT='Arial',SIZE=8,COLOR=RGB(50 50 50),BORDER=LIGHT,$



In FOCUS Since 1983 ~ from PC FOCUS to WebFOCUS 8204M Gen48
 
Posts: 2713 | Location: Nashville TN Area [Test:8204Mg48/Prod:8202Mg60] | Registered: February 23, 2005Reply With QuoteReport This Post
Expert
posted Hide Post
No one can explain why GRID has this effect but many have been annoyed by it.


Francis


Give me code, or give me retirement. In FOCUS since 1991

Production: WF 7.7.05M, Dev Studio, BID, MRE, WebSphere, DB2 / Test: WF 8.1.05M, App Studio, BI Portal, Report Caster, jQuery, HighCharts, Apache Tomcat, MS SQL Server
 
Posts: 10577 | Location: Toronto, Ontario, Canada | Registered: April 27, 2005Reply With QuoteReport This Post
Expert
posted Hide Post
Yeah... Include me in that group.
 
Posts: 2713 | Location: Nashville TN Area [Test:8204Mg48/Prod:8202Mg60] | Registered: February 23, 2005Reply With QuoteReport This Post
Member
posted Hide Post
Chasing the same issue today in PCHOLD FORMAT XLSX in 8105M. I found that i had to remove all BORDER= stylesheet options to permit DROPBLNKLINE to function on HEADING lines.


WF 4.3 - 8.2
Windows\Unix
 
Posts: 3 | Location: Dallas | Registered: November 14, 2012Reply With QuoteReport This Post
Member
posted Hide Post
Hi All, as per the information available over various earlier posts for similar issue and per the IBI documentation, the DROPBLNKLINE is not applicable to EXCEL format and there seems no straight forward way to achieve the same. As soon as we apply border to the DATA/REPORT, the blank line between HEADER and TITLE appears automatically. However, I have generated a workaround that meets the requirement. I have done the PoC on only three columns and anyone can extend the same as per the real time requirement.

Guys, again this is perhaps my first reply over the WebFOCUS community so I'd be more that glad to receive your positive up-votes and feedback. These would help me keep energetic for more repliesSmiler

TABLE FILE CAR
PRINT
COMPUTE COUNTRY/A10 = 'COUNTRY';
COMPUTE CAR/A16 = 'CAR';
COMPUTE MODEL/A24 = 'MODEL';
BY HIGHEST 1 COUNTRY NOPRINT
ON TABLE HOLD AS CAR_TITLE
END
-RUN

TABLE FILE CAR
PRINT
CAR.ORIGIN.COUNTRY
CAR.COMP.CAR
CAR.CARREC.MODEL
BY COUNTRY NOPRINT
ON TABLE HOLD AS CAR_DATA
END
-RUN

TABLE FILE CAR_TITLE
PRINT
COUNTRY
CAR
MODEL
ON TABLE HOLD AS CAR_FNL
MORE
FILE CAR_DATA
END
-RUN

TABLE FILE CAR_FNL
PRINT
COUNTRY AS ''
CAR AS ''
MODEL AS ''
BY COMPUTE BLK/A1 = ''; NOPRINT
ON BLK SUBHEAD
"Markets and Discounts"
ON TABLE SET PAGE OFF
ON TABLE PCHOLD FORMAT XLSX
ON TABLE SET BYDISPLAY ON
ON TABLE SET DROPBLNKLINE HEADING
ON TABLE SET EMPTYREPORT ON
ON TABLE SET SHOWBLANKS OFF
ON TABLE SET STYLE *
TYPE=DATA,BORDER-TOP=LIGHT,BORDER-BOTTOM=LIGHT,BORDER-LEFT=LIGHT,BORDER-RIGHT=LIGHT,SIZE=10,$
TYPE=DATA, COLUMN=COUNTRY, FONT='CALIBRI',SIZE=14,COLOR='WHITE',BACKCOLOR=RGB(83 141 213),STYLE=BOLD,JUSTIFY=CENTER,WHEN=COUNTRY EQ 'COUNTRY', $
TYPE=DATA, COLUMN=CAR, FONT='CALIBRI',SIZE=14,COLOR='WHITE',BACKCOLOR=RGB(83 141 213),STYLE=BOLD,JUSTIFY=CENTER,WHEN=CAR EQ 'CAR', $
TYPE=DATA, COLUMN=MODEL, FONT='CALIBRI',SIZE=14,COLOR='WHITE',BACKCOLOR=RGB(83 141 213),STYLE=BOLD,JUSTIFY=CENTER,WHEN=MODEL EQ 'MODEL', $
TYPE=SUBHEAD, FONT='CAMBRIA',SIZE=16,COLOR=RGB(31 73 125),STYLE=BOLD, JUSTIFY=CENTER,$
ENDSTYLE
END


WebFOCUS 8
Windows, All Outputs
 
Posts: 6 | Registered: January 08, 2018Reply With QuoteReport This Post
  Powered by Social Strata  
 

Focal Point    Focal Point Forums  Hop To Forum Categories  WebFOCUS/FOCUS Forum on Focal Point     [CLOSED] Rogue Blank Line After Heading and Before Column Titles.

Copyright © 1996-2018 Information Builders, leaders in enterprise business intelligence.