I've recently received requirments for a graph that I'm not so sure is possible in Webfocus. A scatter or line graph could get me the data markers but I have no clue where to even begin to add the bars. Any suggestions would be appreciated.

Say we are looking at automobile sales. We have 20 sales for a month. 3 were Mini-Vans, 2 were cars and 15 were trucks. The graph would show Mini-Vans would show as a star on the graph, Cars would show as a plus, Trucks as a triangle, Total Sales as as circle. Simple line graph with no connecting lines or a scatter graph. But then there needs to be bar on the graph that runs between the low and high sales for the month. The lowest sales any salesman had was 1 and the highest sales any salesman had was 8. I need a bar between those 2 points on the graph. Something similiar to a candle stock chart. So basically I need to merge a scatter chart with a candle stock chart. Is it possible?

This message has been edited. Last edited by: Tamra,

Hi,
How about instead of using a BAR, color the entire region between 1 and 8?
Something like:

setDisplay(getY1AltFmtFrame(),true);
setAltFmtFrameSeparator(getY1AltFmtFrame(0),1.0);
setAltFmtFrameSeparator(getY1AltFmtFrame(1),8.0);
setFillColor(getY1AltFmtFrame(0),new Color(255,255,255,0));
setFillColor(getY1AltFmtFrame(1),new Color(255,0,0));
setFillColor(getY1AltFmtFrame(2),new Color(255,255,255,0));
setAltFmtFrameNumColors(getY1AltFmtFrame(),3);

This will color the region between 1 and 8 Red and make the regions below and above transparent.

This message has been edited. Last edited by: <nick z>,

That will actually work great for one of the graphs that only has 1 x-axis. Thanks. The other would be by month and the high low by month may change.

Hi,
What you can do is create a dual Y stack Line or BAR chart.
But for the 1st Y axis, you can show each series as a Line and disconnect the lines, so it will only show markers.
You can force each series to be absolute, so that it will not add them up.
For the second Y axis you can add 2 computed fields: 1 for low value and the second for high minus the low(otherwise it will add up low and high in a stack)
You can pass the parameters for the high and low.
Here is an example of what I did with a CAR file:

  
-SET &High_England=150000;
-SET &High_Italy=160000;
-SET &Low_England=10000;
-SET &Low_Italy=30000;

GRAPH FILE CAR
SUM CAR.BODY.SALES
CAR.BODY.RETAIL_COST
CAR.BODY.DEALER_COST
COMPUTE TOTAL_PER_COUNTRY/D12.2=CAR.BODY.DEALER_COST + CAR.BODY.RETAIL_COST + CAR.BODY.SALES ;
COMPUTE Low_for_Country/D12.2=IF COUNTRY EQ 'ENGLAND' THEN &Low_England ELSE IF COUNTRY EQ 'ITALY' THEN &Low_Italy ELSE 0;
COMPUTE High_for_Country/D12.2=IF COUNTRY EQ 'ENGLAND' THEN (&High_England - Low_for_Country) ELSE IF COUNTRY EQ 'ITALY' THEN (&High_Italy-Low_for_Country) ELSE 0 ;
BY CAR.ORIGIN.COUNTRY
WHERE COUNTRY EQ 'ENGLAND' OR 'ITALY'
ON GRAPH PCHOLD FORMAT PNG
ON GRAPH SET HTMLENCODE ON
ON GRAPH SET GRAPHDEFAULT OFF
ON GRAPH SET ARGRAPHENGIN JSCHART
ON GRAPH SET VZERO OFF
ON GRAPH SET GRMERGE ADVANCED
ON GRAPH SET GRMULTIGRAPH 0
ON GRAPH SET GRLEGEND 0
ON GRAPH SET GRXAXIS 1
ON GRAPH SET LOOKGRAPH VLINSTK2
ON GRAPH SET AUTOFIT ON
ON GRAPH SET STYLE *
*GRAPH_SCRIPT

setPieDepth(0);
setPieTilt(0);
setDepthRadius(0); 
setCurveFitEquationDisplay(false); 
setPlace(true); 
setUseSeriesShapes(true);
setMarkerSizeDefault(50); 

*END

*GRAPH_SCRIPT
setReportParsingErrors(false);
setSelectionEnableMove(false);
setConnectLineMarkers(false);
setSeriesType(4,1);
setFillColor(getSeries(4), new Color(227,136,0,0));
setScaleMaxAuto(getY1Axis(),false);
setScaleMax(getY1Axis(),240000.0);
setScaleMaxAuto(getY2Axis(),false);
setScaleMax(getY2Axis(),240000.0);
setFillColor(getSeries(5), new Color(255,0,0,107));
setSeriesType(5,1);
setAxisAssignment( $0, 0);
setAxisAssignment( $1, 0);
setAxisAssignment( $2, 0);
setAxisAssignment( $3, 0);
setAxisAssignment( $4, 1);
setAxisAssignment( $5, 1);
setForceSeriesAbsolute(getSeries(1),true);
setForceSeriesAbsolute(getSeries(0),true);
setForceSeriesAbsolute(getSeries(2),true);
setForceSeriesAbsolute(getSeries(3),true);
setBorderColor(getSeries(4),new Color(255,255,255,0));
setDisplay(getLegendArea(),false);
setMarkerShape(getSeries(0),13);
setMarkerShape(getSeries(1),4);
setMarkerShape(getSeries(2),6);
setMarkerShape(getSeries(3),2);
setDisplay(getY2Label(),false);
setToolTipDisplay(false);
*END
ENDSTYLE
END

-RUN

Please keep in mind that this will only work in PNG,JPG or SVG.
This technique will not work in JSCHART or Active formats.

Thanks.

I apologize that it's taken me this long to respond. I got side tracked with another issue. This is doing exactly what I need. Thank you so much for your help.