Is it possible to format a pdf report to look like the picture below. Or format it so it looks almost like the picture. I tried but I am not able to get the grid boxs around the Total Moved totals.



Thanks,
prodrigu

This message has been edited. Last edited by: prodrigu,

There is no "picture below". But, the short answer is YES!. The answer is probably shorter then the styling...

Show my the picture and I'll show you some code.

Doug,

When I open up the discussion I see the picture. Can you send me your email and I will send you the picture? Or is there another way to upload pictures besides using http://tinypic.com?

Thanks,
prodrigu

"http://tinypic.com" is blocked here at my company. Please check you Private Message for my email address.

Doug,

I just sent you the picture of the pdf formatting I am trying to accomplish. Is there another tool I can use to upload images/pictures to this forum?

Thanks,
prodrigu

I use dropbox.com and store my screenshots in a public folder - dropbox provides the image URL that you can use in the IMG tag in FocalPoint. Dropbox has a free option and I have not seen it being blocked...

Thanks Prodrigu, I got the image. Let me check it out.

Francis: Could you pass on a link to a dropbox image for me to check?

Done this sort of thing before.

The only problem is the text "Total Moved"

Waz,

Can you send me an example you have done without the text "Total Moved"?

Thanks,
prodrigu

I'll set one up.

OK, here is a sample.

The idea is to have your totals as records in the data, so the grid can be turned on/off.

TABLE   FILE CAR
 SUM    
        COMPUTE CAR/A16   = ' ' ;
        COMPUTE MODEL/A24 = ' ' ;
        COMPUTE DEALER_COST/D7 MISSING ON  = MISSING ;
        COMPUTE SEATS/I3 MISSING ON        = MISSING ;
        COMPUTE RETAIL_COST/D7 MISSING ON  = MISSING ;
        COMPUTE REC_TYPE/A1 = 'X' ;

 BY     COUNTRY

 ON     TABLE HOLD AS TMP_CAR FORMAT ALPHA

END

-RUN

