When I add an average line after grand total, it drops off grand total line. Can someone help me to add average line right below grand total line? I want to have RECOMPUTE by sort break and then grand total and average.

SET SUMMARYLINES=EXPLICIT

TABLE FILE MOVIES
PRINT
COPIES
LISTPR
WHOLESALEPR
COMPUTE AVGPR/F6.2 = LISTPR / COPIES;
DIRECTOR

BY RATING
BY CATEGORY

ON RATING RECOMPUTE
ON TABLE SUMMARIZE AS 'Grand Total'
-*ON TABLE SUBTOTAL
-* AVE. LISTPR
-* AVE. WHOLESALEPR AS 'AVE'
END

Thank you,

This message has been edited. Last edited by: Kerry,

JJ,

Maybe something like this ?

SET SUMMARYLINES=EXPLICIT 

TABLE FILE MOVIES
PRINT
COPIES
LISTPR
WHOLESALEPR
COMPUTE AVGPR/F6.2 = LISTPR / COPIES;
DIRECTOR

BY RATING
BY CATEGORY
WHERE RATING IN ('G','PG13');

ON RATING RECOMPUTE

ON TABLE SUMMARIZE AS 'Grand Total'
ON TABLE RECOMPUTE 
ON TABLE SUBFOOT
"Average<+0> <+0> <AVE.LISTPR  <AVE.WHOLESALEPR <+0>"
ON TABLE SET STYLE *
TYPE=TABFOOTING ,HEADALIGN=BODY ,JUSTIFY=RIGHT ,$
TYPE=TABFOOTING ,HEADALIGN=BODY ,OBJECT=TEXT, JUSTIFY=LEFT ,$
END

FreSte,
Thank you for the quick reply. It is the way I wanted to display average but if you look at the two averages(29.98 and 19.99) are not the actual average values. Any ideas?

Thanks again,

Then I would suggest you calculate the right values as a computed field and put those in the subfoot

SET SUMMARYLINES=EXPLICIT 

TABLE FILE MOVIES
PRINT
COPIES
LISTPR
WHOLESALEPR
COMPUTE AVGPR/F6.2 = LISTPR / COPIES;
COMPUTE AVG1/D12.2 = TOT.LISTPR/TOT.COPIES; NOPRINT
COMPUTE AVG2/D12.2 = TOT.WHOLESALEPR/TOT.COPIES; NOPRINT
DIRECTOR

BY RATING
BY CATEGORY
WHERE RATING IN ('G','PG13');

ON RATING RECOMPUTE

ON TABLE SUMMARIZE AS 'Grand Total'
ON TABLE RECOMPUTE 
ON TABLE SUBFOOT
"Average<+0> <+0> <AVG1<AVG2  <+0> <+0>"
ON TABLE SET STYLE *
TYPE=TABFOOTING ,HEADALIGN=BODY ,JUSTIFY=RIGHT ,$
TYPE=TABFOOTING ,HEADALIGN=BODY ,OBJECT=TEXT, JUSTIFY=LEFT ,$
END

FreSte - Thank you.