Good morning,

I have a compound report consists of two fexes which outputs to EXL2K, HTML or PDF by user choice. Both fexes are quite simple - the first one is grided detail only, and the second once have subhead & subfoot on one of the sorted field.

Symtoms after compounded:
1) 1st fex: some of columns lost the grid, and one of the column font size is larger than the others.
2) 2nd fex: one or sometime all columns were displayed with grey background color.(I defined all column titles that way).

I ran the fexes individually to ensure output in EXL2K, PDF & HTML are satisfactory. Now how can I keep the same formats once I compound them? There is one post simular to mine, unfortunately I couldn't make it my solution. Your help is gratefully appreciated.

Thanks,

Hua

This message has been edited. Last edited by: Hua,

Hua,

The styling of the individual reports in a compound report should work for the three formats. What kind of compound report is it, the traditional SET COMPOUND=OPEN/CLOSE type, or the newer COMPOUND LAYOUT type?

Maybe posting your code will help determine the problem.

quote:

the traditional SET COMPOUND=OPEN/CLOSE type

Yes, I should've be more specific. Here are the codes

The Main fex...

 -DEFAULT &WHS='MDN'
-DEFAULT &KIT = 'F6692'
-DEFAULT &WFFMT = 'HTML'
SET COMPOUND = OPEN NOBREAK
EX app/com014cc2_kit_component_availability.fex WHS=&WHS, KIT=&KIT, WFFMT=&WFFMT
SET COMPOUND = CLOSE
EX app/com014cc3_kit_component_customer_allocations.fex WHS=&WHS, KIT=&KIT, WFFMT=&WFFMT
-EXIT
 

app/com014cc2_kit_component_availability.fex...

SET TOPMARGIN = 0
SET PRINTPLUS = ON
-DEFAULT &WHS = 'MDN';
-DEFAULT &KIT = 'C504';
-* components of a given kit, on open orders - current or previous kit structure
JOIN
 MBCDREP.MBCDREP.CDAENB AND MBCDREP.MBCDREP.CDDCCD AND MBCDREP.MBCDREP.CDCVNB
 AND MBCDREP.MBCDREP.CDFCNB IN MBCDREP TO MULTIPLE MBADREP.MBADREP.ADAENB
 AND MBADREP.MBADREP.ADDCCD AND MBADREP.MBADREP.ADCVNB
 AND MBADREP.MBADREP.ADFCNB IN MBADREP AS J1
 END
TABLE FILE MBCDREP
BY CDAITX
BY ADAITX
BY CDA3CD
WHERE CDA3CD EQ '&WHS.Warehouse.';
WHERE CDH2ST EQ '1';
WHERE CDAITX EQ '&KIT.Kit item.';
WHERE ADAASZ NE 0;
ON TABLE HOLD AS H_OPNCOM FORMAT ALPHA
END

-* component in the current kit structure
TABLE FILE MBCAREP
PRINT
     CAJ6NB
BY CAAITX
BY CAGYTX
WHERE CAAITX EQ '&KIT.Kit item.';
ON TABLE HOLD AS H_CURSTR FORMAT ALPHA
END
MATCH FILE H_OPNCOM
  PRINT CDA3CD
  BY CDAITX AS 'KIT'
  BY ADAITX AS 'OPN_COMP'
RUN
FILE H_CURSTR
  PRINT CAJ6NB
  BY CAAITX
  BY CAGYTX
