I have few basic ACROSS report questions.

1) How to show the Retail Cost title for each column?

2) How to remove the line and space between ACROSS Title and Data?

TABLE FILE CAR
SUM
RETAIL_COST
BY COUNTRY
ACROSS CAR AS ''
ACROSS MODEL AS ''
ON TABLE SET PAGE-NUM OFF
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET STYLE *
TYPE=REPORT,FONT=ARIAL,SIZE=9,GRID=OFF,SQUEEZE=ON,$
TYPE=TITLE,BACKCOLOR=RGB(0 91 91),COLOR=WHITE,$
TYPE=ACROSSVALUE,BACKCOLOR=RGB(0 91 91),COLOR=WHITE,$
TYPE=DATA,STYLE=BOLD,$
TYPE=DATA,COLUMN=CONSISTENTITEM,BACKCOLOR=RGB(0 91 91),COLOR=WHITE,$
TYPE=DATA,ACROSSCOLUMN=N1,BACKCOLOR=SILVER,COLOR=BLACK,$
ENDSTYLE
END
-EXIT

Thanks in advance.

This message has been edited. Last edited by: WFDevConsultant,

Tricky one for the title, you must repeat the SUM field. ACROSS need two fields to display title...

For the second question, add the two SET

SET ACROSSTITLE=SIDE
SET BYPANEL=ON

TABLE FILE CAR
SUM RETAIL_COST NOPRINT
    RETAIL_COST
BY COUNTRY
ACROSS CAR AS ''
ACROSS MODEL AS ''
ON TABLE SET PAGE-NUM OFF
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET STYLE *
TYPE=REPORT,FONT=ARIAL,SIZE=9,GRID=OFF,SQUEEZE=ON,$
TYPE=TITLE,BACKCOLOR=RGB(0 91 91),COLOR=WHITE,$
TYPE=ACROSSVALUE,BACKCOLOR=RGB(0 91 91),COLOR=WHITE,$
TYPE=DATA,STYLE=BOLD,$
TYPE=DATA,COLUMN=CONSISTENTITEM,BACKCOLOR=RGB(0 91 91),COLOR=WHITE,$
TYPE=DATA,ACROSSCOLUMN=N1,BACKCOLOR=SILVER,COLOR=BLACK,$
ENDSTYLE
END

Thanks Martin.

I got the first one to work but your suggestion on second one didn't work.

See my code below.

SET ACROSSTITLE=SIDE
SET BYPANEL=ON

TABLE FILE CAR
SUM
RETAIL_COST NOPRINT
BY COUNTRY
ACROSS CAR AS ''
SUM
RETAIL_COST AS 'Retail,Cost'
BY COUNTRY
ACROSS MODEL AS ''
ON TABLE SET PAGE-NUM OFF
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET STYLE *
TYPE=REPORT,FONT=ARIAL,SIZE=9,GRID=OFF,SQUEEZE=ON,$
TYPE=TITLE,BACKCOLOR=RGB(0 91 91),COLOR=WHITE,$
TYPE=ACROSSVALUE,BACKCOLOR=RGB(0 91 91),COLOR=WHITE,$
TYPE=DATA,STYLE=BOLD,$
TYPE=DATA,COLUMN=CONSISTENTITEM,BACKCOLOR=RGB(0 91 91),COLOR=WHITE,$
TYPE=DATA,ACROSSCOLUMN=N1,BACKCOLOR=SILVER,COLOR=BLACK,$
ENDSTYLE
END
-EXIT

Try this

TABLE FILE CAR
SUM
RETAIL_COST NOPRINT
BY COUNTRY
ACROSS CAR AS ''
SUM
RETAIL_COST AS 'Retail,Cost'
BY COUNTRY
ACROSS MODEL AS ''
ON TABLE SET PAGE-NUM OFF
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TYPE=REPORT,
     BORDER-TOP=LIGHT,
     BORDER-BOTTOM=LIGHT,
     BORDER-LEFT=LIGHT,
     BORDER-RIGHT=LIGHT,
     BORDER-COLOR=WHITE,
$
TYPE=REPORT,FONT=ARIAL,SIZE=9,GRID=OFF,SQUEEZE=ON,$
TYPE=TITLE,BACKCOLOR=RGB(0 91 91),COLOR=WHITE,$
TYPE=ACROSSVALUE,BACKCOLOR=RGB(0 91 91),COLOR=WHITE,$
TYPE=DATA,STYLE=BOLD,$
TYPE=DATA,COLUMN=CONSISTENTITEM,BACKCOLOR=RGB(0 91 91),COLOR=WHITE,$
TYPE=DATA,ACROSSCOLUMN=N1,BACKCOLOR=SILVER,COLOR=BLACK,$
ENDSTYLE
END
-RUN
  

This did the trick. Thanks.