I'm having a problem with a report where several items are grouped in categories, with the headings for those categories drilling down to a next report. I'm not getting the correct values in my drilldown links though; instead of the minimum and maximum values of the entire column, I only get those of the first row per column.

My report is similar to this:

DEFINE FILE CAR
	GROUP/A15 = IF SEATS LT 2 THEN '0 - 2'
				ELSE IF SEATS FROM 2 TO 3 THEN '2 - 4'
				ELSE IF SEATS FROM 4 TO 5 THEN '4 - 6'
				ELSE '6+';
	RANK/I2	= IF COUNTRY EQ 'JAPAN' OR 'FRANCE' THEN 1 ELSE 2;
END
TABLE FILE CAR
SUM
	MIN.SEATS
	MAX.SEATS
ACROSS GROUP
BY RANK NOPRINT
BY COUNTRY
ON TABLE SET STYLE *
TYPE=ACROSSVALUE, FOCEXEC=X(MINSEATS=N3 MAXSEATS=N4),$
END

If you'd use "View source" in the resulting HTML page and look at the link for the second across value, you will see that it has &MINSEATS=5&MAXSEATS=5.
I really need that to be the minimum and maximum values in the column, instead of those of just the first row. In the above case: &MINSEATS=4&MAXSEATS=5.

Is there a way to get those in the across-link?

I get the impression this should be trivial, but I don't see how to do it.

This message has been edited. Last edited by: Kerry,

Here's some code that partially works, perhaps it will give you ideas... The Min/Max for the second group works, but the first group is 0/0 perhaps due to the RANK causing missing values...

SET ASNAMES=ON
SET HOLDFORMAT=ALPHA
SET HOLDLIST=PRINTONLY

DEFINE FILE CAR
GROUP/A15 =
IF SEATS LT 2 THEN '0 - 2' ELSE
IF SEATS FROM 2 TO 3 THEN '2 - 4' ELSE
IF SEATS FROM 4 TO 5 THEN '4 - 6' ELSE
'6+';
RANK/I2 = IF COUNTRY EQ 'JAPAN' OR 'FRANCE' THEN 1 ELSE 2;
END

TABLE FILE CAR
SUM
MIN.SEATS AS MINSEATS
MAX.SEATS AS MAXSEATS
BY GROUP

PRINT
SEATS
BY GROUP
BY RANK
BY COUNTRY

ON TABLE HOLD AS H001
END
-RUN

?FF H001

TABLE FILE H001
SUM
MINSEATS NOPRINT
MAXSEATS NOPRINT

MIN.SEATS
MAX.SEATS

ACROSS GROUP
BY RANK NOPRINT
BY COUNTRY

ON TABLE SET STYLE *
TYPE=ACROSSVALUE, FOCEXEC=X(MINSEATS=MINSEATS MAXSEATS=MAXSEATS),$
END

How about reverting to our godd friend McGuyver?

  
-* File wep02.fex
JOIN BLANK WITH SEATS IN CAR TO BLANK IN FSEQ AS M_
DEFINE FILE CAR
    BLANK/A1 WITH SEATS = ' ';
	GROUP/A15 = IF SEATS LT 2 THEN '0 - 2'
				ELSE IF SEATS FROM 2 TO 3 THEN '2 - 4'
				ELSE IF SEATS FROM 4 TO 5 THEN '4 - 6'
				ELSE '6+';
	RANK/I2	= IF COUNTER EQ 1 THEN 0 ELSE IF COUNTRY EQ 'JAPAN' OR 'FRANCE' THEN 1 ELSE 2;
    XCOUNTRY/A10=IF COUNTER EQ 1 THEN 'TOTAL' ELSE COUNTRY;
END
TABLE FILE CAR
WHERE COUNTER LE 2;
SUM
	MIN.SEATS
	MAX.SEATS
ACROSS GROUP
BY RANK NOPRINT
BY XCOUNTRY
ON TABLE SET STYLE *
TYPE=ACROSSVALUE, FOCEXEC=DUMMY(MINSEATS=N3 MAXSEATS=N4),$
END