I apologize if this gets posted twice.........

The following code is an example of stylesheet information that works in HTML but not in EXL2K.

I've tried several fixes but can't get the computed row totals to show up the same in EXCEL.

  

TABLE FILE CAR
SUM
DEALER_COST
DEALER_COST AS 'DC'
BY COUNTRY
BY CAR
ON TABLE SET ASNAMES ON
ON TABLE HOLD AS SUMCAR
END
-RUN

TABLE FILE SUMCAR
SUM
     'SUMCAR.SUMCAR.DC' NOPRINT
     'MAX.SUMCAR.SUMCAR.DEALER_COST' NOPRINT
     'MIN.SUMCAR.SUMCAR.DEALER_COST' NOPRINT
     COMPUTE MAX/D20 = MAX.DEALER_COST; NOPRINT
     COMPUTE MIN/D20 = MIN.DEALER_COST; NOPRINT
BY 'SUMCAR.SUMCAR.COUNTRY' AS 'Country'
SUM
     'SUMCAR.SUMCAR.DEALER_COST' AS ' '
BY 'SUMCAR.SUMCAR.COUNTRY' AS 'Country'
ACROSS 'SUMCAR.SUMCAR.CAR'
     COMPUTE
          MAX/D20 = MAX;
     COMPUTE
          MIN/D20 = MIN;
     COMPUTE
          TOTL/D20 = DC;
ON TABLE SET NODATA ' '
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     UNITS=IN,
     LEFTMARGIN=0.180556,
     RIGHTMARGIN=0.000000,
     TOPMARGIN=0.055556,
     BOTTOMMARGIN=0.055556,
     SQUEEZE=ON,
     ORIENTATION=LANDSCAPE,
$
TYPE=REPORT,
     GRID=OFF,
     FONT='TIMES NEW ROMAN',
     SIZE=10,
$
TYPE=DATA,
     SIZE=8,
     COLOR='BLUE',
     BACKCOLOR=( RGB(234 234 255) 'WHITE' ),
$
TYPE=TITLE,
     SIZE=9,
     COLOR='BLUE',
     STYLE=BOLD,
$
TYPE=HEADING,
     SIZE=8,
     COLOR='NAVY',
     BACKCOLOR=RGB(147 172 219),
     STYLE=BOLD,
$
TYPE=ACROSSVALUE,
     SIZE=8,
     COLOR='BLUE',
     STYLE=BOLD,
$
TYPE=ACROSSTITLE,
     SIZE=8,
     COLOR='BLUE',
     STYLE=BOLD,
     JUSTIFY=CENTER,
$
ENDSTYLE
END
-RUN

This message has been edited. Last edited by: Kerry,

I have reported styling problems with ACROSS in EXL2K reports for v7.6.5 and was told it was fixed in v7.6.9.

Here's one suggestion on resolving your issue - use the SEQUENCE stylesheet command to move the MIN, MAX, TOTL to end of the ACROSS columns, but have them calculated before the ACROSS:

-* File fpsrc1.fex

TABLE FILE CAR
SUM
DEALER_COST
DEALER_COST AS 'DC'
BY COUNTRY
BY CAR
ON TABLE SET ASNAMES ON
ON TABLE HOLD AS SUMCAR
END
-RUN

TABLE FILE SUMCAR
SUM
     'SUMCAR.SUMCAR.DC' NOPRINT
     'MAX.SUMCAR.SUMCAR.DEALER_COST' NOPRINT
     'MIN.SUMCAR.SUMCAR.DEALER_COST' NOPRINT
     COMPUTE MAX/D20 = MAX.DEALER_COST; 
     COMPUTE MIN/D20 = MIN.DEALER_COST; 
	 COMPUTE TOTL/D20 = SUMCAR.SUMCAR.DC;
BY 'SUMCAR.SUMCAR.COUNTRY' AS 'Country'
SUM
     'SUMCAR.SUMCAR.DEALER_COST' AS ' '
BY 'SUMCAR.SUMCAR.COUNTRY' AS 'Country'
ACROSS 'SUMCAR.SUMCAR.CAR' 

ON TABLE SET NODATA ' '
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     UNITS=IN,
     LEFTMARGIN=0.180556,
     RIGHTMARGIN=0.000000,
     TOPMARGIN=0.055556,
     BOTTOMMARGIN=0.055556,
     SQUEEZE=ON,
     ORIENTATION=LANDSCAPE,
$
TYPE=REPORT,
     GRID=OFF,
     FONT='TIMES NEW ROMAN',
     SIZE=10,
$
TYPE=DATA,
     SIZE=8,
     COLOR='BLUE',
     BACKCOLOR=( RGB(234 234 255) 'WHITE' ),
$
TYPE=TITLE,
     SIZE=9,
     COLOR='BLUE',
     STYLE=BOLD,
$
TYPE=HEADING,
     SIZE=8,
     COLOR='NAVY',
     BACKCOLOR=RGB(147 172 219),
     STYLE=BOLD,
$
TYPE=ACROSSVALUE,
     SIZE=8,
     COLOR='BLUE',
     STYLE=BOLD,
$
TYPE=ACROSSTITLE,
     SIZE=8,
     COLOR='BLUE',
     STYLE=BOLD,
     JUSTIFY=CENTER,
$
TYPE=REPORT, COLUMN=MAX, SEQUENCE=100, $
TYPE=REPORT, COLUMN=MIN, SEQUENCE=101, $
TYPE=REPORT, COLUMN=TOTL, SEQUENCE=102, $

ENDSTYLE
END
-RUN

I used the code changes Francis suggested and it did work.

Also, I found the adding a grandtotal (ON TABLE SUBTOTAL) and that also made the formatting in Excel look just like the HTML stylesheet formatting. Don't know why but it works.

So for now, this issue is resolved.

Thanks........Steve

If you don't want a grand total, I wonder what

ON TABLE SUBTOTAL
ON TABLE NOTOTAL

would do?