FILEDEF TMP_CAR DISK tmp_car.ftm (APPEND

-RUN

TABLE   FILE CAR
 PRINT  
        DEALER_COST
        SEATS
        RETAIL_COST
        COMPUTE REC_TYPE/A1 = 'D' ;

 BY     COUNTRY
 BY     CAR
 BY     MODEL

 ON     TABLE SAVE AS TMP_CAR 

END

-RUN

TABLE   FILE CAR
 SUM    
        COMPUTE C/A16 = ' ' ;
        COMPUTE M/A24 = ' ' ;
        DEALER_COST
        COMPUTE S/I3 MISSING ON  = MISSING ;
        RETAIL_COST
        COMPUTE REC_TYPE/A1 = 'T' ;

 BY     COUNTRY

 ON     TABLE SAVE AS TMP_CAR 

END

-RUN

FILEDEF TMP_CAR DISK tmp_car.ftm

-RUN

SET NODATA = ' '

DEFINE  FILE TMP_CAR
 DISP_COUNTRY/A10 = IF REC_TYPE EQ 'D' THEN COUNTRY ELSE ' ' ;
END

TABLE   FILE TMP_CAR
 PRINT  
        DEALER_COST   AS 'Dealer Cost'
        SEATS/I3S     AS 'Seats'
        RETAIL_COST   AS 'Retail Cost'

 BY     COUNTRY       NOPRINT
 BY     REC_TYPE      NOPRINT
 BY     DISP_COUNTRY  AS 'Country'
 BY     CAR           AS 'Car'
 BY     MODEL         AS 'Model'

-* ON     COUNTRY SKIP-LINE
 ON     TABLE SET STYLE * 
  PAGESIZE=A4,ORIENTATION=PORTRAIT, BORDER=OFF, SIZE=9, GRID=OFF, $
  TYPE=TITLE, BORDER=LIGHT, $
  TYPE=DATA, BORDER=LIGHT, $
  TYPE=DATA  , COLUMN=P01, BORDER-LEFT=OFF, BORDER-BOTTOM=OFF, WHEN=REC_TYPE EQ 'T', $
  TYPE=DATA  , COLUMN=P02, BORDER-LEFT=OFF, BORDER-BOTTOM=OFF, WHEN=REC_TYPE EQ 'T', $
  TYPE=DATA  , COLUMN=P03, BORDER-LEFT=OFF, BORDER-BOTTOM=OFF, WHEN=REC_TYPE EQ 'T', $
  TYPE=DATA  , COLUMN=P05, BORDER-BOTTOM=OFF, WHEN=REC_TYPE EQ 'T', $
  TYPE=DATA, BORDER-LEFT=OFF, BORDER-RIGHT=OFF, WHEN=REC_TYPE EQ 'X', $
 ENDSTYLE

 ON     TABLE PCHOLD FORMAT PDF 

END

-RUN

WAZ,

I was able to get Total Moved positioned correctly. It will look alot clearner once you add a dummy row before the totals.

  
TABLE FILE CAR
SUM    
COMPUTE CAR/A16   = ' ' ;
COMPUTE MODEL/A24 = ' ' ;
COMPUTE DEALER_COST/D7 MISSING ON  = MISSING ;
COMPUTE SEATS/I3 MISSING ON        = MISSING ;
COMPUTE RETAIL_COST/D7 MISSING ON  = MISSING ;
COMPUTE REC_TYPE/A1 = 'X' ;
BY COUNTRY
ON TABLE HOLD AS TMP_CAR FORMAT ALPHA
END
-RUN

FILEDEF TMP_CAR DISK tmp_car.ftm (APPEND
-RUN

TABLE FILE CAR
PRINT  
DEALER_COST
SEATS
RETAIL_COST
COMPUTE REC_TYPE/A1 = 'D' ;
BY COUNTRY
BY CAR
BY MODEL
ON TABLE SAVE AS TMP_CAR 
END
-RUN

TABLE FILE CAR
SUM    
COMPUTE C/A16 = ' ' ;
COMPUTE M/A24 = 'Total Moved:' ;
DEALER_COST
COMPUTE S/I3 MISSING ON  = MISSING ;
RETAIL_COST
COMPUTE REC_TYPE/A1 = 'T' ;
BY COUNTRY
ON TABLE SAVE AS TMP_CAR 
END
-RUN

FILEDEF TMP_CAR DISK tmp_car.ftm
-RUN

SET NODATA = ' '

DEFINE FILE TMP_CAR
DISP_COUNTRY/A10 = IF REC_TYPE EQ 'D' THEN COUNTRY ELSE ' ' ;
END

TABLE FILE TMP_CAR
PRINT  
DEALER_COST   AS 'Dealer Cost'
SEATS/I3S     AS 'Seats'
RETAIL_COST   AS 'Retail Cost'
BY COUNTRY  NOPRINT     
BY REC_TYPE NOPRINT     
BY DISP_COUNTRY  AS 'Country'
BY CAR           AS 'Car'
BY MODEL         AS 'Model'
ON TABLE SET STYLE * 
	PAGESIZE=A4,
	ORIENTATION=PORTRAIT, 
	BORDER=OFF, 
	SIZE=9, 
	GRID=OFF, $
TYPE=TITLE, BORDER=LIGHT, $
TYPE=DATA, BORDER=LIGHT, $
TYPE=DATA, COLUMN=P01, BORDER-LEFT=OFF, BORDER-BOTTOM=OFF, WHEN=REC_TYPE EQ 'T', $
TYPE=DATA, COLUMN=P02, BORDER-LEFT=OFF, BORDER-BOTTOM=OFF, WHEN=REC_TYPE EQ 'T', $
TYPE=DATA, COLUMN=P03, BORDER-LEFT=OFF, BORDER-BOTTOM=OFF, JUSTIFY=RIGHT, WHEN=REC_TYPE EQ 'T', $
TYPE=DATA, COLUMN=P05, BORDER-BOTTOM=OFF, WHEN=REC_TYPE EQ 'T', $
TYPE=DATA, BORDER-LEFT=OFF, BORDER-RIGHT=OFF, WHEN=REC_TYPE EQ 'X', $
ENDSTYLE
ON TABLE PCHOLD FORMAT PDF 
END
-RUN

Just be aware that if the colum to get Total Moved is small, or a numeric, it will cause problems.

This is very much possible with 7.7.03. You should be able to use new features like HEADALIGN=BODY, BORDERALL=LIGHT, COLPSAN=n, etc..
For subtotals, use COMPUTEs.