I have some input strings of which the length are different. Is there a function I can patch it with trailing spaces to make it fixed length?

example:

'F121' -> 'F121 ' (A5)
'bdd' -> 'bdd ' (A5)

Thanks!

This message has been edited. Last edited by: bug,

I do this....
quick & dirty

-DEFAULT &mystring = '123';
-TYPE &mystring  &mystring.LENGTH
-SET &mystring = &mystring | '     ';
-SET &mystring = EDIT( &mystring.QUOTEDSTRING, '99999');
-TYPE &mystring  &mystring.LENGTH

This works

Thanks!

quote:

Originally posted by susannah:
I do this....
quick & dirty

-DEFAULT &mystring = '123';
-TYPE &mystring  &mystring.LENGTH
-SET &mystring = &mystring | '     ';
-SET &mystring = EDIT( &mystring.QUOTEDSTRING, '99999');
-TYPE &mystring  &mystring.LENGTH

Could not resist using one of my favourite techniques, which is useful if there are many variables with different length requirements:

DEFINE FUNCTION VARFILL (STRING/A200,LENGTH/I3)
VARFILL/A200V=SUBSTV(200,STRING,1,LENGTH,VARFILL);
END
-RUN

-DEFAULT &mystring = '123';
-TYPE &mystring  &mystring.LENGTH
-SET &mystring = VARFILL(&mystring.QUOTEDSTRING,5);
-TYPE &mystring  &mystring.LENGTH

Be aware of the special case where the value of &mystring is FOC_NONE or _FOC_NULL. You would end up with 'FOC_N' or '_FOC_' respectively, neither of which do what's expected of them.

Good point.

DEFINE FUNCTION VARFILL (STRING/A200,LENGTH/I3)
LENGTH/I3 = IF STRING LIKE 'FOC_%' OR STRING LIKE '_FOC_%' THEN ARGLEN(200,STRING,'I3') ELSE LENGTH;
VARFILL/A200V = SUBSTV(200,STRING,1,LENGTH,'A200V');
END
-RUN

-DEFAULT &mystring = 'FOC_NONE';
-TYPE &mystring  &mystring.LENGTH
-SET &mystring = VARFILL('&mystring.EVAL',5);
-TYPE &mystring  &mystring.LENGTH

This message has been edited. Last edited by: Alan B,

And don't forget FPRINT (though you're 766 version may not have access to it, you're 7704 will)

-DEFAULTS &STR1='F121';
-TYPE &STR1 &STR1.LENGTH
-SET &STR1TYPE=IF &STR1.TYPE EQ N THEN I ELSE A;
-SET &STR2=FPRINT('&STR1.EVAL',&STR1TYPE.EVAL&STR1.LENGTH,'A5');
-TYPE &STR2 &STR2.LENGTH