hello,
I want to create Drill down for Total column. While I was able to Drill down the Data from Report Canvas(GUI), I am not able to do it for Total as it is not drill-able. Suggest.
Regards,
nn

This message has been edited. Last edited by: <Emily McAllister>,

I guess the question would be why?

Usually a drilldown from a point is the data being diplayed. So you click on Ford and the drill down is a break down of all Fords. So clicking on the Total, where exactly do you go from there? If you just trying to get all information in the drilldown, the just add a button or link on the report that shows up in the header that states "show detail".

As Gavin said, it may not make sense to have a drill o the Total but it also be.

Here a solution for an ACROSS-TOTAL:

TABLE FILE CAR
SUM SEATS
BY COUNTRY
ACROSS CAR
ACROSS-TOTAL
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TYPE=DATA,
     ACROSSCOLUMN=SEATS, FOCEXEC=cntrydet(CTRY=COUNTRY),
     WHEN= SEATS NE 0,
$
ENDSTYLE
END

If you would like to drill from a ROW-TOTAL, Gavin solution can be one.
Otherwise below one is another:

TABLE FILE CAR
SUM SEATS
BY TOTAL COMPUTE ROWID  /D1  = 1;
BY COUNTRY
BY CAR
ON TABLE HOLD AS HLD1 FORMAT FOCUS
END
-RUN

TABLE FILE CAR
SUM SEATS
BY TOTAL COMPUTE ROWID  /D1  = 2;
BY TOTAL COMPUTE COUNTRY/A10 = 'TOTAL';
BY TOTAL COMPUTE CAR    /A16 = '';
ON TABLE HOLD AS HLD2 FORMAT FOCUS
END
-RUN

TABLE FILE HLD1
SUM SEATS
BY ROWID
BY COUNTRY
BY CAR
ON TABLE HOLD AS RPTDATA FORMAT FOCUS
MORE
FILE HLD2
END
-RUN

TABLE FILE RPTDATA
SUM SEATS
BY ROWID NOPRINT
BY COUNTRY
BY CAR
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TYPE=DATA,
     COLUMN=COUNTRY, FOCEXEC=cntrydet(CTRY=COUNTRY),
$
ENDSTYLE
END