I am new to WebFocus, and am trying to emulate an existing report. I need to put a border around particular text in the header, which spans two lines. The border should go around the text (one border around both lines of text, rather than individual borders around each line of text), but not across the whole header, only around the text itself. Is this possible with WebFocus?

If your output is HTML you can use CSS to add borders.
An example CSS file:
/* ibi/apps/tests/styles.css: */

.border_top {
border-top : solid;
border-left : solid;
border-right : solid;
}
.border_mid {
border-left : solid;
border-right : solid;
}

.border_bot {
border-left : solid;
border-right : solid;
border-bottom: solid;
}

/*---------------------------------*/

And the example report:
SET CSSURL='/approot/tests/styles.css';
TABLE FILE CAR
ON TABLE SET PAGE-NUM OFF
ON TABLE SET HTMLCSS ON
HEADING
"This is line 1"
"This is line 2"
"This is line 3"
"This is line 4"
SUM SALES
BY COUNTRY
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF,$

TYPE=HEADING, LINE=2, CLASS='border_top',$
TYPE=HEADING, LINE=3, CLASS='border_bot',$

ENDSTYLE
END

Hope this helps
Grzegorz

Great technique for HTML. Does anyone have any ideas about how one might accomplish this with PFD format?

When the output format is PDF the formating is not such straightforward like for HTML, but there are possible tricks with invisible sort columns, HEADALING options, etc.

For example:

DEFINE FILE CAR
ONE/I1 = 1;
TWO/I1 = 2;
THREE/I1 = 3;
END

TABLE FILE CAR
ON TABLE SET PAGE-NUM OFF
ON TABLE PCHOLD FORMAT PDF
SUM SALES AS ''
BY ONE NOPRINT
BY TWO NOPRINT
BY THREE NOPRINT
BY COUNTRY AS ''
ON ONE SUBHEAD
"LINE 1"
ON TWO SUBHEAD
"BORDERED 1"
"BORDERED 2"
ON THREE SUBHEAD
"LINE 2"
""
" Country <+> Car "
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, STYLE=BOLD, SQUEEZE=ON, $
TYPE=SUBHEAD, BY=THREE, LINE=3, OBJECT=TEXT, ITEM=1, POSITION=P1,$
TYPE=SUBHEAD, BY=THREE, LINE=3, OBJECT=TEXT, ITEM=2, POSITION=P2,$
TYPE=SUBHEAD, BY=TWO, BORDER=MEDIUM,$
ENDSTYLE
END

Regards
Grzegorz