I have date and time in two separate fields in the table.
Date in date format-YYMD (ex:2009/04/14) and time in alpha format-A15 (ex: 12.40.41.625652)
What is the best way to add 36 hours into the above date and time fields?

Thanks,
JJ

This message has been edited. Last edited by: Kerry,

Here's an example, DT and TM are your date and time fields:

DEFINE FILE CAR
DT/YYMD = '2009/04/14';
TM/A15 = '12.40.41.625652';

DT1/A8YYMD = DT;
TM1/A15 = EDIT(TM,'99$:99$:999999999');
DTTM1/A24 = DT1 | ' ' | TM1;

DTTM2/HYYMDm = HADD(DT(20090414 12:40:41.625652), 'HOUR', 36, 10, 'HYYMDm'); 

END
TABLE FILE CAR
PRINT 
DT
DT1
TM
DTTM1
DTTM2

COUNTRY
END

Read up on "Using Standard Date and Time Func" in the "Using Functions" manual.

If you need to convert the last Date-time field back to individual date and time fields, you will require a couple of more defines...

Thank you Francis! If I replace hard coded date/time value with DTTM1 in DTTM2 define, I get an error. Below is how I changed it, am I doing something wrong?
DTTM2/HYYMDm = HADD(DT(DTTM1), 'HOUR', 36, 10, 'HYYMDm');

This message has been edited. Last edited by: JJ,

Use HINPUT to convert the date and time into an 'H' field -- Its input argument can be a data field, but its values should be a straight series of digits, as below:

DEFINE FILE CAR
-* construct sample values
 DT/YYMD = '&DATEYYMD';
 TM/A15 = HHMMSS('A8') | '.987654';
 DATE/YYMD WITH COUNTRY = IF DATE EQ 0 THEN DT ELSE DATE + 1;
-* convert to suitable input for HINPUT:
 ALPHA_DT/A8YYMD=DATE;
 ALPHA_DTTM/A20= ALPHA_DT | EDIT(TM,'99$99$99$999999');
-* convert to date-time format, and add 36 hours:
 DTTM/HYYMDm=HINPUT(20,ALPHA_DTTM,10,DTTM);
 LATER/HYYMDm=HADD(DTTM, 'HOUR', 36, 10, 'HYYMDm');
END
TABLE FILE CAR
 PRINT DATE TM ALPHA_DTTM DTTM LATER 
 BY COUNTRY
END

This message has been edited. Last edited by: j.gross,

JJ, Sorry! I worked on test code and then posted the wrong stuff!

Jack has posted the correct solution.

My solution should have been posted as:

DEFINE FILE CAR
DT/YYMD = '2009/04/14';
TM/A15 = '12.40.41.625652';

DT1/A8YYMD = DT;
TM1/A15 = EDIT(TM,'99$99$99$999999');
DTTM1/A24 = DT1 | TM1;

DTTM2/HYYMDm = HADD(HINPUT(20,DTTM1,10,'HYYMDm'), 'HOUR', 36, 10, 'HYYMDm');

END
TABLE FILE CAR
PRINT
DT
DT1
TM
DTTM1
DTTM2

COUNTRY
END

Apologies.

Not a problem. Thank you to both of you.