AFTER MATCH HOLD AS H_ALLCOM OLD-OR-NEW
END
-* Get item balance info for each component
JOIN
CDA3CD AND OPN_COMP IN H_ALLCOM TO MULTIPLE HOUSE AND ITNBR
IN ITEMBL AS J2
END
TABLE FILE H_ALLCOM
PRINT
HOUSE
KIT
OPN_COMP
CAJ6NB
MOHTQ
MALQT
MPUPQ
MPRPQ
ON TABLE HOLD AS H_COMP FORMAT FOCUS
END
JOIN
LEFT_OUTER H_COMP.SEG01.OPN_COMP IN H_COMP TO MULTIPLE IT0100P.IT0100P.E0INBR
IN IT0100P AS J3
END
JOIN
LEFT_OUTER IT0100P.IT0100P.E0STID AND IT0100P.IT0100P.E0INBR IN H_COMP
TO MULTIPLE ITMRVA.ITMRVA.STID AND ITMRVA.ITMRVA.ITNBR IN ITMRVA AS J4
END
DEFINE FILE H_COMP
Available/D7.2=MOHTQ + MPUPQ + MPRPQ - MALQT;
Phased/A12 MISSING ON = IF CAJ6NB IS MISSING OR CAJ6NB EQ 0 THEN '*Phased out*' ELSE ' '
END
TABLE FILE H_COMP
PRINT
     OPN_COMP AS 'Component '
     ITDSC AS 'Description'
     CAJ6NB/P9.2 AS 'Qty,per'
     MOHTQ/P9.2 AS 'Qty,OH'
     MPUPQ/P9.2 AS 'On,PO'
     MPRPQ/P9.2 AS 'On,MO'
     MALQT/P9.2 AS 'Alloc,Qty'
     Available/P9.2
     Phased AS ''
HEADING
"Kit Component Availability"
"&KIT<+0>  for warehouse - <+0>&WHS<+0> "
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT &WFFMT.(<Excel 2000,EXL2K>,<HTML,HTML>,<PDF,PDF>).Select type of display output.
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     UNITS=IN,
     PAGESIZE='Letter',
     SQUEEZE=ON,
     ORIENTATION=LANDSCAPE,
$
TYPE=REPORT,
     BORDER-TOP=LIGHT,
     BORDER-BOTTOM=LIGHT,
     BORDER-LEFT=LIGHT,
     BORDER-RIGHT=LIGHT,
     FONT='ARIAL',
     SIZE=9,
     BACKCOLOR='NONE',
$
TYPE=DATA,
     COLUMN=N1,
     JUSTIFY=CENTER,
$
TYPE=DATA,
     COLUMN=N2,
     JUSTIFY=CENTER,
$
TYPE=DATA,
     COLUMN=N3,
     JUSTIFY=CENTER,
$
TYPE=DATA,
     COLUMN=N4,
     JUSTIFY=CENTER,
$
TYPE=DATA,
     COLUMN=N5,
     JUSTIFY=CENTER,
$
TYPE=DATA,
     COLUMN=N6,
     JUSTIFY=CENTER,
$
TYPE=DATA,
     COLUMN=N7,
     JUSTIFY=CENTER,
$
TYPE=DATA,
     COLUMN=N8,
     JUSTIFY=CENTER,
$
TYPE=DATA,
     COLUMN=N9,
     JUSTIFY=CENTER,
$
TYPE=TITLE,
     BACKCOLOR='SILVER',
     JUSTIFY=CENTER,
$
TYPE=TABHEADING,
     SIZE=12,
     STYLE=BOLD,
$
TYPE=TABFOOTING,
     SIZE=12,
     STYLE=BOLD,
$
TYPE=HEADING,
     SIZE=12,
     STYLE=BOLD,
$
TYPE=HEADING,
     LINE=1,
     JUSTIFY=CENTER,
$
TYPE=HEADING,
     LINE=1,
     OBJECT=TEXT,
     ITEM=1,
     SIZE=14,
     COLOR='BLUE',
$
TYPE=HEADING,
     LINE=2,
     JUSTIFY=CENTER,
$
TYPE=HEADING,
     LINE=2,
     OBJECT=TEXT,
     ITEM=1,
     SIZE=14,
     COLOR='BLUE',
$
TYPE=HEADING,
     LINE=2,
     OBJECT=TEXT,
     ITEM=2,
     SIZE=14,
     COLOR='BLUE',
$
TYPE=HEADING,
     LINE=2,
     OBJECT=TEXT,
     ITEM=3,
     SIZE=14,
     COLOR='BLUE',
$
TYPE=HEADING,
     LINE=2,
     OBJECT=TEXT,
     ITEM=4,
     SIZE=14,
     COLOR='BLUE',
$
TYPE=FOOTING,
     SIZE=12,
     STYLE=BOLD,
$
TYPE=SUBHEAD,
     SIZE=10,
     STYLE=BOLD,
$
TYPE=SUBFOOT,
     SIZE=10,
     STYLE=BOLD,
