Focal Point Banner
Community Center Education Summit Technical Support User Groups
Let's Get Social!

Facebook Twitter LinkedIn YouTube
Focal Point    Focal Point Forums  Hop To Forum Categories  WebFOCUS/FOCUS Forum on Focal Point     [SOLVED] Blank Line after Header in Excel
Go
New
Search
Notify
Tools
Reply
  
[SOLVED] Blank Line after Header in Excel
 Login/Join
 
Member
posted
Hi,

A blank is displaying between Header and Data fields in the Excel format.

In PDF by using Dropblinkline, the empty line issue is solved, but in excel its not working.

ON TABLE SET DROPBLNKLINE HEADING

Is there any approach/command to remove the blank line after header in the Excel(XLSX) format along with using border lines.

This message has been edited. Last edited by: FP Mod Chuck,


WebFOCUS 8

Windows, All Outputs
 
Posts: 7 | Registered: March 23, 2018Reply With QuoteReport This Post
Virtuoso
posted Hide Post
DROPBLNKLINE doesn't apply to Excel. Could you share an example of your code? I just tested the following and I don't see a blank line after the column titles. Do you have an ACROSS?

  
TABLE FILE CAR
SUM CAR.BODY.DEALER_COST
CAR.BODY.RETAIL_COST
BY CAR.ORIGIN.COUNTRY
BY CAR.COMP.CAR
ON TABLE PCHOLD FORMAT XLSX
END


WebFOCUS 8203, Unix, Windows
 
Posts: 1332 | Location: New York City | Registered: December 30, 2015Reply With QuoteReport This Post
Expert
posted Hide Post
quote:
DROPBLNKLINE doesn't apply to Excel

... And what release of '8' you're using.
 
Posts: 2709 | Location: Nashville TN Area [Test:8204Mg48/Prod:8202Mg60] | Registered: February 23, 2005Reply With QuoteReport This Post
Member
posted Hide Post
Hi Babak/Doug

Blank line is appearing between Header and Column names. Need border for data fields and while removing the borders the blank line is removed ,but borders are also to be present without the blank line. Below is the example.

TABLE FILE CAR
PRINT
CAR.ORIGIN.COUNTRY
CAR.COMP.CAR
CAR.CARREC.MODEL
CAR.BODY.BODYTYPE
CAR.BODY.SEATS
CAR.BODY.DEALER_COST
CAR.BODY.RETAIL_COST
CAR.BODY.SALES
HEADING
"Markets and Discounts"
ON TABLE SET PAGE OFF
ON TABLE PCHOLD FORMAT XLSX
ON TABLE SET BYDISPLAY ON
ON TABLE SET DROPBLNKLINE HEADING
ON TABLE SET EMPTYREPORT ON
ON TABLE SET SHOWBLANKS OFF
ON TABLE SET STYLE *
$
TYPE=HEADING,HEADALIGN=BODY,FONT='CAMBRIA',SIZE=16,COLOR=RGB(31 73 125),STYLE=BOLD, JUSTIFY=CENTER,$
TYPE=TITLE,FONT='CALIBRI',SIZE=11,COLOR='WHITE',BACKCOLOR=RGB(83 141 213),STYLE=BOLD,JUSTIFY=CENTER,$
TYPE=DATA,BORDER-TOP=LIGHT,BORDER-BOTTOM=LIGHT,BORDER-LEFT=LIGHT,BORDER-RIGHT=LIGHT,$
END

Using Webfocus 8105 version.

Thanks,
Vijay


WebFOCUS 8

Windows, All Outputs
 
Posts: 7 | Registered: March 23, 2018Reply With QuoteReport This Post
Member
posted Hide Post
Hi All, as per the information available over various earlier posts for similar issue and per the IBI documentation, the DROPBLNKLINE is not applicable to EXCEL format and there seems no straight forward way to achieve the same. As soon as we apply border to the DATA/REPORT, the blank line between HEADER and TITLE appears automatically. However, I have generated a workaround that meets the requirement. I have done the PoC on only three columns and anyone can extend the same as per the real time requirement.

