I am working on a drill down report. The requirement is to make values of GROUP_NM, ORG_NM and CUST_NM clickable so that a user can just click on any value and a detailed report is run. Below are the codes for the main report and a typical detailed report:

 
*********Main Report*****************
TABLE FILE SALES
SUM
     AMT1
	 AMT2
BY  LOWEST LOCATION 
BY  LOWEST MODEL 
BY  LOWEST SERIAL_NO 
BY  LOWEST GROUP_NM
BY  LOWEST ORG_NM 
BY  LOWEST CUST_NM 
BY  LOWEST SALES_PLAN 
BY  LOWEST SALES_CODE 
BY  LOWEST SALES_TYPE
BY  LOWEST INVOICE_NO 
BY  LOWEST DURATION 

WHERE LOCATION EQ &LOCATION.(OR(FIND LOCATION,LOCATION IN SALES)).LOCATION.;
WHERE GROUP_NM EQ &GROUP_NM.(OR(FIND GROUP_NM,GROUP_NM IN SALES)).GROUP_NM.;
WHERE CUST_NM EQ &CUST_NM.(OR(FIND CUST_NM,CUST_NM IN SALES)).CUST_NM.;
WHERE ORG_NM EQ &ORG_NM.(OR(FIND ORG_NM,ORG_NM IN SALES)).ORG_NM.;
WHERE SALES_PLAN EQ &SALES_PLAN.(OR(FIND SALES_PLAN,SALES_PLAN IN SALES)).SALES_PLAN.;
WHERE DURATION &OP1.(EQ,GT,LT).OPERATOR1. '&DURATION';

ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
     UNITS=CM,
     LEFTMARGIN=0.246914,
     RIGHTMARGIN=0.246914,
     ORIENTATION=LANDSCAPE,
$
TYPE=REPORT,
     BORDER-TOP=LIGHT,
     BORDER-BOTTOM=LIGHT,
     BORDER-LEFT=LIGHT,
     BORDER-RIGHT=LIGHT,
     FONT='ARIAL',
     SIZE=7,
     COLOR='BLACK',
     STYLE=NORMAL,
     RIGHTGAP=0.070547,
     LEFTGAP=0.070547,
$
TYPE=DATA,
     COLUMN=N4,
     FOCEXEC=app/test_group_nm( \
     GROUP_NM=N4 \
     ),
$
TYPE=DATA,
     COLUMN=N5,
     WRAPGAP=ON,
     FOCEXEC=app/test_org_nm( \
     ORG_NM=N5 \
     ),
$
TYPE=DATA,
     COLUMN=N6,
     WRAPGAP=ON,
     FOCEXEC=app/test_cust_nm( \
     ORG_NM=N6 \
     ),
$
ENDSTYLE
END
***************end of main report*************************

******1st drill down report: test_group_nm.fex*****************
TABLE FILE SALES
SUM
     AMT1
	 AMT2
BY  LOWEST LOCATION 
BY  LOWEST MODEL 
BY  LOWEST SERIAL_NO 
BY  LOWEST GROUP_NM
BY  LOWEST ORG_NM 
BY  LOWEST CUST_NM 
BY  LOWEST SALES_PLAN 
BY  LOWEST SALES_CODE 
BY  LOWEST SALES_TYPE
BY  LOWEST INVOICE_NO 
BY  LOWEST DURATION 

WHERE GROUP_NM EQ '&GROUP_NM'

ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *

END
**************test_group_nm.fex****************************
 

My problem is: how do I make the single or multi selected variables values passed from the main report to the GROUP_NM drill down report. I understand that if I have a drill down report test_group_nm.fex for GROUP_NM, the value of the variable &GROUP_NM is passed to the detailed report. But how do I passed multi select values of other variables to the same detailed report.

Any hint will be appreciated.

This message has been edited. Last edited by: Kerry,

You can supply more than 1 parameter for drilldowns, see below
(XCOUNTRY, XCAR and XMODEL are here set as variables for your calling procedure)

TABLE FILE CAR
  SUM
    DEALER_COST
  BY COUNTRY
  BY CAR
  BY MODEL
  ON TABLE SET HTMLCSS ON
  ON TABLE SET STYLE *
  TYPE=DATA,
     COLUMN   = DEALER_COST,
     FOCEXEC  = APP/TEST_ORG_NM( \
     XCOUNTRY = COUNTRY \
     XCAR     = CAR \
     XMODEL   = MODEL),$

  TYPE=REPORT   ,UNITS=PTS   ,FONT='VERDANA', SIZE=8        ,$
  TYPE=REPORT   ,BORDER=1    ,BORDER-COLOR=RGB(210 210 210) ,$
  TYPE=TITLE    ,STYLE=BOLD  ,BACKCOLOR=RGB(230 230 230)    ,$
  TYPE=ACROSS   ,JUSTIFY=CENTER                             ,$
  TYPE=SUBTOTAL ,STYLE=BOLD  ,BACKCOLOR=RGB(210 210 210)    ,$
  TYPE=DATA     ,TOPGAP=2    ,BOTTOMGAP=2                   ,$
  TYPE=DATA     ,BACKCOLOR=(RGB(255 255 255) RGB(245 245 245)),$
ENDSTYLE
END

Thank you. It worked!