$
TYPE=SUBTOTAL,
     BACKCOLOR=RGB(210 210 210),
$
TYPE=ACROSSVALUE,
     SIZE=9,
$
TYPE=ACROSSTITLE,
     STYLE=BOLD,
$
TYPE=GRANDTOTAL,
     BACKCOLOR=RGB(210 210 210),
     STYLE=BOLD,
$
ENDSTYLE
END
-RUN
  

app/com014cc3_kit_component_customer_allocations.fex...

-DEFAULT &WHS = 'MDN'
-DEFAULT &KIT = 'C504'
-* get open order components of a kit
JOIN
 MBCDREP.MBCDREP.CDAENB AND MBCDREP.MBCDREP.CDDCCD AND MBCDREP.MBCDREP.CDCVNB
 AND MBCDREP.MBCDREP.CDFCNB IN MBCDREP TO MULTIPLE MBADREP.MBADREP.ADAENB
 AND MBADREP.MBADREP.ADDCCD AND MBADREP.MBADREP.ADCVNB
 AND MBADREP.MBADREP.ADFCNB IN MBADREP AS J0
 END
TABLE FILE MBCDREP
BY ADAITX AS 'COMPONENT'
WHERE ( CDH2ST EQ '1' ) AND ( CDA3CD EQ '&WHS' ) AND ( CDAITX EQ '&KIT' );
WHERE CDH3ST LT '50';
WHERE ( ADAASZ GT 0 ) AND ( ADHFCD LT '50' ) AND ( ADIIST LT '50' ) AND ( ADAQQT GT 0 );
ON TABLE NOTOTAL
ON TABLE HOLD AS H_COMP FORMAT ALPHA
ON TABLE SET STYLE *
     UNITS=IN,
     SQUEEZE=ON,
     ORIENTATION=PORTRAIT,
$
TYPE=REPORT,
     GRID=OFF,
     FONT='TIMES NEW ROMAN',
     SIZE=10,
$
ENDSTYLE
END
SET PRINTPLUS = ON
SET LINES = 9999
SET ORIENTATION = LANDSCAPE
-* get all the customers orders for the required components(in any kit)
JOIN CLEAR *
JOIN
 MBADREP.MBADREP.ADAENB AND MBADREP.MBADREP.ADDCCD AND MBADREP.MBADREP.ADCVNB
 AND MBADREP.MBADREP.ADFCNB IN MBADREP TO MULTIPLE MBCDREP.MBCDREP.CDAENB
 AND MBCDREP.MBCDREP.CDDCCD AND MBCDREP.MBCDREP.CDCVNB
 AND MBCDREP.MBCDREP.CDFCNB IN MBCDREP AS J1
 END
JOIN
 MBCDREP.MBCDREP.CDAENB AND MBCDREP.MBCDREP.CDDCCD AND MBCDREP.MBCDREP.CDCVNB
 IN MBADREP TO MULTIPLE MBC6REP.MBC6REP.C6AENB AND MBC6REP.MBC6REP.C6DCCD
 AND MBC6REP.MBC6REP.C6CVNB IN MBC6REP AS J2
 END
JOIN
 MBADREP.MBADREP.ADAITX IN MBADREP TO MULTIPLE ITMENT.ITMENT.ITNBR IN ITMENT
 AS J3
 END
JOIN
 MBC6REP.MBC6REP.C6CANB AND MBC6REP.MBC6REP.C6AENB IN MBADREP TO MULTIPLE
 MBBFREP.MBBFREP.CUSNO AND MBBFREP.MBBFREP.COMNO IN MBBFREP AS J4
 END
DEFINE FILE MBADREP
Order/A15=EDIT(ADAENB) | '-' | ADDCCD | '-' | ADCVNB;
Remark/A1=IF ADAITX EQ '&KIT' THEN '*' ELSE ' ';
ORDATE/A6=EDIT( C6ACDT, '$$$$9999') || EDIT(C6ACDT, '$$99');
DSP_DATE/MDY=DATECVT(ORDATE, 'A6', 'MDY');
END
TABLE FILE MBADREP
PRINT
     ADAQQT AS 'Open  pick,Quantity'
     Remark AS ''
     Order
     DSP_DATE AS 'Order,Date'
     CDAITX AS 'Kit'
     CDALTX AS 'Description'
     C6CANB
     CUSNM AS 'Customer'
     C6CHNB
