Is there a way to control the Excel worksheet name (outputting to EXCEL, EXL97, EXL2K, EXL2K PIVOT, etc.)?

My users would like to have something besides "Sheet1" at the bottom of the worksheet. It's not a huge deal, but a few of them have asked about it, so I figure it's worth looking into.

Thanks,
Michael

This is a new feature in WebFOCUS 5.2.

Now, we can customize the worksheets tab names using the new TITLETEXT attribute in the report styleSheet.

See 5.2 EXL2K Enhancements Doc.

Example:

TABLE FILE CAR
SUM
SALES
BY COUNTRY
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET STYLE *
TYPE=REPORT, TITLETEXT="Sales Report", $
END
-RUN

Regards,
Mikel

Thanks a bunch!

It turns out you don't need the quotes... AND you can use amper variables! Also, Excel seems to have a limit of 31 characters for a worksheet name.

Thanks again,
Michael

Does anyone know if there is a way to have a compound report with multiple sheets in Excel? I like the naming ability for each sheet but it doesn't seem to work with multiple reports, do I have to use a different COMPOUND declaration?

Thanks!

Here's how I do it.

-*******************************************************************************
-* TITLE : FOCEXEC (DRILLTHR)
-* SYSTEM : HEALTH
-* AUTHOR : GLENDA STURM
-* DATE WRITTEN : 5/17/2006
-* DESCRIPTION : COBC Rolling Year Views
-* INPUT FILES : COBCCNTS
-* OUTPUT FILES : EXCEL Spreadsheet
-*******************************************************************************
-* --------- PURPOSE ---------
-* This report will create an EXCEL document with several different worksheets.
-*******************************************************************************
-* --------- CHANGE LOG ---------
-*******************************************************************************
-* Processor 1
-*******************************************************************************
FILEDEF COBCCNTS DISK /edadata/pda/cobccnts.dat
-*********BY SUMMARY
DEFINE FILE COBCCNTS
INTERMEDIARY/A120 = COBCID||' - '||INTERMED;
CNTS/I9 = EDIT(QTY);
WEEKS/I8 = IF &YYMD GE 20070102
THEN 52
ELSE DATEDIF('20060102', DATEMOV('&YYMD', 'BOW'), 'WD')/5;
END
TABLE FILE COBCCNTS
HEADING
"COBC DETAIL"
" "
PRINT
*
CNTS
BY COMPANY
BY INTERMEDIARY
ON TABLE SET STYLE *
TYPE=REPORT, TITLETEXT='COBC DETAIL', $
TYPE=HEADING, SIZE=18, $
ENDSTYLE
ON TABLE PCHOLD FORMAT EXL2K OPEN
END
TABLE FILE COBCCNTS
HEADING
"COBC BY INTERMEDIARY ACROSS WEEK"
" "
SUM
CNTS
ACROSS WEEKOF
BY COMPANY
BY INTERMEDIARY
WHERE COMPANY EQ 'ANTEX-A'
ON INTERMEDIARY ROW-TOTAL AS 'TOTAL'
ON TABLE SET BYDISPLAY ON
ON TABLE SET STYLE *
TYPE=REPORT, TITLETEXT='ANTEX-A BY INTERMEDIARY', $
TYPE=HEADING, SIZE=18, $
ENDSTYLE
ON TABLE PCHOLD FORMAT EXL2K
END
TABLE FILE COBCCNTS
HEADING
"COBC BY INTERMEDIARY ACROSS WEEK"
" "
SUM
CNTS
ACROSS WEEKOF
BY COMPANY
BY INTERMEDIARY
WHERE COMPANY EQ 'ANTEX-B'
ON INTERMEDIARY ROW-TOTAL AS 'TOTAL'
ON TABLE SET BYDISPLAY ON
ON TABLE SET STYLE *
TYPE=REPORT, TITLETEXT='ANTEX-B BY INTERMEDIARY', $
TYPE=HEADING, SIZE=18, $
ENDSTYLE
ON TABLE PCHOLD FORMAT EXL2K
END
TABLE FILE COBCCNTS
HEADING
"COBC BY INTERMEDIARY ACROSS WEEK"
" "
SUM
CNTS
ACROSS WEEKOF
BY COMPANY
BY INTERMEDIARY
WHERE COMPANY EQ 'SLAICO-A'
ON INTERMEDIARY ROW-TOTAL AS 'TOTAL'
ON TABLE SET BYDISPLAY ON
ON TABLE SET STYLE *
TYPE=REPORT, TITLETEXT='SLAICO-A BY INTERMEDIARY', $
TYPE=HEADING, SIZE=18, $
ENDSTYLE
ON TABLE PCHOLD FORMAT EXL2K
END
TABLE FILE COBCCNTS
HEADING
"COBC BY INTERMEDIARY ACROSS WEEK"
" "
SUM
CNTS
ACROSS WEEKOF
BY COMPANY
BY INTERMEDIARY
WHERE COMPANY EQ 'SLAICO-B'
ON INTERMEDIARY ROW-TOTAL AS 'TOTAL'
ON TABLE SET BYDISPLAY ON
ON TABLE SET STYLE *
TYPE=REPORT, TITLETEXT='SLAICO-B BY INTERMEDIARY', $
TYPE=HEADING, SIZE=18, $
ENDSTYLE
ON TABLE PCHOLD FORMAT EXL2K
END
TABLE FILE COBCCNTS
HEADING
"COBC BY WEEK ACROSS COBCID"
" "
SUM
CNTS
ACROSS COBCID
BY COMPANY
BY DAY
BY WEEKOF
WHERE COMPANY EQ 'ANTEX-A'
ON DAY ROW-TOTAL AS 'TOTAL'
ON TABLE SET BYDISPLAY ON
ON TABLE SET STYLE *
TYPE=REPORT, TITLETEXT='ANTEX-A BY DAY', $
TYPE=HEADING, SIZE=18, $
ENDSTYLE
ON TABLE PCHOLD FORMAT EXL2K
END
TABLE FILE COBCCNTS
HEADING
"COBC BY WEEK ACROSS COBCID"
" "
SUM
CNTS
ACROSS COBCID
BY COMPANY
BY DAY
BY WEEKOF
WHERE COMPANY EQ 'ANTEX-B'
ON DAY ROW-TOTAL AS 'TOTAL'
ON TABLE SET BYDISPLAY ON
ON TABLE SET STYLE *
TYPE=REPORT, TITLETEXT='ANTEX-B BY DAY', $
TYPE=HEADING, SIZE=18, $
ENDSTYLE
ON TABLE PCHOLD FORMAT EXL2K
END
TABLE FILE COBCCNTS
HEADING
"COBC BY WEEK ACROSS COBCID"
" "
SUM
CNTS
ACROSS COBCID
BY COMPANY
BY DAY
BY WEEKOF
WHERE COMPANY EQ 'SLAICO-A'
ON DAY ROW-TOTAL AS 'TOTAL'
ON TABLE SET BYDISPLAY ON
ON TABLE SET STYLE *
TYPE=REPORT, TITLETEXT='SLAICO-A BY DAY', $
TYPE=HEADING, SIZE=18, $
ENDSTYLE
ON TABLE PCHOLD FORMAT EXL2K
END
TABLE FILE COBCCNTS
HEADING
"COBC BY WEEK ACROSS COBCID"
" "
SUM
CNTS
ACROSS COBCID
BY COMPANY
BY DAY
BY WEEKOF
WHERE COMPANY EQ 'SLAICO-B'
ON DAY ROW-TOTAL AS 'TOTAL'
ON TABLE SET BYDISPLAY ON
ON TABLE SET STYLE *
TYPE=REPORT, TITLETEXT='SLAICO-B BY DAY', $
TYPE=HEADING, SIZE=18, $
ENDSTYLE
ON TABLE PCHOLD FORMAT EXL2K
END
TABLE FILE COBCCNTS
HEADING
"COBC SUMMARY BY WEEK"
" "
SUM CNTS
ACROSS WEEKOF
BY COMPANY
BY INTERMEDIARY
ON TABLE SET STYLE *
TYPE=REPORT, TITLETEXT='COBC SUMMARY BY WEEK', $
TYPE=HEADING, SIZE=18, $
ENDSTYLE
ON TABLE PCHOLD FORMAT EXL2K
END
TABLE FILE COBCCNTS
HEADING
"COBC SUMMARY BY ID"
" "
SUM CNTS
ACROSS DAY
BY COMPANY
BY INTERMEDIARY
BY WEEKOF
ON TABLE SET STYLE *
TYPE=REPORT, TITLETEXT='COBC SUMMARY BY ID', $
TYPE=HEADING, SIZE=18, $
ENDSTYLE
ON TABLE PCHOLD FORMAT EXL2K CLOSE
END

Thanks Glenda!

I this works great! I also saw this other thread with a solution. This will boggle the minds of the end users a bit

Thanks again!