We've been working on this one for too long! How many apostrophes do we need to wrap this string?

 

-SET &SystemGroup =  '('P397_1','P397_2','P397_4')';

This message has been edited. Last edited by: <Emily McAllister>,

The simple answer: two apostrophes per apostrophe per dialog manager command.

e.g.

-SET &SystemGroup = '(''P397_1'',''P397_2'',''P397_4'')';

or if the variable is EVALed later then.

-SET &SystemGroup = '(''''P397_1'''',''''P397_2'''',''''P397_4'''')';
-SET &SystemGroup2 = &SystemGroup.EVAL ;

Thanks Waz,

Here is what the final code looked like:

-SET &NA_Systems = '&SystemChoice.(<PRDM,PRDM>,<PRDZ,PRDZ>,<WADM,WADM>,<WADZ,WADZ>).System Group.';
-SET &SystemGroup1 =  IF &NA_Systems.EVAL EQ 'PRDZ' THEN '''(''''P397_1'''',''''P397_2'''',''''P397_4'''')'''
-                ELSE IF &NA_Systems.EVAL EQ 'PRDM' THEN '''(''''P397_1'''',''''P397_2'''')'''
-                ELSE IF &NA_Systems.EVAL EQ 'WADZ' THEN '''(''''W415_8'''',''''W415_9'''',''''W416_0'''')'''
-                ELSE IF &NA_Systems.EVAL EQ 'WADM' THEN '''(''''W415_8'''',''''W415_9'''')'''
-                ELSE 'Nope';
-SET &SystemGroup = &SystemGroup1.EVAL;
...
TABLE FILE NAT1F_JSATS
SUM
     MAX.NAT_PEAKLOCATION AS 'FIRSTDETECTION'
BY NAT_YEAR
BY NAT_PROJECT
BY NAT_TAGCODE
BY PINGSBACK
BY NAT_SYSTEM
BY JOIN_NPR
WHERE NAT_SYSTEM IN &SystemGroup.EVAL;
END
 

From what you have done, I would think you could remove one layer of EVAL and quotes.

quote:

you could remove one layer of EVAL and quotes.

Agreed, just use the following code with your other code unchanged -

-SET &NA_Systems = '&SystemChoice.(<PRDM,PRDM>,<PRDZ,PRDZ>,<WADM,WADM>,<WADZ,WADZ>).System Group.';
-SET &SystemGroup =  IF &NA_Systems.EVAL EQ 'PRDZ' THEN '(''P397_1'',''P397_2'',''P397_4'')'
-                ELSE IF &NA_Systems.EVAL EQ 'PRDM' THEN '(''P397_1'',''P397_2'')'
-                ELSE IF &NA_Systems.EVAL EQ 'WADZ' THEN '(''W415_8'',''W415_9'',''W416_0'')'
-                ELSE IF &NA_Systems.EVAL EQ 'WADM' THEN '(''W415_8'',''W415_9'')'
-                ELSE 'Nope';
-SET &SystemGroup = &SystemGroup.QUOTEDSTRING;

-TYPE &|SystemGroup = &SystemGroup

T

Excellent - I totally forgot about QUOTEDSTRING.

I will replace my code with your updates.