I'm using WebFOCUS 7.6.4.

I have a query that I am using a 5 line header at the top of the report, but declaring the values on that header elsewhere. For some reason, the final report only includes lines 1, 2 ,3, & 5 (4 is missing).

Does anyone know why this would happen?

My Code:

SET ASNAMES = ON

-SET &TODAY = DATECVT(&YYMD, 'I8YYMD', 'YYMD');

-SET &BACK30DAYS = &TODAY-30;

-SET &HEAD1 = '"'|'Proprietary Information'|'"';
-SET &HEAD2 = '"'|'Cycle Time Report'|'"';
-SET &HEAD3 = '"'|'Report Start Date: ' | EDIT (DATECVT ( &BACK30DAYS, 'YYMD' , 'I8MDYY' ) , '99/99/9999' );
-SET &HEAD4 = '"'|'Report End Date: ' | EDIT (DATECVT ( &TODAY, 'YYMD' , 'I8MDYY' ) , '99/99/9999' );
-SET &HEAD5 = '"'|'Date Prepared: ' | EDIT (DATECVT ( &TODAY, 'YYMD' , 'I8MDYY' ) , '99/99/9999' );

-*>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>

TABLE FILE BASELINE
PRINT
BASELINE.FIELD1
BASELINE.FIELD2
BASELINE.FIELD3
BASELINE.FIELD4

BY BASELINE.FIELD1 NOPRINT

ON TABLE SUBHEAD
&HEAD1.EVAL
&HEAD2.EVAL
&HEAD3.EVAL
&HEAD4.EVAL
&HEAD5.EVAL

ON TABLE SET STYLE *
TYPE=TITLE, COLOR=NAVY, STYLE=BOLD+UNDERLINE, $
TYPE=REPORT, TITLETEXT= 'CYCLE TIME', $
TYPE=TABHEADING,STYLE=BOLD,$
TYPE=SUBHEAD,STYLE=BOLD,$
TYPE=SUBFOOT,STYLE=BOLD,$
TYPE=TABFOOTING,STYLE=BOLD,$
ENDSTYLE

ON TABLE PCHOLD FORMAT EXL2K
END

Any help would be appreciated.

-CWM

CWM,

quote:

-SET &HEAD1 = '"'|'Proprietary Information'|'"';
-SET &HEAD2 = '"'|'Cycle Time Report'|'"';
-SET &HEAD3 = '"'|'Report Start Date: ' | EDIT (DATECVT ( &BACK30DAYS, 'YYMD' , 'I8MDYY' ) , '99/99/9999' );
-SET &HEAD4 = '"'|'Report End Date: ' | EDIT (DATECVT ( &TODAY, 'YYMD' , 'I8MDYY' ) , '99/99/9999' );
-SET &HEAD5 = '"'|'Date Prepared: ' | EDIT (DATECVT ( &TODAY, 'YYMD' , 'I8MDYY' ) , '99/99/9999' );

S/B

-SET &HEAD1 = '"'|'Proprietary Information'|'"';
-SET &HEAD2 = '"'|'Cycle Time Report'|'"';
-SET &HEAD3 = '"'|'Report Start Date: ' | EDIT (DATECVT ( &BACK30DAYS, 'YYMD' , 'I8MDYY' ) , '99/99/9999' ) | '"';
-SET &HEAD4 = '"'|'Report End Date: ' | EDIT (DATECVT ( &TODAY, 'YYMD' , 'I8MDYY' ) , '99/99/9999' ) | '"';
-SET &HEAD5 = '"'|'Date Prepared: ' | EDIT (DATECVT ( &TODAY, 'YYMD' , 'I8MDYY' ) , '99/99/9999' ) | '"';


At the top of your program add

-SET &ECHO=ALL;

and you will get error messages, if any...


Edit: Had the wrong code copied in and didn't see the missing double quotes at the end...
Tom

This message has been edited. Last edited by: Tom Flynn,

That worked!

Thank you.

My method (which is completely user preference) is to always use the double quotes for headings, footing, etc. and form the &var strings accordingly. - Helps me recognize my text lines because they always have the " marks.

So I would
-SET &HEAD1 = 'Proprietary Information';
-SET &HEAD2 = 'Cycle Time Report';
-SET &HEAD3 = 'Report Start Date: ' | EDIT (DATECVT ( &BACK30DAYS, 'YYMD' , 'I8MDYY' ) , '99/99/9999' );
-SET &HEAD4 = 'Report End Date: ' | EDIT (DATECVT ( &TODAY, 'YYMD' , 'I8MDYY' ) , '99/99/9999' );
-SET &HEAD5 = 'Date Prepared: ' | EDIT (DATECVT ( &TODAY, 'YYMD' , 'I8MDYY' ) , '99/99/9999' );

and then

ON TABLE SUBHEAD
"&HEAD1.EVAL"
"&HEAD2.EVAL"
"&HEAD3.EVAL"
"&HEAD4.EVAL"
"&HEAD5.EVAL"

This works best for me but when the heading/footing is always of fixed number of lines. However if the subhead can have variable lines based on some parameter, then I do include the " in the parameter string.

Darin

100% agree, but, sometimes I let automony take over...

CWM,

Instead of:
EDIT (DATECVT ( &TODAY, 'YYMD' , 'I8MDYY' ) , '99/99/9999' )
why no use:
&DATEMDYY?

Also, since your &HEADs do not contain DM commands, you don't need the .EVAL suffix.