I have a variable in dialog manager that contains date in the format of 'yyyy/mm/dd'. How can I convert it to a date value so that I can apply the DATEADD function to it? I have searched in the forum but I have only found examples that work when the date value is coming from TABLE FILE. I have not been able to find examples that work in dialog manager.

This message has been edited. Last edited by: JC Zhu,

It depends as to what you are trying to use DATEADD for. If you need to use Weekdays or Business days, then DATEADD is good:

-SET &INPUTDATE = '2013/05/03';
-SET &NEWDATE =  HCNVRT(HDTTM(DATEADD(HDATE(HINPUT(8,EDIT(&INPUTDATE,'9999$99$99'),8,'HYYMDS'),'YYMD'),'WD',5),8,'HYYMDS'), '(HYYMD)', 10, 'A10');
-*                                                                                                     ------
-TYPE &NEWDATE

WD - Weekday, 5 for increment by 5. BD for business days using SET BUSDAYS.

If you want to use just days, months or years, HADD will work:

-SET &NEWDATE =  HCNVRT(HADD(HINPUT(8,EDIT(&INPUTDATE,'9999$99$99'),8,'HYYMDS'),'dd',5,8,'HYYMDS'),'(HYYMD)',10,'A10');
-*                                                                              ------
-TYPE &NEWDATE

dd - days, 5 for increment by 5. Check documentation for other options.

If you're just trying to add or subtract days from the initial date value, you can also strip out the slashes with EDIT and use the legacy function AYMD. With AYMD, conversion to a SmartDate value is not necessary.

What if the variable has a single digit month or day? For example, 2013/5/2. How can that be handled?

It's more difficult! Referring to previous post, the code becomes:

-SET &INPUTDATE = '2013/5/1';
-SET &YEAR = GETTOK(&INPUTDATE,&INPUTDATE.LENGTH,1,'/',4,'A4');
-SET &MONTH = GETTOK(&INPUTDATE,&INPUTDATE.LENGTH,2,'/',2,'A2');
-SET &DATE = GETTOK(&INPUTDATE,&INPUTDATE.LENGTH,3,'/',2,'A2');
-SET &NEWDATE =  HCNVRT(HDTTM(DATEADD(HDATE(HSETPT(HSETPT(HSETPT(HGETC(8,'HYYMDS'),'year',&YEAR,4,'HYYMDS'),'month',&MONTH,2,'HYYMDS'),'dd',&DATE,2,'HYYMDS'),'YYMD'),'WD',2),8,'HYYMDS'),'(HYYMD)',10,'A10');
-*                                                                                                                                                                    ------
-TYPE &NEWDATE

or

-SET &INPUTDATE = '2013/5/1';
-SET &YEAR = GETTOK(&INPUTDATE,&INPUTDATE.LENGTH,1,'/',4,'A4');
-SET &MONTH = GETTOK(&INPUTDATE,&INPUTDATE.LENGTH,2,'/',2,'A2');
-SET &DATE = GETTOK(&INPUTDATE,&INPUTDATE.LENGTH,3,'/',2,'A2');
-SET &NEWDATE =  HCNVRT(HADD(HSETPT(HSETPT(HSETPT(HGETC(8,'HYYMDS'),'year',&YEAR,4,'HYYMDS'),'month',&MONTH,2,'HYYMDS'),'dd',&DATE,2,'HYYMDS'),'dd',4,8,'HYYMDS'),'(HYYMD)',10,'A10');
-*                                                                                                                                              ------
-TYPE &NEWDATE

It is important to note that Dialogue Manager interprets dates as alphanumeric or numeric, and the date functions such as DATEADD requires a standard date stored as an offset from the base date.
What this means is you have to convert the date string to a date offset using the function DATECVT.
Here is a sample:

  
-* Initial Date string
-SET &MYDATE = '2012/01/01';

-*Removing the '/' from the date
-SET &MYDATE = EDIT(&MYDATE, '9999$99$99');

-*Converting the date to an offset
-SET &MYDATE_OFFSET = DATECVT(&MYDATE, 'I8YYMD', 'YYMD');

-* Now you can use the &MYDATE_OFFSET with most of the date manipulation functions, such as DATEADD and DATEMOV

Thanks for the answers. I have just found that I can more easily achieved that with passing the variable to the DATEADD function directly without any conversion. I tried this initially but it didn't work. I got this to work by adding single quotes around the variable name when passing the value to the DATEADD function. With the single quotes, DATEADD seems to be able to automatically interpret it as a date.


-SET &INPUTDATE = '2013/5/2';
-SET &NEWDATE = HCNVRT(HDTTM(DATEADD('&INPUTDATE', 'D', -1),8,'HYYMDS'),'(HYYMD)',10,'A10');
-TYPE &NEWDATE

quote:

With the single quotes, DATEADD seems to be able to automatically interpret it as a date.

Not in my experience it won't, nor according to the documentation.