Can anybody supply a simple pie chart using the CAR file that demonstrates how to set the fontsize of the pie slice label?

I've been reading all the docmentation about setPlace(true);, setO1LabelAutofit(false);, setFontSize(getO1Label(),16); and setFontSizeAbsolute(getO1Label(),true); but I have not been able to change the fontsize of the pie slice labels.

So I suspect that there are other graphic properties that must be set appropirately.

So I think the simplest way to understand how to adjust the fontsize of a pie slice label would be for someone to create a simple and complete example using the CAR file.

I hope someone out there knows how to do this.

See it this helps...
GRAPH FILE CAR
SUM SALES
ACROSS COUNTRY
ON GRAPH SET LOOKGRAPH PIE
ON GRAPH SET GRAPHEDIT SERVER

ON GRAPH SET VAXIS 480
ON GRAPH SET HAXIS 640
ON GRAPH SET GRAPHSTYLE *

-* The line below controls display of data values for the slices
-* Valid arguments are: 0=No Labels
-* 1=Feeler lines and text
-* 2=Labels only (no feeler lines)
-* 3=Labels on slices
setPieFeelerTextDisplay(1);
-* The line below controls how the slice values are displayed
-* 2=Integer Percent, 3=Percent in Tenths, 4=Percent in Hundredths
-* For a complete list, see the documentation
setTextFormatPreset(getPieSliceLabel(),1);
-* The line below sets the kind of information displayed for each slice
-* Valid arguments are: 0=Absolute true value of slice
-* 1=Percent value of slice
-* 2=Series (Y Axis field name) label
-* 3=Series label and percent value
setPieLabelDisplay(0);

-* The next two lines set the font size and style for the Pie slice labels
setFontSizeVC(getPieSliceLabel(),1500);
setFontStyle(getPieSliceLabel(),2);
setLegendAutomatic(true);
setPlace(false);
ENDSTYLE
ON GRAPH SET BARNUMB OFF
ON GRAPH SET 3D OFF
ON GRAPH SET VZERO ON
ON GRAPH SET GRID ON
END