Focal Point Banner
Community Center Education Summit Technical Support User Groups
Let's Get Social!

Facebook Twitter LinkedIn YouTube
Focal Point    Focal Point Forums  Hop To Forum Categories  WebFOCUS/FOCUS Forum on Focal Point     [SOLVED] insert a 5 blank lines in tablear report not in the subfooter
Go
New
Search
Notify
Tools
Reply
  
[SOLVED] insert a 5 blank lines in tablear report not in the subfooter
 Login/Join
 
Gold member
posted
HI

i have scenarios Like ,i have 10 records to display and insert a blank 5lines ,but not in sub footer part Plz give example

Thank you

This message has been edited. Last edited by: Developer,


WebFOCUS 8202
 
Posts: 57 | Location: India | Registered: March 24, 2014Reply With QuoteReport This Post
Guru
posted Hide Post
Explain better what do you need.


WebFOCUS 8.1.05 / APP Studio
 
Posts: 272 | Location: Brazil | Registered: October 31, 2006Reply With QuoteReport This Post
Master
posted Hide Post
Do you mean 15 records, 10 with data and 5 with no data?

I don't know how to do that with a normal report. It could be done with jQuery, but dealing with a themed/styled report would be much more difficult than this simple example:

TABLE FILE ibisamp/car
PRINT CAR.ORIGIN.COUNTRY
CAR.COMP.CAR
CAR.CARREC.MODEL
WHERE CAR.ORIGIN.COUNTRY IN ('ENGLAND', 'ITALY', 'JAPAN');
ON TABLE HOLD AS CAR_FILE FORMAT HTML
ON TABLE NOTOTAL
ON TABLE SET CACHELINES 100
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE SET SQUEEZE ON
ON TABLE SET HTMLCSS ON
ON TABLE SET HTMLENCODE ON
ON TABLE SET EMPTYREPORT ON
ON TABLE SET GRWIDTH 1
END
-RUN

-HTMLFORM BEGIN
!IBI.FIL.CAR_FILE;
<script type="text/javascript" src="/ibi_html/javaassist/jquery/jquery_min.js"></script>
<script>
$(document).ready(function() {
	for (var i = 0; i < 5; i++) {
		$("tbody:first").append("<tr><td>&|nbsp;</td><td></td><td></td></tr>");
	}
});
</script>
-HTMLFORM END


App Studio
WebFOCUS 8.1.05M
Windows, All Outputs
 
Posts: 594 | Location: Michigan | Registered: September 04, 2015Reply With QuoteReport This Post
Virtuoso
posted Hide Post
May not be elegant, but it does the trick

DEFINE FILE CAR
SEATS /I3 = 0;
ROWID /I3 = ROWID + 100;
END
TABLE FILE CAR
PRINT SEATS
BY ROWID
BY TOTAL COMPUTE MODEL /A24 = '';
BY COUNTRY NOPRINT
WHERE READLIMIT   EQ 5;
WHERE RECORDLIMIT EQ 5;
ON TABLE HOLD AS BLANKFIL FORMAT FOCUS
END
-RUN

DEFINE FILE CAR
ROWID  /I3 = ROWID + 1;
END
TABLE FILE CAR
PRINT COMPUTE SEATX /A3 = IF ROWID GE 100 THEN '' ELSE FPRINT(SEATS, 'I3', 'A3'); AS 'SEATS'
BY ROWID NOPRINT
BY MODEL
ON TABLE SET STYLE *
TYPE=DATA,
     COLUMN=SEATX,
     JUSTIFY=RIGHT,
$
ENDSTYLE
MORE
FILE BLANKFIL
END
-RUN


WF versions : Prod 8.2.0.1M gen 240, Dev 8.2.04 gen 48, OS : Windows, DB : MSSQL, Outputs : HTML, Excel, PDF
In Focus since 2007
 
Posts: 2191 | Location: Montreal Area, Qc, CA | Registered: September 25, 2013Reply With QuoteReport This Post
Master
posted Hide Post
quote:
Originally posted by MartinY:
May not be elegant, but it does the trick

Yes it does. I like it!


App Studio
WebFOCUS 8.1.05M
Windows, All Outputs
 
Posts: 594 | Location: Michigan | Registered: September 04, 2015Reply With QuoteReport This Post
Gold member
posted Hide Post
Thank you its working fine
quote:
Originally posted by MartinY:
May not be elegant, but it does the trick

DEFINE FILE CAR
SEATS /I3 = 0;
ROWID /I3 = ROWID + 100;
END
TABLE FILE CAR
PRINT SEATS
BY ROWID
BY TOTAL COMPUTE MODEL /A24 = '';
BY COUNTRY NOPRINT
WHERE READLIMIT   EQ 5;
WHERE RECORDLIMIT EQ 5;
ON TABLE HOLD AS BLANKFIL FORMAT FOCUS
END
-RUN

DEFINE FILE CAR
ROWID  /I3 = ROWID + 1;
END
TABLE FILE CAR
PRINT COMPUTE SEATX /A3 = IF ROWID GE 100 THEN '' ELSE FPRINT(SEATS, 'I3', 'A3'); AS 'SEATS'
BY ROWID NOPRINT
BY MODEL
ON TABLE SET STYLE *
TYPE=DATA,
     COLUMN=SEATX,
     JUSTIFY=RIGHT,
$
ENDSTYLE
MORE
FILE BLANKFIL
END
-RUN


WebFOCUS 8202
 
Posts: 57 | Location: India | Registered: March 24, 2014Reply With QuoteReport This Post
Virtuoso
posted Hide Post
My pleasure to help.

Edit your first post, then in the subject add [SOLVED] at the beginning


WF versions : Prod 8.2.0.1M gen 240, Dev 8.2.04 gen 48, OS : Windows, DB : MSSQL, Outputs : HTML, Excel, PDF
In Focus since 2007
 
Posts: 2191 | Location: Montreal Area, Qc, CA | Registered: September 25, 2013Reply With QuoteReport This Post
  Powered by Social Strata  
 

Focal Point    Focal Point Forums  Hop To Forum Categories  WebFOCUS/FOCUS Forum on Focal Point     [SOLVED] insert a 5 blank lines in tablear report not in the subfooter

Copyright © 1996-2018 Information Builders, leaders in enterprise business intelligence.