I need some help from the gurus here to remove the blank line at the end of the report that opens up the box surrounding it. My code is given below.

-* File box_around_pdfreport.fex
-* Default Mode: Report FEX
-SET &ECHO=ALL;
TABLE FILE EDUCFILE
PRINT COURSE_CODE
BY EMP_ID
ON TABLE HOLD AS HOLD01
END
DEFINE FILE HOLD01
YCOURSE_CODE/I8 = EDIT(COURSE_CODE);
XCOURSE_CODE/D8c = YCOURSE_CODE;
WCOURSE_CODE/A8 = FTOA(XCOURSE_CODE, '(D8c)', 'A8');
ZCOURSE_CODE/A8 = LJUST(8, WCOURSE_CODE, 'A8');
CONCAT_COURSE/A200 = IF EMP_ID EQ LAST EMP_ID
THEN (SUBSTR(200, CONCAT_COURSE, 1, ARGLEN(200, CONCAT_COURSE, 'I4'), ARGLEN(200, CONCAT_COURSE, 'I4'), 'A190')
|| '-' || ZCOURSE_CODE) ELSE ZCOURSE_CODE;
END
TABLE FILE HOLD01
SUM CONCAT_COURSE AS 'Course'
BY EMP_ID AS 'Employee'
ON TABLE FOOTING
""
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL
ON TABLE SET ONLINE-FMT PDF
ON TABLE SET STYLE *
UNITS=IN, PAGESIZE='Letter', SQUEEZE=ON, ORIENTATION=PORTRAIT,
LEFTMARGIN=0.250000, RIGHTMARGIN=0.250000, TOPMARGIN=0.000000, BOTTOMMARGIN=0.000000, $

TYPE=REPORT, GRID=OFF, WRAP=OFF, FONT='TIMES NEW ROMAN', SIZE=10, COLOR='BLACK', BACKCOLOR='NONE', STYLE=NORMAL, $

TYPE=TITLE, BORDER=LIGHT, STYLE=-UNDERLINE+BOLD+ITALIC, $

TYPE=DATA, BORDER-LEFT=LIGHT, BORDER-RIGHT=LIGHT, FONT='ARIAL', SIZE=8, $

TYPE=FOOTING, BORDER-TOP=LIGHT, $
END

I tried to do the same thing but had the same results as you do. The solution provided from IBI was the work around I posted before. I agree that it should be fixed in the product but that takes longer...maybe version 7 will do the footer right under the data.

Note: I did try to set TOPGAP=0 and that did work on my local machine but not on the server. You could try that at your site.

Jayem Nolan

Just a thought:

TABLE FILE EDUCFILE
PRINT COURSE_CODE
BY EMP_ID
ON TABLE HOLD AS HOLD01
END
-RUN
-SET &TOT_LINES = &LINES;
DEFINE FILE HOLD01
YCOURSE_CODE/I8 = EDIT(COURSE_CODE);
XCOURSE_CODE/D8c = YCOURSE_CODE;
WCOURSE_CODE/A8 = FTOA(XCOURSE_CODE, '(D8c)', 'A8');
ZCOURSE_CODE/A8 = LJUST(8, WCOURSE_CODE, 'A8');
CONCAT_COURSE/A200 = IF EMP_ID EQ LAST EMP_ID
THEN (SUBSTR(200, CONCAT_COURSE, 1, ARGLEN(200, CONCAT_COURSE, 'I4'), ARGLEN(200, CONCAT_COURSE, 'I4'), 'A190')
|| '-' || ZCOURSE_CODE) ELSE ZCOURSE_CODE;
D_CTR/I5 = LAST D_CTR + 1;
END
TABLE FILE HOLD01
SUM
CONCAT_COURSE AS 'Course'
MAX.D_CTR NOPRINT

BY
EMP_ID AS 'Employee'
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL
ON TABLE SET ONLINE-FMT PDF
ON TABLE SET STYLE *
UNITS=IN,
PAGESIZE='Letter',
LEFTMARGIN=0.250000,
RIGHTMARGIN=0.250000,
TOPMARGIN=0.000000,
BOTTOMMARGIN=0.000000,
SQUEEZE=ON,
ORIENTATION=PORTRAIT,
$
DEFMACRO=COND0001,
MACTYPE=RULE,
RIGHTGAP=0.125000,
WHEN=N3 EQ &TOT_LINES,
$
TYPE=REPORT,
FONT='TIMES NEW ROMAN',
SIZE=10,
COLOR='BLACK',
BACKCOLOR='NONE',
STYLE=NORMAL,
RIGHTGAP=0.125000,
$
TYPE=DATA,
BORDER-LEFT=LIGHT,
BORDER-RIGHT=LIGHT,
FONT='ARIAL',
SIZE=8,
$
TYPE=DATA,
COLUMN=N1,
BORDER-BOTTOM=LIGHT,
MACRO=COND0001,
$
TYPE=DATA,
COLUMN=N2,
BORDER-BOTTOM=LIGHT,
MACRO=COND0001,
$
TYPE=TITLE,
BORDER=LIGHT,
STYLE=-UNDERLINE+BOLD+ITALIC,
$
TYPE=FOOTING,
BORDER-TOP=LIGHT,
$
ENDSTYLE
END