Hello

I have a compound AHTML report which has 5 reports. 1st report has only header and remaining 4 are active reports and active graphs. I am having an issue with the first report as there is an arrow (options menu) coming up even when there are no fields displayed except heading. Can anyone please suggest removing it? (Its under MODEL in 1st report)

 
COMPOUND LAYOUT PCHOLD AS 'Car Details'  FORMAT AHTML
SECTION=Section_1, LAYOUT=ON, PAGESIZE=E, ORIENTATION=PORTRAIT, SHOW_GLOBALFILTER=OFF, ACTIVE_UNITS=PTS, PAGECOLOR=RGB(255 255 255), $
PAGELAYOUT=1, NAME='Car Details', TEXT='Car Details', LEFTMARGIN=0.25, RIGHTMARGIN=0.25, TOPMARGIN=-0.1, BOTTOMMARGIN=0.25, $
COMPONENT=REP1, COMPONENT-TYPE=REPORT, POSITION=(5.45 2.15), DIMENSION=(9.0 4.0), ARREPORTSIZE=DIMENSION, METADATA='VERSION:1.0;COMPONENTS_INCLUDED:TRANS,MONTH', $
COMPONENT=REP2, COMPONENT-TYPE=REPORT, POSITION=(5.45 4.15), DIMENSION=(9.0 4.0), ARREPORTSIZE=DIMENSION, METADATA='VERSION:1.0;COMPONENTS_INCLUDED:TRANS,MONTH', $
END

SET COMPONENT=REP1
TABLE FILE CAR
BY  COUNTRY NOPRINT
HEADING
"CAR FILE DETAILS"
"COUNTRY "
"MODEL"
WHERE RECORDLIMIT EQ 1
ON TABLE PCHOLD FORMAT AHTML
ON TABLE SET HTMLEMBEDIMG ON
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     INCLUDE = IBFS:/EDA/EDASERVE/_EDAHOME/ETC/warm.sty,$
TYPE=REPORT, OBJECT=STATUS-AREA, PAGE-LOCATION=OFF,$
ENDSTYLE
END
-RUN

SET COMPONENT=REP2
TABLE FILE CAR
PRINT
	COUNTRY
ON TABLE PCHOLD FORMAT AHTML
ON TABLE SET HTMLEMBEDIMG ON
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     INCLUDE = IBFS:/EDA/EDASERVE/_EDAHOME/ETC/warm.sty,$
TYPE=REPORT, OBJECT=STATUS-AREA, PAGE-LOCATION=OFF,$
ENDSTYLE
END
-RUN
COMPOUND END 

Thank you.

This message has been edited. Last edited by: WebFOCUS_Dev,

The only way I've been able to deal with that problem is to hide the down arrow by making it the same color as the background. So if your background color is white, you can use this syntax to make the arrow white to make it invisible.

  
TYPE=REPORT, ARICONSET=WHITE,$

Are you inserting an existing report or creating the report in the document? Try creating a separate .STY file with this code in it and only apply that .STY to the specific report you want to hide.

When I implement this in my actual report which has multiple active graphs and report, its not working. Option menu from other reports are also changed to white color.
I am creating new reports inside the compound report, not including existing reports. Also, I tried adding a new STY for that report but still did not work.

Can anyone suggest on this issue?
Thank you.

If your first report seems to just display a HEADING (report title), why not include a text box in your compound instead of a report ?
And no need to have it as static text, may be a variable.

-SET &TITLE_4 = 'Fourth Line In Title';
SET HTMLARCHIVE=ON
*-HOLD_SOURCE
COMPOUND LAYOUT PCHOLD FORMAT AHTML
UNITS=IN, $
SECTION=section1, LAYOUT=ON, METADATA='prop_with_names^Margins_Left=0.5^Margins_Top=0.5^Margins_Right=0.5^Margins_Bottom=0.5^thumbnailscale=4', MERGE=OFF, ORIENTATION=PORTRAIT, PAGESIZE=Letter, SHOW_GLOBALFILTER=OFF, ARGRAPHENGINE=JSCHART, ACTIVE_UNITS=PTS, $
PAGELAYOUT=1, NAME='Page layout 1', text='Page layout 1', TOC-LEVEL=1, BOTTOMMARGIN=0.5, TOPMARGIN=0.5, METADATA='BOTTOMMARGIN=0.5,TOPMARGIN=0.5,LEFTMARGIN=0,RIGHTMARGIN=0,', $
OBJECT=STRING, NAME='text1', TEXT='<center>Car File Detail<br>Country<br>Model<br>&TITLE_4</center>', POSITION=(0.708 0.521), MARKUP=ON, WRAP=ON, DIMENSION=(7.500 0.613), font='TREBUCHET MS', color=RGB(0 0 0),  size=10, METADATA='left: 0.708in; top: 0.521in; width: 7.5in; height: 0.613in; text-align: center; color: rgb(0, 0, 0); font-family: TREBUCHET MS; font-size: 10pt; position: absolute; z-index: 1; -ms-word-wrap: break-word;', $
COMPONENT='report1', TEXT='report1', TOC-LEVEL=2, POSITION=(0.813 1.250), DIMENSION=(2.867 2.652), BYTOC=0,  ARREPORTSIZE=DIMENSION, METADATA='left: 0.813in; top: 1.25in; width: 2.867in; height: 2.652in; position: absolute; z-index: 2;', $
COMPONENT='report2', TEXT='report2', TOC-LEVEL=2, POSITION=(4.042 1.250), DIMENSION=(3.750 3.692), BYTOC=0,  ARREPORTSIZE=DIMENSION, METADATA='left: 4.042in; top: 1.25in; width: 3.75in; height: 3.692in; position: absolute; z-index: 3;', $
END
SET COMPONENT='report1'
-*component_type report
TABLE FILE CAR
PRINT COUNTRY
ON TABLE PCHOLD FORMAT AHTML
ON TABLE SET HTMLEMBEDIMG ON
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     INCLUDE = IBFS:/EDA/EDASERVE/_EDAHOME/ETC/warm.sty,$
TYPE=REPORT, OBJECT=STATUS-AREA, PAGE-LOCATION=OFF,$
ENDSTYLE
END
SET COMPONENT='report2'
-*component_type report
TABLE FILE CAR
PRINT CAR
ON TABLE PCHOLD FORMAT AHTML
ON TABLE SET HTMLEMBEDIMG ON
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     INCLUDE = IBFS:/EDA/EDASERVE/_EDAHOME/ETC/warm.sty,$
TYPE=REPORT, OBJECT=STATUS-AREA, PAGE-LOCATION=OFF,$
ENDSTYLE
END
COMPOUND END

Thanks Martin. I think I will go ahead with this.