Hi All,

Am trying to create a master file and then updating the file through a launch page.

The code am using to create a master file is:

 

APP HOLDDATA XYZ
APP HOLDMETA XYZ

DEFINE FILE EMPDATA
ID/A20 = ' ';
PYRAMID/A20 = ' ';
CATEGORY/A50 = ' ';
PROJECT/A50 = ' ';
REPORT/A50 = ' ';
ACTIVITY/A20 = ' ';
WEEK_END_DT/A20 = ' ';
SUNDAY/A10 = ' ';
MONDAY/A10 = ' ';
TUESDAY/A10 = ' ';
WEDNESDAY/A10 = ' ';
THURSDAY/A10 = ' ';
FRIDAY/A10 = ' ';
SATURDAY/A10 = ' ';

END

TABLE FILE EMPDATA
PRINT
ID
PYRAMID
CATEGORY
PROJECT
REPORT
ACTIVITY
WEEK_END_DT
SUNDAY
MONDAY
TUESDAY
WEDNESDAY
THURSDAY
FRIDAY
SATURDAY
WHERE PIN = 'A'
ON TABLE HOLD AS TIME_SHT FORMAT FOCUS INDEX ID
END
 

The below code is used to read the values from the launch page and then update into the file

 -*********FEX TO UPDATE TABLE TIME_TBL*********************************
-****************************************************************************
-SET &ECHO = ALL;
-SET &COUNTER = 1;
-SET &COUNTER2 = 1;
-SET &PYR='HR';
-SET &WK_ED_DT='12312009';
-SET &CAT = 'CAT';
-SET &PRJ = 'PRJ';
-SET &RPT = 'RPT';
-SET &ACT = 'ACT';
-SET &SUN = 'SUN';
-SET &MON = 'MON';
-SET &TUE = 'TUE';
-SET &WED = 'WED';
-SET &THU = 'THU';
-SET &FRI = 'FRI';
-SET &SAT = 'SAT';




-*******DATA
-REPEAT MY_LOOP FOR &COUNTER FROM 1 TO 3;
-*&RPT_COUNT;

-SET &PYRAMID = 'AB';
-SET &CATEGORY  = &CAT.&COUNTER;
-SET &PROJECT = &PRJ.&COUNTER;
-SET &REPORT = &RPT.&COUNTER;
-SET &ACTIVITY  = &ACT.&COUNTER;
-SET &WEEK_END_DT = &WK_ED_DT;
-SET &SUNDAY  = &SUN.&COUNTER;
-SET &MONDAY=&MON.&COUNTER;
-SET &TUESDAY=&TUE.&COUNTER;
-SET &WEDNESDAY=&WED.&COUNTER;
-SET &THURSDAY=&THU.&COUNTER;
-SET &FRIDAY=&FRI.&COUNTER;
-SET &SATURDAY=&SAT.&COUNTER;

-SET &ID = 'AB'|'&WK_ED_DT.EVAL'|'&COUNTER.EVAL';
-*-SET &ID = '12';
-TYPE &ID


-SET &TIME_DATA1.&COUNTER2 = 'ID=&ID.EVAL, PYRAMID=&PYR.EVAL, CATEGORY=&CATEGORY.EVAL, PROJECT=&PROJECT.EVAL, REPORT=&REPORT.EVAL, ACTIVITY =&ACTIVITY.EVAL, WEEK_END_DT=&WEEK_END_DT.EVAL, SUNDAY=&SUNDAY.EVAL,';

-SET &TIME_DATA2.&COUNTER2 = ' MONDAY = &MONDAY.EVAL, TUESDAY = &TUESDAY.EVAL,WEDNESDAY = &WEDNESDAY.EVAL, THURSDAY=&THURSDAY.EVAL, FRIDAY=&FRIDAY.EVAL, SATURDAY=&SATURDAY.EVAL,$' ;
-TYPE &TIME_DATA1.&COUNTER2 &TIME_DATA2.&COUNTER2

MODIFY FILE TIME_SHT
FREEFORM  ID PYRAMID CATEGORY PROJECT REPORT ACTIVITY WEEK_END_DT SUNDAY MONDAY TUESDAY WEDNESDAY THURSDAY FRIDAY SATURDAY
MATCH  ID
ON MATCH  UPDATE  PYRAMID CATEGORY PROJECT REPORT ACTIVITY WEEK_END_DT SUNDAY MONDAY TUESDAY WEDNESDAY THURSDAY FRIDAY SATURDAY
DATA
&TIME_DATA1.&COUNTER2
&TIME_DATA2.&COUNTER2
ON NOMATCH INCLUDE
DATA
&TIME_DATA1.&COUNTER2 &TIME_DATA2.&COUNTER2
END

-SET &COUNTER2=&COUNTER2 +1;
-MY_LOOP
-EXIT
 

but when updating the table i get an error as
(FOC415)TRANS 1 REJECTED NOMATCH SEG01

could anybody help me on this .. y am getting this error... and how can i overcome it?

Thanks in advance

This message has been edited. Last edited by: Kerry,

Two things are wrong with this procedure.
First is that you will also get a foclist in your new time_sht file. You don't want that, because it is automatically part of the key - which you do not supply.
You get rid of the foclist field when you do a SUM and a BY ID in the first table request.
Second is the syntax of the modify which is wrong.
You can have only ONE data statement.
It should read:

MODIFY FILE TIME_SHT
FREEFORM ID PYRAMID CATEGORY PROJECT REPORT ACTIVITY WEEK_END_DT SUNDAY MONDAY TUESDAY WEDNESDAY THURSDAY FRIDAY SATURDAY
MATCH ID
ON MATCH UPDATE PYRAMID CATEGORY PROJECT REPORT ACTIVITY WEEK_END_DT SUNDAY MONDAY TUESDAY WEDNESDAY THURSDAY FRIDAY SATURDAY
ON NOMATCH INCLUDE
DATA
&TIME_DATA1.&COUNTER2 &TIME_DATA2.&COUNTER2
END

Hope this helps ...

quote:

MODIFY FILE TIME_SHT
FREEFORM ID PYRAMID CATEGORY PROJECT REPORT ACTIVITY WEEK_END_DT SUNDAY MONDAY TUESDAY WEDNESDAY THURSDAY FRIDAY SATURDAY
MATCH ID
ON MATCH UPDATE PYRAMID CATEGORY PROJECT REPORT ACTIVITY WEEK_END_DT SUNDAY MONDAY TUESDAY WEDNESDAY THURSDAY FRIDAY SATURDAY
DATA
&TIME_DATA1.&COUNTER2
&TIME_DATA2.&COUNTER2
ON NOMATCH INCLUDE
DATA
&TIME_DATA1.&COUNTER2 &TIME_DATA2.&COUNTER2
END

You can only use 1 DATA statement in your MODIFY

MODIFY FILE TIME_SHT
FREEFORM  ID PYRAMID CATEGORY PROJECT REPORT ACTIVITY WEEK_END_DT SUNDAY MONDAY TUESDAY WEDNESDAY THURSDAY FRIDAY SATURDAY
MATCH  ID
ON MATCH  UPDATE  PYRAMID CATEGORY PROJECT REPORT ACTIVITY WEEK_END_DT SUNDAY MONDAY TUESDAY WEDNESDAY THURSDAY FRIDAY SATURDAY
ON NOMATCH INCLUDE
DATA
&TIME_DATA1.&COUNTER2
&TIME_DATA2.&COUNTER2
END
  

Start by writing the modify correctly and you may get somewhere.

Thank you very much for the quick response.
It's working fine now