January 14, 2005, 12:32 PM
<NIVAS>Formatting in Excel
Hi all,
I am trying to count country in a sub-foot section.It works fine in HTML but not excel.Please help me with this
Here is the sample code by using car file
SET BYDISPLAY=ON
DEFINE FILE CAR
AMPER/A1 WITH COUNTRY = HEXBYT(38, AMPER);
SEMI/A1 WITH COUNTRY = HEXBYT(59, SEMI);
NBSP/A6 WITH COUNTRY = AMPER | 'nbsp' | SEMI;
GAP/A36 WITH COUNTRY = NBSP|NBSP|NBSP|NBSP|NBSP|NBSP;
END
TABLE FILE CAR
PRINT CAR RCOST DCOST
BY COUNTRY
ON COUNTRY SUBFOOT
"*TOTAL <ST.CNT.COUNTRY<GAP<GAP<GAP<GAP<GAP<GAP<ST.RCOST<GAP<GAP<GAP<GAP<ST.DCOST"
ON TABLE PCHOLD FORMAT EXL2K
END
January 18, 2005, 03:42 PM
reFOCUSingGive this code a spin:
SET BYDISPLAY=ON
TABLE FILE CAR
PRINT CAR RCOST DCOST
BY COUNTRY
ON COUNTRY SUBFOOT
"*TOTAL<ST.CNT.COUNTRY<ST.RCOST<ST.DCOST"
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
UNITS=IN,LEFTMARGIN=0.000000,RIGHTMARGIN=0.000000,
TOPMARGIN=0.000000,BOTTOMMARGIN=0.000000,$
PAGESIZE='LETTER',ORIENTATION=PORTRAIT,$
TYPE=REPORT,GRID=OFF,SIZE=8,SQUEEZE=ON,FONT='ARIAL',$
TYPE=SUBFOOT,HEADALIGN=BODY,$
TYPE=SUBFOOT,BY=1,LINE=1,ITEM=2,JUSTIFY=RIGHT,STYLE=BOLD,$
TYPE=SUBFOOT,BY=1,LINE=1,ITEM=3,JUSTIFY=RIGHT,STYLE=BOLD,$
TYPE=SUBFOOT,BY=1,LINE=1,ITEM=4,JUSTIFY=RIGHT,STYLE=BOLD,$
ENDSTYLE
END
The headalign line is what does it this should work in html but you will not be able to use this in pdf format.
If you want to do this in pdf try the following:
SET BYDISPLAY=ON
TABLE FILE CAR
PRINT CAR RCOST DCOST
BY COUNTRY
ON COUNTRY SUBFOOT
"*TOTAL<ST.CNT.COUNTRY<ST.RCOST<ST.DCOST"
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
UNITS=IN,LEFTMARGIN=0.000000,RIGHTMARGIN=0.000000,
TOPMARGIN=0.000000,BOTTOMMARGIN=0.000000,$
PAGESIZE='LETTER',ORIENTATION=PORTRAIT,$
TYPE=REPORT,GRID=OFF,SIZE=8,SQUEEZE=ON,FONT='ARIAL',$
TYPE=SUBFOOT,BY=1,LINE=1,ITEM=2,JUSTIFY=RIGHT,STYLE=BOLD,POSITION=P2,$
TYPE=SUBFOOT,BY=1,LINE=1,ITEM=3,JUSTIFY=RIGHT,STYLE=BOLD,POSITION=P3,$
TYPE=SUBFOOT,BY=1,LINE=1,ITEM=4,JUSTIFY=RIGHT,STYLE=BOLD,POSITION=P4,$
ENDSTYLE
END
Hope this helps.