Is it not possible to run an Excel BYTOC and OPEN/CLOSE procedure together?

I have two reports that I would like to present as a single workbook. The first uses BYTOC to burst multi tabs based on websites and the second is an overall total of the previous tabs but retaining the full detail of the total tab and not rolling to a single line.

I'm attempting to use the following format lines at the end of the two FEXs respectively:

ON TABLE PCHOLD FORMAT EXL2K BYTOC OPEN
ON TABLE PCHOLD FORMAT EXL2K BYTOC CLOSE

If I take out the 'BYTOC' it works as desired, but I only get two tabs instead of one tab per website from the first FEX.

This message has been edited. Last edited by: Kerry,

Since posting I've been able to find some older posts with similar problems. At the time they were stating that BYTOC couldn't be used on a COMPOUND call, but it does seem to work if it is the final portion of the call.

In other words BYTOC OPEN will ignore the next call, but BYTOC CLOSE works fine.

If you want to use a "compound" report with a "bytoc" report, you must start with the "compound" report first (don't use the close portion) and follow it with the "bytoc report. See the example below.

TABLE FILE CAR
SUM MODEL
BY CAR
BY MODEL NOPRINT
ON TABLE SET STYLE *
TYPE=REPORT,
   TITLETEXT='MODELS BY CAR',
$
ENDSTYLE
ON TABLE PCHOLD FORMAT EXL2K OPEN
END
-*
TABLE FILE CAR
SUM CAR
BY COUNTRY
BY CAR NOPRINT
BY MODEL NOPRINT
ON TABLE SET STYLE *
TYPE=REPORT,
   TITLETEXT='CARS BY COUNTRY',
$
ENDSTYLE
ON TABLE PCHOLD FORMAT EXL2K
END
-*
TABLE FILE CAR
PRINT CAR
      MODEL
      BODYTYPE 
BY COUNTRY NOPRINT
ON TABLE PCHOLD FORMAT EXL2K BYTOC
END

one more example

SET COMPOUND = ON
TABLE FILE EMPLOYEE
BY FIRST_NAME
BY SALARY
ON TABLE PCHOLD FORMAT EXL2K OPEN
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TYPE=REPORT,TITLETEXT='SUMMARY REPORT',
UNITS=IN,
SQUEEZE=ON,
ORIENTATION=LANDSCAPE,
$
ENDSTYLE
END
TABLE FILE EMPLOYEE
PRINT
EMP_ID
CURR_SAL
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
UNITS=IN,
SQUEEZE=ON,
ORIENTATION=LANDSCAPE,
$
ENDSTYLE
END
TABLE FILE EMPLOYEE
PRINT
FIRST_NAME
LAST_NAME
COMPUTE COUNTER/I7 = COUNTER+1; NOPRINT
COMPUTE WORKSHEET/I2=COUNTER/65000; NOPRINT
COMPUTE TITLESHEET/A40='SAMPLE' | EDIT(WORKSHEET) ; NOPRINT
BY TOTAL TITLESHEET NOPRINT
ON TABLE PCHOLD FORMAT EXL2K BYTOC CLOSE
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
FONT='ARIAL',
SIZE=10,
$
ENDSTYLE
END