I would like to reference the TSCOMID and SESID in a FOCEXEC, so we can log activity.

We are running a self-service application under WebFocus 5.5.3 running on Windows 2003 server.
The application uses has three large drill menu, and a lot of Dialogue Manager. This seems to be a random event.

On occasion processing threads stay in use although server is done with the processing and the report has returned to the client browser. If the number of the stuck agents get over eight the server response time become unacceptable. Setting the agent_refresh to 5 instead of the 100 has reduced the occurance of the stuck theads, but not completely eliminated them.


What I would like to do is log user activities and match it to the stuck thread. This would allow me to get a better understanding of the root cause of the problem

The configuration info is:
release = R720533B
gen_num = 07.01
source_date = 12/14/2004 11:53:50
gen_build_date = 12/14/2004 14:49:06
gen_buildsys = Windows 2000 5.0 Build 2195 Service Pack 3
gen_short_buildsys = Windows NT 5.0
eda_supportsys = Windows
media_type = 3595DB308B51C9C2

I don't think those particular values are available to be passed back to or used in a fex. All of this information can be made available in server traces. Turn traces on and run the app a few times until you get a "stuck" agent. Then you can go back through the traces and the EDAPRINT to see the TSCOMID and SESID used and all the processing that happened on that agent. Remember to turn them off when you're done. They get really big, really fast depending on what traces are set. In fact, I believe you can turn traces on for a single user or within the self-service app code itself to help control what get's written to the trace file.
I don't know exactly what you're looking for si I can't say what trace components to use, but it's documented in the server operations manual.

Jim,

I don't know about SESID variable but for the TSCOMID one you can try with this code hereunder:

-SET &V = TEMPPATH (100,'A100');
-SET &L1 = ARGLEN (100,'&V.EVAL','I3');
-SET &L = &L1 + 1;
-SET &F = 'A' || &L.EVAL ;

-SET &&EDATEMP = TEMPPATH (&L.EVAL ,'&F.EVAL');
-SET &POSFD = POSIT ( '&&EDATEMP.EVAL', &L ,'ts0' ,3 ,'I2');
-SET &TSCOMID = SUBSTR (&L ,'&&EDATEMP.EVAL', &POSFD ,&POSFD + 7 ,8 ,'A8');

Michel

Jim,

This is the way to get the TSCOMID and SESID value you need at execution time.
You need to execute this code at the end of your focexec. (as a focexec himself using -INCLUDE OR EXEC)

-DEFAULTS &TSCOMID = '?';
-DEFAULTS &SESID = '?';

-SET &V = TEMPPATH (255, 'A255');
-SET &L = ARGLEN (255, &V ,'I3');
-SET &F = 'A' || &L;
-SET &V = TEMPPATH (&L , '&F.EVAL');
-SET &EDATEMP = &V ;
-SET &P = POSIT ( '&EDATEMP.EVAL' , &L , 'ts0' , 3 , 'I2');
-SET &TSCOMID = SUBSTR (&L , '&EDATEMP.EVAL' , &P , &P + 7 , 8 , 'A8');
-SET &TS1 = EDIT (&TSCOMID ,'$$999999');
-SET &TS2 = TRIM ( L , &TS1 , 6 , '0' , 1 , 'A6' );
-SET &L = ARGLEN ( 6 , &TS2 ,'I3');
-SET &F = 'A' || &L;
-SET &TSNUM = SUBSTR ( 6 , '&TS2.EVAL', 1 , &L , &L , '&F.EVAL');
-SET &TIME = EDIT ('&TOD.EVAL','99$:99$:99');

FILEDEF EDAPRINT DISK D:\ibi\srv53\wfs\edaprint.log
-RUN

-*=======
DEFINE FILE EDAPRINT
-*=======
SDATE /A10 = GETTOK (F1, 150, 1, ' ', 10 , 'A10') ;
STMST /A8 = GETTOK (F1, 150, 2, ' ', 8 , 'A8' ) ;
SESID /A8 = GETTOK (F1, 150, -1, '=', 8 , 'A8' ) ;

END

-*=======
TABLEF FILE EDAPRINT
-*=======
PRINT SESID

WHERE F1 CONTAINS 'connecting'
AND F1 CONTAINS 'sesid='
AND F1 CONTAINS 'tscomid=&TSNUM.EVAL'
AND SDATE EQ '&DATEMDYY.EVAL'
AND STMST EQ '&TIME.EVAL'

ON TABLE SAVE AS SVRID FORMAT ALPHA
END
-RUN
-IF &LINES EQ 0 THEN GOTO NOSESID;

-READ SVRID &SESID.A8.
-RUN

-NOSESID
-TYPE tscomid=&TSCOMID , sesid=&SESID

Regards,
Michel