Guys, again this is perhaps my first reply over the WebFOCUS community so I'd be more that glad to receive your positive up-votes and feedback.

 TABLE FILE CAR
PRINT
COMPUTE COUNTRY/A10 = 'COUNTRY';
COMPUTE CAR/A16		= 'CAR';
COMPUTE MODEL/A24	= 'MODEL';
BY HIGHEST 1 COUNTRY NOPRINT
ON TABLE HOLD AS CAR_TITLE
END
-RUN

TABLE FILE CAR
PRINT
CAR.ORIGIN.COUNTRY 	
CAR.COMP.CAR        
CAR.CARREC.MODEL 
BY COUNTRY NOPRINT
ON TABLE HOLD AS CAR_DATA
END
-RUN

TABLE FILE CAR_TITLE
PRINT 
COUNTRY 
CAR 
MODEL
ON TABLE HOLD AS CAR_FNL
MORE 
FILE CAR_DATA
END
-RUN

TABLE FILE CAR_FNL
PRINT 
COUNTRY AS '' 
CAR AS '' 
MODEL AS ''
BY COMPUTE BLK/A1 = ''; NOPRINT
ON BLK SUBHEAD
"Markets and Discounts"
ON TABLE SET PAGE OFF
ON TABLE PCHOLD FORMAT XLSX
ON TABLE SET BYDISPLAY ON
ON TABLE SET DROPBLNKLINE HEADING
ON TABLE SET EMPTYREPORT ON
ON TABLE SET SHOWBLANKS OFF
ON TABLE SET STYLE *
TYPE=DATA,BORDER-TOP=LIGHT,BORDER-BOTTOM=LIGHT,BORDER-LEFT=LIGHT,BORDER-RIGHT=LIGHT,SIZE=10,$
TYPE=DATA, COLUMN=COUNTRY, FONT='CALIBRI',SIZE=14,COLOR='WHITE',BACKCOLOR=RGB(83 141 213),STYLE=BOLD,JUSTIFY=CENTER,WHEN=COUNTRY EQ 'COUNTRY', $
TYPE=DATA, COLUMN=CAR, FONT='CALIBRI',SIZE=14,COLOR='WHITE',BACKCOLOR=RGB(83 141 213),STYLE=BOLD,JUSTIFY=CENTER,WHEN=CAR EQ 'CAR', $
TYPE=DATA, COLUMN=MODEL, FONT='CALIBRI',SIZE=14,COLOR='WHITE',BACKCOLOR=RGB(83 141 213),STYLE=BOLD,JUSTIFY=CENTER,WHEN=MODEL EQ 'MODEL', $
TYPE=SUBHEAD, FONT='CAMBRIA',SIZE=16,COLOR=RGB(31 73 125),STYLE=BOLD, JUSTIFY=CENTER,$
ENDSTYLE
END


 


WebFOCUS 8
Windows, All Outputs
 
Posts: 6 | Registered: January 08, 2018Reply With QuoteReport This Post
Virtuoso
posted Hide Post
Aj_BI

Welcome to the Focal Point forum. It is a very upbeat helpful forum and we look forward to your participation.


Thank you for using Focal Point!

Chuck Wolff - Focal Point Moderator
WebFOCUS 7x and 8x, Windows, Linux All output Formats
 
Posts: 1206 | Location: Customer Support | Registered: April 12, 2005Reply With QuoteReport This Post
Member
posted Hide Post
HI Aj_BI,

Thanks for the response. It worked for the issue. Thanks for your support.


WebFOCUS 8

Windows, All Outputs
 
Posts: 7 | Registered: March 23, 2018Reply With QuoteReport This Post
  Powered by Social Strata  
 

Focal Point    Focal Point Forums  Hop To Forum Categories  WebFOCUS/FOCUS Forum on Focal Point     [SOLVED] Blank Line after Header in Excel

Copyright © 1996-2018 Information Builders, leaders in enterprise business intelligence.