If I have a 31 digit field that would have values with 0's and 1s ( Ex: 011100101110101 ). I want to count the 1s in the number field.?

Is it possible.?

This message has been edited. Last edited by: Kerry,

Here's an example of how to count a character in a string.

1) Determine the length of the string
2) Convert the 1's to blanks
3) Strip the blanks out of the string
4) Determine the length of the string without the blanks
5) Determine the number of blanks in the string by subtracting the length of the string without the blanks from the length of the string

DEFINE FILE CAR
NUMSTRING/A15 =
IF COUNTRY EQ 'ENGLAND' THEN '011100101110101' ELSE
IF COUNTRY EQ 'FRANCE'  THEN '110100111111000' ELSE
IF COUNTRY EQ 'JAPAN'   THEN '011001100010001' ELSE
IF COUNTRY EQ 'ITALY'   THEN '101010101010010' ELSE
                             '010101101010001';

INSTRLEN/D4 = ARGLEN(15, NUMSTRING, 'D4');
OUTSTR1/A15 = CTRAN(15, NUMSTRING, BYTVAL('1','I3'), BYTVAL(' ','I3'), OUTSTR1);
OUTSTR2/A15 = STRIP(15, OUTSTR1, ' ', OUTSTR2);
OUTSTRLEN/D4 = ARGLEN(15, OUTSTR2, 'D4');
NBR_ONES/D4 = INSTRLEN - OUTSTRLEN;
END

TABLE FILE CAR
PRINT
NUMSTRING
-*INSTRLEN
-*OUTSTR1
-*OUTSTR2
-*OUTSTRLEN
NBR_ONES
END

[SOLVED] Count blanks in a string

create a master that describes this string

the occurs=variable will give the answer

FILENAME=FP, SUFFIX=FIX
SEGNAME=ROOT, OCCURS=VARIABLE
FIELD=CODE,,A1,,$

now you have a database with 31 records either 0 or 1

this can be done with any string
"hello world here I am"
tells you it has 3 times 'e' and 'l' and so on....

I tend to use STRREP more:

ONES/I2 = ARGLEN(31,STRREP(31,BINARY,1,'0',0,'X',31,'A31'),'I2');
ZEROS/I2 = ARGLEN(31,STRREP(31,BINARY,1,'1',0,'X',31,'A31'),'I2');

all methods above are good. my preference is Frank's. But just to throw another flavor at ya..(Yes -repeat here would be better, but I elongated to hsow you logic behind it.)
-REPEAT (looping).
-* INITIALIZE SOME DUMMY VALUE..
-SET &CHK1 =4;
-SET &CHK2 =5;
-SET &CHK3 =6;
-SET &CHK4 =7;
-SET &CHK5 =8;
-* INITIALIZE A HOLDING BUCKET FOR THE VALUE...
-SET &KNTR = 0 ;
-RUN
DEFINE FILE CAR
TST/A31
WITH COUNTRY='1010101010101010101010101010101';
END
TABLE FILE CAR PRINT TST WHERE RECORDLIMIT EQ 1
ON TABLE SAVE AS MYDUMMY
END
-RUN
-READ MYDUMMY NOCLOSE &CHK1 &CHK2 &CHK3 &CHK4 &CHK5 (....to 31)
-SET &KNTR = &KNTR + &CHK1 + &CHK2 + &CHK3 +&CHK4 + &CHK5; (all the way to 31)..
-TYPE &KNTR ;
-READ MYDUMMY NOCLOSE
-EXIT

hope it helps...
Ira

Alan B, I don't see how the combination of ARGLEN and STRREP works to determine the count of a particular character in a string.

This doesn't work:

TABLE FILE CAR
PRINT
MODEL
-*STRREP (inlength, instring, searchlength, searchstring, replength, repstring, outlength, outstring)
COMPUTE ONES/I2 = ARGLEN(24,STRREP(24,MODEL,1,'0',0,'X',24,'A24'),'I2');
COMPUTE ZEROS/I2 = ARGLEN(24,STRREP(24,MODEL,1,'1',0,'X',24,'A24'),'I2');
END

Francis

quote:

If I have a 31 digit field that would have values with 0's and 1s ( Ex: 011100101110101 ). I want to count the 1s in the number field.?

I did not say it worked on model, or anything else other than a field with 1s' and 0s',i.e. a binary type field, which is what was asked for.

However if you use:

TABLE FILE CAR
PRINT
MODEL
-*STRREP (inlength, instring, searchlength, searchstring, replength, repstring, outlength, outstring)
COMPUTE ONES/I2 = ARGLEN(24,STRREP(24,MODEL,1,'1',0,'X',24,'A24'),'I2');
COMPUTE ZEROS/I2 = ARGLEN(24,STRREP(24,MODEL,1,'0',0,'X',24,'A24'),'I2');
COMPUTE TOTAL/I2 = ARGLEN(24,MODEL,'I2');
COMPUTE ACTUAL_ONES/I2 = TOTAL - ONES;
COMPUTE ACTUAL_ZEROS/I2 = TOTAL - ZEROS;
END

It works.

This message has been edited. Last edited by: Alan B,

quote:

Originally posted by Francis Mariani:
This doesn't work:

But this does: Squeeze out the blanks, then squeeze out the 0's, and compare the lengths:

DEFINE FILE CAR
WARR0/A25=SUBSTR(40,WARRANTY,1,25,25,'A25');
WARR1/A25=STRREP(25,WARR0,1,' ',0,' ',25,'A25');
WARR2/A25=STRREP(25,WARR1,1,'0',0,' ',25,'A25');
LEN0/I2 = ARGLEN(25,WARR0,'I2');
LEN1/I2 = ARGLEN(25,WARR1,'I2');
LEN2/I2 = ARGLEN(25,WARR2,'I2');
ZEROS/I2=LEN1-LEN2;
END

TABLE FILE CAR
PRINT WARR0 WARR1 WARR2 LEN0 LEN1 LEN2 ZEROS
BY CAR 
IF WARRANTY NE ' '
ON TABLE PCHOLD FORMAT WP
END

  PAGE     1
  
  
  CAR               WARR0                      WARR1                      WARR2                      LEN0  LEN1  LEN2  ZEROS      
  ---               -----                      -----                      -----                      ----  ----  ----  -----      
  AUDI              12 MONTHS OR 20000 MILES   12MONTHSOR20000MILES       12MONTHSOR2MILES             24    20    16      4
  DATSUN            12 MONTHS OR 12000 MILES   12MONTHSOR12000MILES       12MONTHSOR12MILES            24    20    17      3
  JAGUAR            12 MONTHS OR 12000 MILES   12MONTHSOR12000MILES       12MONTHSOR12MILES            24    20    17      3
  JENSEN            12000 MILES OR 12 MONTHS   12000MILESOR12MONTHS       12MILESOR12MONTHS            24    20    17      3
  MASERATI          6 MONTHS OR 6000 MILES     6MONTHSOR6000MILES         6MONTHSOR6MILES              22    18    15      3
  PEUGEOT           12 MONTHS ON 12000 MILES   12MONTHSON12000MILES       12MONTHSON12MILES            24    20    17      3
  TOYOTA            12 MONTHS OR 12500 MILES   12MONTHSOR12500MILES       12MONTHSOR125MILES           24    20    18      2
  TRIUMPH           12 MONTHS OR 12000 MILES   12MONTHSOR12000MILES       12MONTHSOR12MILES            24    20    17      3

Thanks Alan - I get it.

Thanks for all the answers. I just need to count 0's and 1's so Alans answer works best for me.