[SHARING] POPUPDESC options

March 08, 2010, 03:58 PM

What, if any, options are there with "POPUPDESC"?

1) I'd like to change the backcolor...
2) I'd like it to work with COMPUTEd and DEFINEd fields.

I know it works off the DESCRIPTION in the MFD... So, where do I go from here?

Thanks In Advance...

This message has been edited. Last edited by: Kerry,

March 08, 2010, 04:43 PM

Francis Mariani

It appears it isn't as easy as DRILLMENUITEM Styling.

The WebFOCUS file to modify is C:\ibi\WebFOCUS76\ibi_html\javaassist\ibi\html\js\ibipopupdesc.js.

The code is:

<TABLE WIDTH=200 BORDER=1 BORDERCOLOR=black CELLPADDING=2 CELLSPACING=0 "+
    "BGCOLOR=#ECD1F8><TD><FONT COLOR=black SIZE=2>

Unfortunately CSS classes are not used here, seems like a cheesy, non-21st century way to do things, but you could change the font and background color here (make a backup).

March 09, 2010, 05:06 AM

<JG>

quote:
2) I'd like it to work with COMPUTEd and DEFINEd fields.

That's not possible.

There are several open NFR's specifically for that.

The only way to do that at the moment is to have either an alternate master that you
reallocate the the file to use, or to dynamically rewrite the master as needed.

March 09, 2010, 09:12 AM

Doug

This is all so very interesting... I've found that if WebFOCUS cannot do some (of great value) then, eventually, IB will make it do it (for the most part)... So, the NFR is OK for #2... #1 still needs to be addressed...

Thanks...

March 09, 2010, 09:40 AM

Doug

Explanation Section
New Feature Request
Customer request 2 enhancements to the POPUPDESC feature

1. Ability to change the background color for the pop-up box

2. Enable this feature for COMPUTE fields(currently this requires an entry in the MFD, where Computed fields are not referenced)
...

March 09, 2010, 05:06 PM

Mighty Max

Old mock up using CSS and mouseover hover. Does not use POPUPDESC.
Used the example Francis gave in [SOLVED] Event on a report cell.
Don't remember where I found the CSS on the web.
Maybe this will help you in change the background colors.

  
-HTMLFORM BEGIN
<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<style type="text/css">
span.tool {
  position: relative;   /* this is key */
  cursor: help;
}

span.tip{
  display: none;        /* so is this */
}

/* tooltip will display on :hover event */

span.tool:hover span.tip{
  display: block;
  z-index: 100;
  position: absolute;
  top: 0px;
  left: 0px;
  width: 100px;
  padding: 3px;
  border: 1px solid #333366;
  background-color: #ffdddd;
  font: normal 8pt arial, helvetica, sans-serif;
  text-align: center;
  color: #000000;
}

</style>
-HTMLFORM END

SET HOLDLIST=PRINTONLY
-RUN

TABLE FILE CAR
PRINT
COMPUTE COLOUR_FLAG/A1 =
IF SALES GT 40000 THEN '4' ELSE
IF SALES GT 30000 THEN '3' ELSE
IF SALES GT 20000 THEN '2' ELSE
IF SALES GT 10000 THEN '1' ELSE
IF SALES EQ 0 THEN '0' ELSE
'9'; NOPRINT

COMPUTE COLOUR_TEXT/A20 =
IF SALES GT 40000 THEN 'Sales > 40,000' ELSE
IF SALES GT 30000 THEN 'Sales > 30,000' ELSE
IF SALES GT 20000 THEN 'Sales > 20,000' ELSE
IF SALES GT 10000 THEN 'Sales > 10,000' ELSE
IF SALES EQ 0 THEN 'Zero sales' ELSE
'Sales < 10,000'; NOPRINT


COMPUTE MOUSEOVER/A255 =
IF COLOUR_FLAG EQ '0' THEN
'<span class=''tool''>' | FTOA(SALES, '(D6)', 'A20') |
'<span class=''tip''>' | COLOUR_TEXT | '</span></span>'
ELSE FTOA(SALES, '(D6)', 'A20'); AS 'Sales'

BY COUNTRY
BY CAR
BY MODEL
ON TABLE SET ASNAMES ON


ON TABLE SET PAGE-NUM OFF
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TYPE=REPORT, FONT='ARIAL', SIZE=10, $
TYPE=DATA, COLUMN=MOUSEOVER, BACKCOLOR=RED,    WHEN= COLOUR_FLAG EQ '0', $
TYPE=DATA, COLUMN=MOUSEOVER, BACKCOLOR=GREEN,  WHEN= COLOUR_FLAG EQ '1', $
TYPE=DATA, COLUMN=MOUSEOVER, BACKCOLOR=BLUE,   WHEN= COLOUR_FLAG EQ '2', $
TYPE=DATA, COLUMN=MOUSEOVER, BACKCOLOR=ORANGE, WHEN= COLOUR_FLAG EQ '3', $
TYPE=DATA, COLUMN=MOUSEOVER, BACKCOLOR=PINK,   WHEN= COLOUR_FLAG EQ '4', $
TYPE=DATA, COLUMN=MOUSEOVER, BACKCOLOR=PURPLE, WHEN= COLOUR_FLAG EQ '9', $
ENDSTYLE
END