-SET &MONTH='201105';
-SET &FIRST_MONTH=&MONTH||'01';


-SET &DATE1=DATEADD(&FIRST_MONTH,'D',1);
-TYPE &DATE1
-SET &DATE2=DATEADD(&FIRST_MONTH,'M',1);
-TYPE &DATE2
-SET &DATE3=DATECVT(&DATE1,'YYMD','A8YYMD');
-TYPE &DATE3

7703:
20110502
569611005
69610906

7701:
20110502
20110601
20110601

who can tell me why?
thanks!

This message has been edited. Last edited by: Kerry,

First DATEADD does directly work with Dialogue Manager. Neither does DATEMOV or DATEDIF. Do a search on UDATEADD. You will find a DEFINE FUNCTION that will work with Dialogue Manager. You can also create similar Functions for DATEMOV and DATEDIF.

Per the 7702 Using Functions Manual:

quote:

Do not use DATEADD with Dialogue Manager. DATEADD requires a date to be in date format; Dialogue Manager interprets a date as alphanumeric or numeric.

Perhaps take a look at the following amendments to your code:

-SET &MONTH='201105';
-SET &FIRST_MONTH=&MONTH | '01';
-TYPE &FIRST_MONTH
-*
-SET &DATE1=AYMD(&FIRST_MONTH,1,'I8YYMD');
-TYPE &DATE1
-*
-SET &DATE2=AYM(&MONTH,1,'I6YYM');
-SET &DATE2 = &DATE2 | '01';
-TYPE &DATE2
-EXIT  

Yielding:

20110501
20110502
20110601

DATEADD and other SmartDate-only functions can be used in Dialogue Manager (DM), but the DM dates must first be converted to SmartDate integers with function DATECVT. Note that the DM dates must be identified as numeric and not alpha in DATECVT (I8YYMD, not A8YYMD). After performing the desired SmartDate math (DATEADD in this case), the SmartDate integers must be converted back to DM dates. But as David indicates, the legacy date functions AYMD and AYM will handle DM dates directly and do not require conversion to/from SmartDate formats.

-SET &MONTH = '201105';
-SET &FIRST_MONTH = &MONTH || '01';
-*
-SET &DATE1 = DATECVT(DATEADD(DATECVT(&FIRST_MONTH,'I8YYMD','YYMD'),'D',1),'YYMD','I8YYMD');
-SET &DATE2 = DATECVT(DATEADD(DATECVT(&FIRST_MONTH,'I8YYMD','YYMD'),'M',1),'YYMD','I8YYMD');
-*
-TYPE &DATE1
-TYPE &DATE2

thanks all