BY ADAITX AS ''
ON ADAITX SUBHEAD
"Component:   <ADAITX - <ITDSC "
ON ADAITX SUBTOTAL
     ADAQQT AS 'Allocation'
HEADING
"All Customer Allocations of the Components"
"&KIT<+0>  - for warehouse <+0>&WHS<+0> "
FOOTING BOTTOM
"NOTE: (*) indicates the quantity allocated to the current Kit"
WHERE CDA3CD EQ '&WHS.For Warehouse.';
WHERE ( ADIIST LT '50' ) AND ( ADHFCD LT '50' );
WHERE ADAITX IN FILE H_COMP;
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT &WFFMT.(<Excel 2000,EXL2K>,<HTML,HTML>,<PDF,PDF>).Select type of display output.
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     UNITS=IN,
     PAGESIZE='Letter',
     SQUEEZE=ON,
     ORIENTATION=LANDSCAPE,
$
TYPE=REPORT,
     FONT='ARIAL',
     SIZE=9,
     COLOR='BLACK',
     STYLE=NORMAL,
     LEFTGAP=0.013889,
$
TYPE=TITLE,
     BACKCOLOR='SILVER',
$
TYPE=TABHEADING,
     SIZE=12,
     STYLE=BOLD,
$
TYPE=TABFOOTING,
     SIZE=12,
     STYLE=BOLD,
$
TYPE=HEADING,
     BORDER-TOP=LIGHT,
     BORDER-BOTTOM=LIGHT,
     BORDER-LEFT=LIGHT,
     BORDER-RIGHT=LIGHT,
$
TYPE=HEADING,
     LINE=1,
     JUSTIFY=CENTER,
$
TYPE=HEADING,
     LINE=1,
     OBJECT=TEXT,
     ITEM=1,
     SIZE=14,
     COLOR='BLUE',
     STYLE=BOLD,
$
TYPE=HEADING,
     LINE=2,
     JUSTIFY=CENTER,
$
TYPE=HEADING,
     LINE=2,
     OBJECT=TEXT,
     ITEM=1,
     SIZE=14,
     COLOR='BLUE',
$
TYPE=HEADING,
     LINE=2,
     OBJECT=TEXT,
     ITEM=2,
     SIZE=14,
     COLOR='BLUE',
$
TYPE=HEADING,
     LINE=2,
     OBJECT=TEXT,
     ITEM=3,
     SIZE=14,
     COLOR='BLUE',
$
TYPE=HEADING,
     LINE=2,
     OBJECT=TEXT,
     ITEM=4,
     SIZE=14,
     COLOR='BLUE',
$
TYPE=FOOTING,
     SIZE=12,
     STYLE=BOLD,
$
TYPE=FOOTING,
     LINE=1,
     OBJECT=TEXT,
     ITEM=1,
     SIZE=8,
     STYLE=NORMAL,
$
TYPE=SUBHEAD,
     SIZE=10,
     STYLE=BOLD,
$
TYPE=SUBFOOT,
     SIZE=10,
     STYLE=BOLD,
$
TYPE=SUBTOTAL,
     BACKCOLOR=RGB(210 210 210),
$
TYPE=ACROSSVALUE,
     SIZE=9,
$
TYPE=ACROSSTITLE,
     STYLE=BOLD,
$
TYPE=GRANDTOTAL,
     BACKCOLOR=RGB(210 210 210),
     STYLE=BOLD,
$
ENDSTYLE
END
-RUN
  

For which format do you have the styling problem? I think you may have a problem with HTML, because the

ON TABLE SET HTMLCSS ON

will generate two CSS stylesheets that are applied to both reports. If the problem is with HTML, try turning off the

ON TABLE SET HTMLCSS ON

commands.

Francis,

As you suspected, I do have problem with HTML.
ON TABLE SET HTMLCSS ON is the general direction to my problem. I do need it for the first table so the solid border lines show instead of the default grid lines. And I don't need it for the 2nd one.

Today, I learned what the internal CSS do to my report. Thanks to you, Francis.

Hua

Hua, glad to have helped. Francis.