Hi to All
i have Some Problem in my Chart,iam using the combination of line and bar in a single chart.for the line values it is showing points on the bar(One Big Bar and lot of Line fields)but my requirement is no markers on the bars, i want to display only lines over the bar. is it possible to draw a line for each marker.



Thanks,
Kalyan

I hope I understood your requirement correct!
Find the highest and lowest value that would appear in the graph
Manully set the graph MAX scale/Min scale
If The value of line falls inside the bar value, set it to a value higher (or lower) and out of range of the graphic scale.
finally set Y1offscaledisplay to false to avoid showing lines/markers for the datapoints out side the scale.

eg.

-* Some dummy data for the graph with two lines and a bar
TABLE FILE CAR
PRINT
CAR NOPRINT
COMPUTE ROW1/I2 = ROW1 + 1;
COMPUTE LINE1/D10= IF ROW1 EQ 0 THEN 8 ELSE
IF ROW1 EQ 1 THEN 6 ELSE
IF ROW1 EQ 2 THEN 5 ELSE
IF ROW1 EQ 3 THEN 7 ELSE
IF ROW1 EQ 4 THEN 4 ELSE
IF ROW1 EQ 5 THEN 5 ELSE
IF ROW1 EQ 6 THEN 2 ELSE
IF ROW1 EQ 7 THEN 7 ELSE
IF ROW1 EQ 8 THEN 3 ELSE
IF ROW1 EQ 9 THEN 13 ELSE 10;
COMPUTE LINE2/D10= IF ROW1 EQ 0 THEN 9 ELSE
IF ROW1 EQ 1 THEN 7 ELSE
IF ROW1 EQ 2 THEN 6 ELSE
IF ROW1 EQ 3 THEN 8 ELSE
IF ROW1 EQ 4 THEN 5 ELSE
IF ROW1 EQ 5 THEN 6 ELSE
IF ROW1 EQ 6 THEN 3 ELSE
IF ROW1 EQ 7 THEN 8 ELSE
IF ROW1 EQ 8 THEN 4 ELSE
IF ROW1 EQ 9 THEN 14 ELSE 10;

COMPUTE BARVAL/D10= IF ROW1 EQ 0 THEN 7 ELSE
IF ROW1 EQ 1 THEN 10 ELSE
IF ROW1 EQ 2 THEN 4 ELSE
IF ROW1 EQ 3 THEN 9 ELSE
IF ROW1 EQ 4 THEN 4 ELSE
IF ROW1 EQ 5 THEN 5 ELSE
IF ROW1 EQ 6 THEN 2 ELSE
IF ROW1 EQ 7 THEN 1 ELSE
IF ROW1 EQ 8 THEN 3 ELSE
IF ROW1 EQ 9 THEN 12 ELSE 10;



WHERE RECORDLIMIT EQ '10';
ON TABLE HOLD AS HOLD1 FORMAT ALPHA
END
-RUN


TABLE FILE HOLD1
SUM
MAX.BARVAL
MAX.LINE1
MAX.LINE2
ON TABLE HOLD AS HIGHBAR FORMAT ALPHA
END
-RUN
-READ HIGHBAR &HIGHVAL1.D10. &HIGHVAL2.D10. &HIGHVAL3.D10.
-SET &HIGHVAL = IF &HIGHVAL2 GT &HIGHVAL1 THEN &HIGHVAL2 ELSE &HIGHVAL1;
-SET &HIGHVAL = IF &HIGHVAL3 GT &HIGHVAL THEN &HIGHVAL3 ELSE &HIGHVAL;

-SET &MAXSCALE= &HIGHVAL +2;
-RUN
DEFINE FILE HOLD1
-* If the value is less than bar value set the value to a high value out of the
-* graph range
NEW_LINE1/D10 = IF LINE1 GT BARVAL THEN LINE1 ELSE (2 * &HIGHVAL) + 1 ;
NEW_LINE2/D10 = IF LINE2 GT BARVAL THEN LINE2 ELSE (2 * &HIGHVAL) + 1 ;
END

GRAPH FILE HOLD1
SUM
LINE1
LINE2
BARVAL
BY ROW1
ON GRAPH SET LOOKGRAPH VBAR
ON GRAPH SET GRAPHEDIT SERVER
ON GRAPH SET BARNUMB OFF
ON GRAPH SET 3D OFF
ON GRAPH SET VZERO OFF
ON GRAPH SET GRID ON
ON GRAPH SET GRAPHSTYLE *
setSeriesType(0,2);
setSeriesType(1,2);
setMarkerDisplay(true);
END

GRAPH FILE HOLD1
SUM
NEW_LINE1
NEW_LINE2
BARVAL
BY ROW1
ON GRAPH SET LOOKGRAPH VBAR
ON GRAPH SET GRAPHEDIT SERVER
ON GRAPH SET BARNUMB OFF
ON GRAPH SET 3D OFF
ON GRAPH SET VZERO OFF
ON GRAPH SET GRID ON
ON GRAPH SET GRMERGE ON
ON GRAPH SET GRAPHSTYLE *
setSeriesType(0,2);
setSeriesType(1,2);
setMarkerDisplay(true);

setScaleMaxAuto(getY1Axis(),false);
setScaleMax(getY1Axis(),&MAXSCALE);
setY1OffScaleDisplay(false);

ENDSTYLE
END